         SYSTEM   SIG7FDP
           SYSTEM   BPM
         TITLE    'PHASE 0.0'
*
* PHASE 0.0 REFERENCES
*    COBIO
*
         REF      COBIOOOF,COBIODB,TYPE
         REF      DIAG
         REF      RANGE
         REF      XRFBUF
         REF      CPBUF
         REF      ON:LINE           ON-LINE DEBUGGING FLAG
         REF      PH5E                                                  COBOL00
*
COB00    RES      0
         CAL1,8   TLIST1          M:TRAP,SIG5,(TRAP,NAO)
         LI,1     0
         CBS,0    0               VERIFY THAT THIS IS SIGMA7
         CAL1,8   TLIST2          M:TRAP,TRAP,(TRAP,NAO,PS,FP,DEC,FX,CAL
         B        %+2             RUNNING ON SIGMA 7
SIG5     CAL1,8   TLIST3          M:TRAP,TRAP,(PS,FP,DEC,FX,CAL)
         CAL1,8   GLIST             M:GP  N
         STW,8    PAGE              SAVE NUM OF PAGES                   COBOL00
         STW,9    PDBZ              SET
         STW,9    PDBZ+1              THE
         STS,9    MLIST             FROM ADDRESS OF SMPRT PLIST
         SLS,8    9                       OF
         AI,8     -1                        THE
         AW,9     8                           COMPILER'S
         STW,9    CPBUF             END OF COPY BUFFER
         AI,9     -1000
         STW,9    CPBUF+1           BEGINNING OF COPY BUFFER
         AI,9     -1
         STW,9    PDBZ+5            END OF DYNAMIC AREA
         STS,9    MLIST+1           TO ADDRESS OF SMPRT PLIST
         CAL1,8   MLIST             M:SMPRT - DECLARE PROTECTION CLASS
         LI,2     0
         LI,5     8
         BAL,11   COBIOOOF          OPEN DMF TO OUTPUT (NONCLUSTERED)
         CAL1,8   TLIST4                                                COBOL00
         STD,8    PTC                                                   COBOL00
         CAL1,1   PROMPT            SET PROMPT CHARACTER                COBOL00
         BCS,8    NONLINE                                               C-B-L00
         MTW,0    *X'4F'            SEE JIT FOR ONLINE STATUS           COBOL00
         BGEZ     NONLINE           IF BIT 0= 0 NOT ONLINE              COBOL00
         CAL1,2   SALUTE            YES. SALUTE THE USER                COBOL00
NONLINE  RES      0                                                     COBOL00
         CAL1,8   TLIST5                                                COBOL00
         CAL1,1   PLIST4            M:READ - COBOL CONTROL COMMAND
         LI,2     0                                                     COBOL00
         LI,5     7                                                     COBOL00
         BAL,11   COBIOOOF          OPEN SPF TO OUTPUT (NONCLUSTERED)   COBOL00
         LI,2     17                                                    COBOL00
         LI,3     7                                                     COBOL00
         LW,4     ='SPF '                                               COBOL00
         BAL,11   COBIODB           SET PRINT CONTROL FOR SPF           COBOL00
         LI,2     18                                                    COBOL00
         LI,3     8                                                     COBOL00
         LW,4     ='DMF '               AND                             COBOL00
         BAL,11   COBIODB            DMF                                COBOL00
         LW,7     PAGE                                                  COBOL00
         CI,7     4                 CHECK FOR MINIMUM PAGES             COBOL00
         BL       NO%PAGE           NOT ENOUGH                          COBOL00
         LW,7     PDBZ              FIRST WORD OF DYNAMIC STORAGE ADDR  COBOL00
         LW,6     BLANKS            BLANK OUT                           COBOL00
         LW,5     X'4F'             JIT POINTER
         LW,8     1,5               CURRENT ACCOUNT WORD 1
         LW,9     2,5                     AND 2
         LI,5     3
         AND,5    M:LI               ASN
         CI,5     2
         BE TAP%L
         STW,6    1,7
         STW,6    2,7               BLANK OUT TAPE ACN
         AI,7     2                 AND SKIP OVER
TAP%L    EQU      %
         LI,2     M:LI                                                  COBOL00
         LW,2     6,2               GET FLP
         AND,2    =X'1FFFF'
ACN%LOOK LB,15    *2
         CI,15    2                 ACN YET
         BE       ACN%FND           YES.
         LW,15    *2
         AND,15   =X'FF'
         AW,2     15
         AI,2     1
         B        ACN%LOOK
ACN%FND  AI,2     1
         LW,14    0,2               MOVE ACN FROM                       COBOL00
         STW,14   1,7                M:LI DCB                           COBOL00
         LW,14    1,2                TO 1ST LIBRARY                     COBOL00
         STW,14   2,7                 POSITION                          COBOL00
         AI,7     2                  (TAPE OR NOT)                      COBOL00
         STW,8    1,7
         STW,9    2,7
         STW,6    3,7
         STW,6    4,7
         AI,7     3
         STW,7    *PDBZ
* SCAN THE CONTROL COMMAND
         LI,4     BA(CBUF)          LOCATE CONTROL CARD IMAGE
CC1      AI,4     1                 PASS                                COBOL00
         LB,15    0,4                OVER
         CI,15    ' '                 LEADING
         BNE      CC2                                                   COBOL00
         CI,4     BA(CBUF)+79                                           COBOL00
         BL       CC1                                                   COBOL00
         BAL,11   ERROR             DIAG - CONTROL COMMAND              COBOL00
         B        SOP99             DEFAULT                             COBOL00
CC2      AI,4     1                                                     COBOL00
         LB,15    0,4                OVER
         CI,15    ' '                 'COBOL'
         BNE      %-3                  COMMAND
         AI,4     1
         CI,4     BA(CBUF)+80
         BE       SOP99             END-OF-CARD - NO OPTIONS
NEXT     BAL,11   GETSTRNG          GET CHARACTER STRING TO BUFFER      COBOL00
         LI,2     OPTAB                                                 COBOL00
         LW,11    WBUF              LOOK                                COBOL00
LOST     CW,11    0,2                FOR                                COBOL00
         BE       FOUND               MATCHING                          COBOL00
         AI,2     1                    TABLE                            COBOL00
         B        LOST                  ENTRY                           COBOL00
FOUND    CI,2     WBUF              IF MATCHES ITSELF                   COBOL00
         BNE      CHKOUT            NO. GO CHECK FOR CHKOUT OPTION      COBOL00
         LB,1      WBUF                IF BLANK                         COBOL00
         CI,1      X'40'               THEN NULL COMMAND                COBOL00
         BE        NEXT                AND NOT ERROR                    COBOL00
         LI,1     0                                                     COBOL00
         BAL,11   ERROR             YES. STACK UP ERROR                 COBOL00
         B        NEXT
CHKOUT   CI,2     OPTCS                                                 COBOL00
         BG       SOP10             ALL AFTER CS ARE CHECKOUT           COBOL00
         BE       SOP5              CS                                  COBOL00
         CI,2     OPTLIB                                                COBOL00
         BE       LIB               LIB                                 COBOL00
         CI,2     OPTSO                                                 COBOL00

         BE       SO                                                    COBOL00

         CI,2     OPTLO
         BE       LO
SET%OPT  RES      0
         AI,2     -OPTAB                                                COBOL00
         LCW,2    2                                                     COBOL00
         LI,7     X'8000'                                               COBOL00
         SLS,7    0,2                                                   COBOL00
         STS,7    PDBCC             SET OPTION BIT ON                   COBOL00
         B        NEXT                                                  COBOL00
SOP5     RES      0                 SHOULD BE CS OPTION
         LI,1     3
         CB,1     PUNCT
         BE       CS2
CSERR    BAL,11   ERROR
         B        NEXT
CS2      BAL,11   GETSTRNG
         LI,1     4
         CB,1     PUNCT
         BNE      CSERR
         LI,7     X'F'
         AND,7    PUNCT
         BEZ      %+3
         CI,7     7                 MAX NO OF CHARACTERS                COBOL00
         BLE      CS3
         LI,1     180                                                   COBOL00
         BAL,11   DIAG              ISSUE DIAG                          COBOL00
         B        NEXT
CS3      STB,7    MBSCS+1
         STB,7    PDBY
         LD,6     MBSCS
         MBS,6    0
         B        NEXT                                                  COBOL00
LIB      EQU      %
         LI,1     3                 IF LAST
         CB,1     PUNCT              PUNCTUATION                        COBOL00
         BE       LIB2              NOT LEFT PARENTHESES                COBOL00
         BAL,11   ERROR                                                 COBOL00
         B        NEXT              ISSUE DIAGNOSTIC TRY AGAIN          COBOL00
LIB2     EQU      %                                                     COBOL00
         BAL,11   GETSTRNG          GET AN ACCOUNT NUMBER               COBOL00
         LI,7     X'F'                                                  COBOL00
         AND,7    PUNCT                                                 COBOL00
         BEZ      %+3               LENGTH ZERO  OR                     COBOL00
         CI,7     8                                                     COBOL00
         BLE      LIB3              GREATER THAN 8                      COBOL00
         LI,1     3                  DIAGNOSE                           COBOL00
         BAL,11   ERROR              AND CONTINUE                       COBOL00
LIB3     LW,7     *PDBZ                                                 COBOL00
LIB4     LW,6     WBUF              MOVE                                COBOL00
         STW,6    0,7                ACN                                COBOL00
         LW,6     WBUF+1                                                COBOL00
         STW,6    1,7                                                   COBOL00
         LW,6     BLANKS            BLANK OUT                           COBOL00
         STW,6    2,7                NEXT                               COBOL00
         STW,6    3,7                ACN                                COBOL00
         STW,6    4,7
         STW,6    5,7
         MTW,2    *PDBZ             UPDATE ACN POINTER                  COBOL00
         LB,7     PUNCT             IF LAST PUNCTUATION                 COBOL00
         CI,7     4
         BNE      LIB2              TRY ANOTHER ACN                     COBOL00
         B        NEXT                                                  COBOL00
*
LO       RES      0
         LI,1     3
         CB,1     PUNCT
         BNE      SET%OPT           NO RANGE..GET OUT
         LI,5     RANGE
         STW,5    RANGE-1
         SLS,5    1                 ..HW ADDR OF NEXT RANGE
NXT%RNGE RES      0
         BAL,11   GETSTRNG          GET NEXT RANGE
         LI,15    0                 CLEAR RESULT
         LI,6     0                 RESET BYTE INDEX
RNGE%DIG RES      0
         LB,1     WBUF,6            GET NEXT DIGIT
         CI,1     X'40'             IF SPACE GO STORE RESULT
         BE       STOR%RNG
         MH,15    =X'A0000'         ELSE SHIFT LAST RESULT
         AND,1    =X'0F'            ADD
         AW,15    1                 NEW DIGIT
         AI,6     1
         B        RNGE%DIG
STOR%RNG RES      0
         STH,15   0,5               STORE RANGE
         AI,5     1
         LB,1     PUNCT
         CI,1     4                 IF RT PAREN
         BNE      NXT%RNGE          NO. TRY ANOTHER
         B        SET%OPT           YES. FORGET IT
*                                                                       COBOL00

SO       RES      0                                                     COBOL00

         CAL1,1   SO%OPEN                                               COBOL00

         LW,15    FIRSTKEY                                              COBOL00

         STW,15   SO%SEQ                                                COBOL00

         B        NEXT                                                  COBOL00

FIRSTKEY GEN,8,24 3,1000                                                COBOL00

         REF      M:SO,SO%SEQ                                           COBOL00

SO%OPEN  GEN,8,24 X'14',M:SO                                            COBOL00

         DATA     X'07400000'
         DATA     2,2,2,2,X'010000'
SV4      RES      1
SV11     RES      1
SV3      RES      1
SIGNS    DATA,1   ' ','.',',','(',')'                                   COBOL00
         BOUND    4
PUNCT    GEN,8,24 5,0
         REF      PDBCC,PDBY
         REF      M:LI
         BOUND    8
MBSCS    DATA     BA(WBUF),BA(PDBY)+1
MBSWBUF  GEN,8,24 80,BA(WBUF)                                           COBOL00
BLANKS   TEXT     '    '                                                COBOL00
BLANK    EQU      BLANKS                                                COBOL00
R3       EQU      3
R7       EQU      7
GETSTRNG LW,1     MBSWBUF                                               COBOL00
         MBS,0    BLANK                                                 COBOL00
         LI,R3    0                                                     COBOL00
         LB,R7    PUNCT                                                 COBOL00
         B        %,7                                                   COBOL00
         B        SOP99             PERIOD   1                          COBOL00
         B        GSTRING           COMMA    2                          COBOL00
         B        GSTRING           LEFT P   3                          COBOL00
         B        GSTRING
GSTRING  LB,15    0,4                                                   COBOL00
         AI,4     1                 SKIP                                COBOL00
         CI,15    ' '                BLANKS                             COBOL00
         BE       GSTRING                                               COBOL00
         CI,15    ';'                                                   COBOL00
         BE       NEWCARD                                               COBOL00
         CI,15    X'15'             IF NEW-LINE
         BE       GETBLNK             OR
         CI,15    X'0D'                CARRIAGE-RETURN
         BNE      GSTN
GETBLNK  EQU      %
         LI,15    X'40'             BLANK OUT
PUTBLNK  EQU      %
         STB,15   0,4
         AI,4     1
         CI,4     BA(CBUF)+79
         BLE      PUTBLNK            TO END OF CARD
         LI,15    '.'               REPORT PERIOD FOUND
GSTN     EQU      %
         LI,7     4                                                     COBOL00
         CB,15    SIGNS,7                                               COBOL00
         BE       PUNCTURE                                              COBOL00
         BDR,7    %-2                                                   COBOL00
         STB,15   WBUF,3                                                COBOL00
         AI,3     1                                                     COBOL00
         B        GSTRING                                               COBOL00
PUNCTURE EQU      %
         XW,3     PUNCT
         STB,7    PUNCT                                                 COBOL00
         LB,1     3
         CI,1     4
         BNE      *11
        LB,1     PUNCT,1
         BNEZ     P2
         LB,1     PUNCT
         CI,1     2
        BLE      GETSTRNG
P2       EQU      %
         LI,1     2
        B        DIAG              REPORT ERROR AND EXIT
NEWCARD  LI,4     BA(CBUF)-2                                            COBOL00
         LI,2     82                                                    COBOL00
         STW,11   SV11                                                  COBOL00
         STW,3    SV3
         BAL,11   WRSPF                                                 COBOL00
         LW,1     BLANKIT                                               COBOL00
         MBS,0    BLANKS                                                COBOL00
         CAL1,1   PLIST4            READ NEXT CARD
         LW,3     SV3
         LW,11    SV11
         MTW,1    CBUF-1                                                COBOL00
         LI,4     BA(CBUF)                                              COBOL00
         B        GSTRING                                               COBOL00
ERROR    EQU      %                                                     COBOL00
         LI,1     181                                                   COBOL00
         B        DIAG              ISSUE DIAG & EXIT                   COBOL00
NO%PAGE  RES      0                                                     COBOL00
         LI,1     282                                                   COBOL00
         BAL,11   DIAG              NO DYNAMIC ABORT                    COBOL00
         B        PH5E              ABORT                               COBOL00
SOP99    RES      0
         LI,4     1
         LH,15    PDBCC,4            WERE ANY PROGRAM OPTIONS SPECIFIED?
         BNEZ     SOP99A             YES                                COBOL00
         LI,15    X'8040'           DEFAULT LS,GO FOR BATCH             COBOL00
         MTW,0    *X'4F'            SEE JIT FOR ON-LINE OR BATCH        COBOL00
         BGEZ     SOP99B            BIT 0=0 SO ITS BATCH                COBOL00
         LI,15    X'40'             DEFAULT TO GO FOR ON-LINE           COBOL00
         B        SOP99B              SET DEFAULT OPTIONS               COBOL00
SOP99A   AND,15   L(X'0000000A')    IS PMAP (OR MAPS) SPECIFIED ?       COBOL00
         BEZ      SOP99C              NO                                COBOL00
         LH,15    PDBCC,4             YES, SET LS ALSO                  COBOL00
         OR,15    L(X'00008000')                                        COBOL00
SOP99B   STH,15   PDBCC,4                                               COBOL00
SOP99C   LI,4     MESS                                                  COBOL00
         BAL,11   TYPE
         LI,2     0
         LI,5     7
         BAL,11   COBIOOOF          OPEN SPF TO OUTPUT (NONCLUSTERED)
         LI,2     17
         LI,3     7
         LW,4     L(C'SPF ')
         BAL,11   COBIODB           PRINT CONTROL
         LI,2     18
         LI,3     8
         LW,4     L(C'DMF ')
         BAL,11   COBIODB           PRINT CONTROL
*
* IS CROSS REFERENCE SPECIFIED
*
         LI,2     X'2006'
         AND,2    PDBCC
         OR,2     ON:LINE                                               COBOL00
         BEZ      COB001
         LI,2     BA(XRFBUF)
         LI,5     6
         BAL,11   COBIOOOF          OPEN XRF TO OUTPUT (CLUSTERED)
         LI,2     12
         LI,3     6
         LW,4     L(C'XRF ')
         BAL,11   COBIODB           PRINT CONTROL
*    OUTPUT NAME CLUSTER FOR 'TALLY' IN THE XRF
         LI,4     BA(XRFCL)
         BAL,11   WRXRF
COB001   RES      0
         LI,4     BA(CBUF)-2
         LI,2     82
         BAL,11   WRSPF             OUTPUT COBOL CONTROL CARD
         M:TIME   TMDATE+1          GET TIMEDATE
         LW,5     TMDATE+4
         STH,5    TMDATE+5
         LW,5     L(X'6B40F1F9')    CHANGE TO ', 19'
         STW,5    TMDATE+4
         LI,1     X'20'              IS 'SEG' OPTION
         AND,1    PDBCC               SPECIFIED?
         BNEZ     %+3               YES
         LI,1     X'99'              NO - SUPPRESS SEGMENTATION
         STW,1    PDBP                       IF IT OCCURS
         LW,1     PDBCC
         CI,1     X'10'             SYNTAX-CHECK ONLY
         BAZ      PH00E               NO-RETURN
         LI,1     X'4000'             YES-ABORT BIT
         OR,1     PDBP
         STW,1    PDBP
         REF      PDBP
         B        PH00E             RETURN TO PHASE 0
         REF      PH00E
* THIS IS WHERE THE COMPILER DEBUGGING OPTIONS ARE PROCESSED
SOP10    RES      0
         CI,2     SRTS              SEQ  SORT
         BE       SORTO
         CI,2     SRTR              RANDOM  SORT
         BE       SORTR
         CI,2     TESTOP
         BE       SETEST
         CI,2     NORPOP
         BE       UNCOP
         AI,2     -OPTCS
         LCW,7    2                 MANUFACTURE
         LI,1     3                  A
         STB,7    %+3,1               RIGHT
         LW,7     L(X'80000000')       SHIFT
         STS,7    PDBJ                  INSTRUCTION
         SLS,7    0                 MODIFIED
         STS,7    PDBJ
         LI,7     X'100'
         AND,7    PDBJ              'ALL' OPTION SPECIFIED
         BEZ      %+3               NO -
         LI,7     X'FFFB0'             YES-TURN ON ALL DEBUGGING
         STW,7    PDBJ
         B        NEXT
SORTO    RES      0
         LI,7     1
         STS,7    PDBJ
         B        NEXT
SORTR    RES      0
         LI,7     2
         STS,7    PDBJ
         B        NEXT
SETEST   RES      0
         LW,3     TESTSET
         STS,3    PDBCC             SET TEST OPTIONS
         STW,3    ON:LINE
         B        SO
TESTSET  DATA     X'800'            SET DEBUG ON FOR 'TEST'             COBOL00
UNCOP    RES      0                 NO COPY REPLACING BUFFER
         LW,2     CPBUF
         STW,2    PDBZ+5
         LI,2     0
         STW,2    CPBUF
         STW,2    CPBUF+1
         B        NEXT
         REF      WRSPF,TMDATE,PDBJ
         PAGE
*
* PHASE 0.0 PLISTS AND ETC.
MESS     TEXTC    '
COBOL00
'
PLIST4   GEN,8,24 X'10',M:C         M:READ
         DATA     X'30000010'
         DATA     CBUF
         DATA     80
         DATA     0
         DATA     0
*
         DATA     0
CBUF     DO1      20                                                    COBOL00

         DATA     '    '                                                COBOL00

          DATA      '....'         END OF CARD STOPPER
TLIST1   GEN,8,24 X'14',SIG5      TEST IF SIGMA 7
         DATA     X'00200000'     NAO ONLY
TLIST2   GEN,8,24 X'14',TRAP
         DATA     X'002F8003'     NAO AND OTHERS
TLIST3   GEN,8,24 X'14',TRAP
         DATA     X'200F8003'     ALL EXCEPT NAO
         REF      TRAP              DEFINED IN COBOL0
GLIST    GEN,8,24 X'08',256         M:GP  256
MLIST    GEN,8,24 X'0A',0           M:SMPRT
         GEN,8,24 X'00',0
OPTAB    TEXT     'LS  '            SOURCE LISTING
OPTLO    TEXT     'LO  '
         TEXT     'XREF'            CROSS-REFERENCE LISTING
         TEXT     'DIAG'            LIST TRIVIAL DIAGNOSTICS
         TEXT     'DEBU'            COMPILE DEBUGGING STATEMENTS
         TEXT     'MAIN'            MAIN PROGRAM
         TEXT     'SUB '            SUB PROGRAM
         TEXT     'SEQC'            SEQUENCE CHECK
         TEXT     'BO  '
         TEXT     'GO'
         TEXT     'SEG '            SEGMENTATION
         TEXT     'SYN '            SYNTAX CHECK ONLY
         TEXT     'PMAP'            PROCEDURE MAP
         TEXT     'DMAP'            DATA MAP
         TEXT     'MAPS'            PMAP AND DMAP
         TEXT     'DQ  '            DOUBLE QUOTE                        COBOL00
         TEXT     'SQ  '            SINGLE QUOTE                        COBOL00
         TEXT     'SI  '            IGNORE - FOR XOS COMPATIBILITY ONLY COBOL00
OPTLIB   TEXT     'LIB '                                                COBOL00
OPTSO    TEXT     'SO  '            SOURCE OUTPUT                       COBOL00

OPTCS    TEXT     'CS  '            COMMON-STORAGE SECTION
         TEXT     'EPF '
         TEXT     'EDF '
         TEXT     'CRF '
         TEXT     'ECF '
         TEXT     'OLF '
         TEXT     'RGF '
         TEXT     'IVF '
         TEXT     'DDD '
         TEXT     'MCF '
         TEXT     'ILF '
         TEXT     'POF '
         TEXT     'XRF '
         TEXT     'RFF '
         TEXT     'SPD '
         TEXT     'CSF '
         TEXT     'RPF '
         TEXT     'SPF '
         TEXT     'DMF '
         TEXT     'SCAN'
         TEXT     'LEX '
         TEXT     'LINE'
         TEXT     'TYPE'
         TEXT     'ALL '
         TEXT     'DUMP'
         TEXT     'CONT'
         TEXT     'MPF '
         TEXT     'MDF '
*+403  OVERLAP    CO-RESIDENT SORT  DGC                                 COBOL00
TESTOP   TEXT     'TEST'            ON-LINE DEBUGGING
NORPOP   TEXT     'NORE'            NO COPY REPLACING NEEDED
         TEXT     '%:**'            OPEN WORD                           COBOL00
SRTS     TEXT     'SRTS'
SRTR     TEXT     'SRTR'
OPTEND   EQU      %
OPTCT    EQU      OPTEND-OPTAB      #ENTRIES IN OPTAB
WBUF     TEXT     '    '            OPTION BUFFER
          RES      20
         RES      2
EOC      DATA     0                 END-OF-CARD INDICATOR
XRFCL    RES      0
         GEN,8,8,16 6,0,0           'TALLY' HAS REFERENCE NO. ZERO
         TEXTC    'TALLY'
         BOUND    4
PROMPT   GEN,8,24 X'2C','%'                                             COBOL00
SALUTE   GEN,8,24 1,0                                                   COBOL00
         GEN,1,31 1,0                                                   COBOL00
         DATA     SALUTEM                                               COBOL00
SALUTEM  DATA,1    BA(SALUTEND)-BA(SALUTEM),X'15',' ',' '               COBOL00
         TEXT      'F00 COBOL'
         DATA     X'15404040'                                           COBOL00
         TEXT     'OPTIONS?'                                            COBOL00
         DATA,1   X'15'                                                 COBOL00
SALUTEND DATA,1   X'15'                                                 COBOL00
         BOUND    4                                                     COBOL00
TLIST4   GEN,8,24 X'14',NONLINE                                         COBOL00
         DATA     X'8000'                                               COBOL00
TLIST5   GEN,8,24 X'14',PTC                                             COBOL00
         DATA     X'80000000'                                           COBOL00
         BOUND    8                                                     COBOL00
PTC      RES      2                                                     COBOL00
BLANKIT  GEN,8,24 80,BA(CBUF)                                           COBOL00
PAGE     DATA     0
         REF      WRXRF
         REF      PDBZ,M:OC,M:C
         DEF      COB00
         END
