         SYSTEM   SIG7FDP
         TITLE    'PHASE 4.1 - STACK SUBROUTINES'
* DIAG PROC                                                             APD
DX       CNAME                                                          APD00
         PROC                                                           APD01
* AF     DX       DIAG CODE,LINK                                        APD02
LF       LI,R1    AF(1)             LOAD DIAG CODE                      APD10
         DO       NUM(AF(3))
         B        DIAG              WRITE DMF CLUSTER
         ELSE
         DO       NUM(AF(2))
         LI,L1    AF(2)             LOAD LINK REGISTER
         B        DIAG              WRITE DMF CLUSTER                   APD242
         ELSE                                                           APD243
         BAL,L1   DIAG              WRITE DMF CLUSTER                   APD244
         FIN                                                            APD248
         FIN                                                            APD29
         PEND                                                           APD40
* REGISTER EQUIVALENCES
R0       EQU      0
R1       EQU      1
R2       EQU      2
R3       EQU      3
R4       EQU      4
R5       EQU      5
R6       EQU      6                                                     117
R7       EQU      7                                                     116
V0       EQU      8
V1       EQU      9
V2       EQU      10
L0       EQU      V2                                                    1212
L1       EQU      11                LINK REGISTER
D0       EQU      12                DECA
D1       EQU      13
D2       EQU      14
D3       EQU      15
*CONDITION CODE EQUIVALENCES
CM       EQU      1                 NEGATIVE
CP       EQU      2                 POSITIVE
CZ       EQU      3                 ZERO(RESET)
CL       EQU      CM                LESS                                ADI
CG       EQU      CP                GREATER                             ADI
CE       EQU      CZ                EQUAL(RESET)
CV       EQU      4                 OVERFLOW
CC       EQU      8                 CARRY OVER
CA       EQU      CP                AND BIT
CB       EQU      CV                BIT COMPARE
CMI      EQU      1                 MODIFY INCREMENT
* EXTERNAL REFERENCES
         REF      WRMCF
         REF      DIAG
         REF      JMCRD,JMCER,JRDF  RETURNS,READ
         REF      ADI00,ADI02       REF
         REF      JAKON,JADAT,JASAV
         REF      STBAS             DATA STACK
         REF      MCBUF
         REF      ADV00
         REF      PH41E
JBGOP    EQU      MCBUF
* DIAG CODE BASE EQUIVALENCES
XGS      EQU      126               ROUNDED
*
CJIFZ    EQU      X'70394'        M FIGCON - ZERO                       ADI821
CJINL    EQU      X'60598'          N LIT
*
CISAV    EQU      X'80000'          SAVE REF FLAG                       ADI455
CLOP     EQU      X'80'           A LAST OPERAND                        A
CBGSUB   EQU      1                 SUBTRACT
CBGOSE   EQU      2                 OSE
* ENTRY POINTS
         DEF      ADF00,ADG00,ADH00 STACK,UNSTACK
         REF      STMTYP
         REF      PRIMODE
         REF      COMPFLG
*
* STACK REFERENCES                 "STREF"                              ADF
*                        R1 = WA(NREF)+1                                ADF0 1
*                        R3 = HA(STKTOP)                                ADF0 3
*                        V2 = REF CONTROL                               ADF0 6
*                        L1 = LINK REGISTER                             ADF0 7
*                        D0 = TYPE EXU TABLOC                           ADF0 8
*                        D1 = NO. OF TYPES,IGNORE OPTION                ADF0 9
ADF00    RES      0                                                     ADF00
         STD,L0   JDFSAV            SAVE REF CONTROL,LINK REG           ADF001
         STW,R1   JDREF                  WA(NREF)                       ADF002
         STH,D1   JDIGN                  IGNORE OPTIONS                 ADF003
         LH,D1    D1                SET MBS RU1 COUNT                   ADF004
         STB,D1   R1                                                    ADF005
         STW,D1   JTYPB             CLEAR TYPE BITS                     ADF054
         AW,D1    R1                COMPUTE WA(ANCHOR)                  ADF006
         AI,R1    -1                SET WA(NREF)-1                      ADF0064
         SLS,R1   2                 WA COUNT,WA(NREF) TO BA             ADF007
         MBS,0    X'2C'   (=BA(L1)) INITIALIZE NREF(I)
         STD,D0   JDEXU             SAVE TYPE EXU,ANCHOR LOC            ADF009
ADF02    RES      0                                                     ADF020
         LI,R1    0                 CLEAR REGISTER                      ADF021
         STH,R1   0,R3              CLEAR TYPLNK(STKTOP)                ADF022
         BAL,L1   ADI00             CHECK REF                           ADF023
         B        ADF16             BAD DATA                            ADF024
ADF04    RES      0
         AI,R2    1                 HA(NLOC) = HA(NLOC)+1
         LH,R1    0,R2              LOAD OPTYP,STMT OPTION
         AI,R2    -1                HA(NLOC) = HA(NLOC)-1
         CI,R1    X'FF01'           CHECK FOR OPTION ONLY
         BANZ     ADF10             NO. NOT OPTION ONLY
         LH,L1    0,R2              LOAD,CHECK CNTL
         CI,L1    X'80'
         BANZ     ADF10             1ST STMT CLUSTER
*OPTION  ONLY - ROUNDED
         CI,R5    0                 CHECK HA(LLOC)-|
         BE       ADF08             =0,INVALID LAST OPND
*                        R5 = HA(LLOC)-1                                ADF0875
         CI,R6    X'20000'          CHECK OPND TYPE
         BAZ      ADF06             RFLD = BIN/NC/ND/NE
* W****4INVALID ROUND OPTION********
         DX       XGS,ADF08         WRITE DMF CLUSTER
* VALID ROUND OPTION
ADF06    RES      0
         MTH,4    1,R5              RAISE RFLD ROUND FLAG
         AI,R7    4
ADF08    RES      0
         BAL,L1   *JRDF             READ NEXT CLUSTER
* NOT OPTION ONLY
ADF10    RES      0                                                     ADF100
         CI,R5    0                 CHECK HA(LLOC)-1
         BEZ      ADF12             =0, INVALID LAST OPND
* VALID OPERAND
         LW,11    STMTYP
         CI,11    3                 DIVIDE STMT ?
         BE       %+3               YES
         LW,11    COMPFLG
         BEZ      NO                NOT COMPUTE
         LW,11    PRIMODE           LOAD PREVIOUS MODE
         CI,11    2                 DEC MODE ?
         BL       DEC
         CI,11    3                 FLOATING
         BLE      NO                SKIP
         LH,11    6                 GET NEW MODE
         STW,11   PRIMODE           STORE NEW MODE
         B        NO
DEC      LH,11    6                 GET NEW MODE
         CI,11    3
         BG       NO                BIN MODE, SKIP
         STW,11   PRIMODE
NO       RES      0
         BAL,L1   ADG00             CHAIN OPERAND
*                        R2 = HA(NLOC)                                  ADF1102
ADF12    RES      0
         AI,R2    1                 HA(NLOC) = HA(NLOC)+1
         LH,R1    0,R2              LOAD OPTYP,STMT OPTION
         AI,R2    -1                HA(NLOC) = HA(NLOC)-1
         CI,R7    CLOP              CHECK LAST OP FLAG                  ADF111
         BCS,CB   ADF14             LAST OP FLAG UP                     ADF112
* NOT LAST OPERAND                                                      ADF12
*                        R1 = NEXT OP OPTYP,STMT OPT                    ADF1201
         CI,R1    X'9F'             CHECK STMY OPTION
         BCR,CB   ADF02             NO STMT OPTIONS                     ADF122
         LW,L1    JIGNL             IGNORE LITERAL
         BNEZ     ADF13             NO
         CI,R1    X'6000'           .LITERAL/FIGCON
         BANZ     ADF02
* *** ALL LITERALS,FIGCONS ACCEPTABLE ********
ADF13    RES      0
         AND,R1   K39F              MASK,CHECK OPTION
         CB,R1    JDIGN             COMPARE STMT,IGNORE OPT             ADF123
         BCR,CE   ADF02             = IGNORE OPT                        ADF124
         CI,R1    CLOP              CHECK FOR LAST OP ONLY
         BE       ADF02             YES.  IGNORE.
         LI,R7    0                 CLEAR LAST OP FLAG                  ADF125
* NOT IGNORE OPTION                                                     ADF131
*                        R1 = NEXT OP OPTYP,STMT OPTION                 ADF1311
*                        R7 = 0                                         ADF1317
* LAST OP PROCESSED                                                     ADF132
*                        R6 = LAST OP TYPE,CLNG,CNTL                    ADF1326
*                        R7 = LAST OP OPTYP,STMT OPTION                 ADF1327
* LAST OP PROCESSED VALID                                               ADF133
*                        R4 = HA(LLOC)                                  ADF1334
*                        R5 = HA(LLOC)+1                                ADF1335
*                                                                       ADF134
*                        R2 = HA(NLOC)                                  ADF1342
*                           = 0 IF LAST OP INVALID                      ADF1343
*                                                                       ADF135
* RETURN                                                                ADF14
ADF14    RES      0                                                     ADF140
         LD,L0    JDFSAV            RESTORE REG                         ADF141
         B        *L1               RETURN                              ADF142
* INVALID OPERAND                                                       ADF16
ADF16    RES      0                                                     ADF160
         CI,R7    CLOP              CHECK LAST OP FLAG                  ADF161
         BANZ     ADF14             LAST OP FLAG UP                     ADF162
         LI,R5    0                 SET HA(LLOC)-1 =0
         B        ADF04
K39F     DATA     X'9F'             OPTION MASK
         PAGE
* STACK DATA REFS                  "STDAT"                              ADG
ADG00    RES      0                                                     ADG00
         LCI      6                 SAVE REGISTERS                      ADG001
         STM,R2   JDGSAV                                                ADG002
         STW,L1   JDGSAV+6          SAVE LINK REGISTER                  ADG0024
         LH,R3    R6                LOAD DATA TYPE                      ADG004
         EXU      *JDEXU,R3         EXECUTE TYPE CHECK                  ADG005
         CW,R5    KHASTKL           SEE IF STACK LIMIT EXCEEDED         COBOLJU3
         BLE      ADG01             NO
         DX       X'3D'             YES ISSUE DIAG 61                   COBOL41O
         DX       X'77'                AND 119 (ABORT JOB)              COBOL41O
         B        PH41E             EXIT
ADG01    RES      0
         SW,R5    KHASTK            HA(CLOC)-1 = STACK OFFSET (LNKC)
         EXU      ADG09+2,R3        EXECUTE FINAL TYPE BRANCH           ADG006
* BIN/FLP                                                               ADG02
ADG02    RES      0                                                     ADG020
*                        R4 = LNKL(I)                                   ADG0204
         LH,R1    *JDREF,R3         CHECK NREF(I)                       ADG022
         BCS,CZ   ADG06             NREF(I) NOT= 0                      ADG023
* SET TYPE, ANCHOR(I)                                                   ADG03
ADG03    RES      0                                                     ADG030
         MTB,CMI  JNTYP             NO. OF TYPES(NTYP) = NTYP+1         ADG031
         LI,R1    1                 SET TYPE BIT                        ADG032
         LCW,R2   R3                LOAD -I                             ADG0324
         SCS,R1   -3,R2                                                 ADG033
         AWM,R1   JTYPB                                                 ADG034
         STH,R5   *JDANC,R3         LNKC TO ANCHOR(I)                   ADG035
         B        ADG07                                                 ADG036
* LINK LNKL(I) TO LNKC TO TYPLNK(LNKL)                                  ADG04
ADG04    RES      0                                                     ADG040
         STH,V0   JDLST,R3          DECP/SUBF LAST = DECPC/SUBFC        ADG041
         B        ADG05+1                                               ADG042
* LINK TO LNKL(I)                                                       ADG05
ADG05    RES      0                                                     ADG050
         LH,R1    STBAS,R4          TLNKL = TYPLNK(LNKL)                ADG051
*                        R1 = TYPLNK(LNKL)                              ADG0511
         STH,R1   STBAS,R5          TLNKL TO TYPLNK(LNKC)               ADG052
* LINK TO LNKL(I)                                                       ADG06
ADG06    RES      0                                                     ADG060
*                        R4 = LNKL(I)                                   ADG0604
         STH,R5   STBAS,R4          LNKC TO TYPLNK(LNKL)                ADG061
* LNKC TO LNKL(I)                                                       ADG07
ADG07    RES      0                                                     ADG070
         STH,R5   JLNKL,R3          LNKC TO LNKL(I)                     ADG071
* LINKAGE COMPLETED                                                     ADG08
ADG08    RES      0                                                     ADG080
         MTH,CMI  *JDREF,R3         NREF(I) = NREF(I)+1                 ADG081
         MTB,CMI  JNREF             NREF = NREF+1                       ADG082
         STH,R3   JLSTI             SAVE LAST I                         ADG0824
* RETURN                                                                ADG083
         LCI      6                 RESTORE REGISTERS                   ADG084
         LM,R2    JDGSAV                                                ADG085
         B        *JDGSAV+6         RETURN                              ADG086
ADG09    RES      0                                                     ADG090
         B        ADG30           I=-2  INDEX                           ADG0901
         B        ADG10             -1  DESCENDING DECP                 ADG0902
         B        ADG10             0   ASCENDING DECP                  ADG0903
         LH,R4    JLNKL,R3          1   FLL                             ADG0910
         LH,R4    JLNKL,R3          2   FLS                             ADG0911
         LH,R4    JLNKL,R3          3   BIN                             ADG0912
         LH,R4    JLNKL,R3          4   AN/ANE                          ADG0913
         LH,R4    JLNKL,R3          5   GRP                             ADG0914
         LH,R4    JLNKL,R3          6   ZERO FILL NC/NE                 ADG0915
         LH,R4    JLNKL,R3          7   ZERO FILL ND                    ADG0916
         LH,R4    JLNKL,R3          8   ZERO FILL BIN                   ADG0917
         LH,R4    JLNKL,R3          9   SPACE FILL AN/ANE               ADG0918
         LH,R4    JLNKL,R3          10  SPACE FILL GRP                  ADG0919
* ND/NC DATA - NO SIGNIFICANCE CHECK                                    ADG10
ADG10    RES      0                                                     ADG100
         LH,R6    *JDREF,R3         CHECK NREF(I)                       ADG111
         BCS,CZ   ADG13             NREF(I) NOT= 0                      ADG112
         STH,V1   JSIZM,R3          SET SIZE MAX                        ADG113
* ANCHOR(I) = 0, 1ST ENTRY                                              ADG12
ADG12    RES      0                                                     ADG120
         STH,V0   JDLST,R3          SET DECP/SUBF LAST                  ADG121
         STH,V0   JDMAX,R3              DECP/SUBF MAX                   ADG122
         STH,V0   JDMIN,R3              DECP/SUBF MIN                   ADG123
         STH,R5   JLNKT,R3          SET LNKT                            ADG124
         B        ADG03             TO SET TYPE,ANCHOR(I)               ADG125
* DEC - NOT FIRST ENTRY                                                 ADG13
ADG13    RES      0                                                     ADG130
         CH,V0    JDMAX,R3          COMPARE DECP,DECP MAX               ADG131
         BCR,CL   ADG16             >/=, LINK TO LNKT(A)/ANCHOR(D)      ADG132
* DECPC < DECP MAX(I)                                                   ADG133
         LW,R1    V1                SIZC MAX = SIZC                     ADG134
         AH,R1    JDMAX,R3                   + DECP MAX(I)              ADG135
         SW,R1    V0                         - DECPC
         CH,R1    JSIZM,R3          COMPARE SIZC MAX,SIZE MAX(I)        ADG137
         BCR,CG   ADG14             </=, SIZE MAX(I)                    ADG138
         STH,R1   JSIZM,R3          SIZE MAX(I) = SIZC MAX              ADG139
* DECPC </= DECP MIN(I)                                                 ADG14
ADG14    RES      0                                                     ADG140
         CH,V0    JDMIN,R3          COMPARE DECPC,DECP MIN(I)           ADG141
         BCS,CG   ADG20             >, LINK INTO CHAIN                  ADG142
* ANCHOR(I) TO TYPLNK(LNKC), LNKC TO ANCHOR(I)                          ADG15
ADG15    RES      0                                                     ADG150
         EXU      ADG18+2,R3        TO LINK TO ANCHOR(A)/LNKT(D)        ADG151
         LH,R1    *JDANC,R3         ANCHOR(I) TO TYPLNK(LNKC)           ADG152
         STH,R1   STBAS,R5                                              ADG153
         STH,R5   *JDANC,R3         ANCHOR(I) = LNKC                    ADG154
* ** DECP/SUBF LAST NOT SET AT MAX/MIN ***
         B        ADG08                                                 ADG155
ADG16    RES      0                                                     ADG160
         LH,R1    JSIZM,R3          SIZC MAX = SIZE MAX(I)              ADG161
         AW,R1    V0                         + DECPC                    ADG162
         SH,R1    JDMAX,R3                   - DECP MAX(I)              ADG163
         STH,R1   JSIZM,R3          SIZE MAX(I) = SIZC MAX              ADG164
         CW,R1    V1                COMPARE SIZC MAX,SIZC               ADG165
         BGE      ADG17             >/=, SIZE MAX(I) = SIZC MAX         ADG166
         STH,V1   JSIZM,R3          <, SIZE MAX(I) = SIZC               ADG167
* LINK TO LNKT(I)                                                       ADG17
ADG17    RES      0                                                     ADG170
         EXU      ADG19+2,R3        TO LINK TO LNKT(A)/ANCHOR(D)        ADG171
         LH,R1    JLNKT,R3          LNKC TO TYPLNK(LNKT)                ADG172
         STH,R5   STBAS,R1                                              ADG173
         STH,R5   JLNKT,R3          LNKC TO LNKT(I)                     ADG174
* ** DECP/SUBF LAST NOT SET AT MAX/MIN ***
         B        ADG08                                                 ADG175
* EXU FOR DECP/SUBF MIN                                                 ADG18
ADG18    RES      0                                                     ADG180
         STH,V0   JDMIN,R3          DECP/SUBF MIN = DECPC/SUBFC         ADG181
         B        %+1               DESCENDING - DECP MIN = DECPC       ADG182
         STH,V0   JDMIN,R3          DECP/SUBF MIN = DECPC/SUBFC         ADG183
         B        ADG17+1           DESCENDING - LINK TO LNKT(I)        ADG184
* EXU FOR DECP/SUBF MAX                                                 ADG19
ADG19    RES      0                                                     ADG190
         STH,V0   JDMAX,R3          DECP/SUBF MAX = DECPC/SUBFC         ADG191
         B        %+1               DESCENDING - DECP MAX = DECPC       ADG192
         STH,V0   JDMAX,R3          DECP/SUBF MAX = DECPC/SUBFC         ADG193
         B        ADG15+1           DESCENDING - LINK TO ANCHOR(I)      ADG194
* LINK TO CHAIN - DECP MIN(I) < DECPC < DECP MAX(I)                     ADG20
ADG20    RES      0                                                     ADG200
         LH,R4    JLNKL,R3          LOAD LNKL(I)                        ADG201
         CH,V0    JDLST,R3          COMPARE DECPC,DECP LAST             ADG202
         BCR,CE   ADG05             =, LINK TO LNKL(I)                  ADG203
         BCS,CL   ADG23+1,R3        <, BRANCH ON I                      ADG204
* DECPC > DECP LAST                                                     ADG21
         EXU      ADG25+1,R3        >, EXECUTE ON I                     ADG211
* DESCENDING CHAIN SEARCH                                               ADG22
ADG22    RES      0                                                     ADG220
         LH,R1    STBAS,R4          TLNKL = TYPLNK(LNKL)                ADG221
         CH,V0    STBAS+4,R1        COMPARE DECPC,DECP(TLNKL)           ADG222
         BG       ADG04             >, INSERT LINKC
         LW,R4    R1                LNKL(I) = TLNKL                     ADG224
         B        ADG22             CONTINUE SEARCH
         B        ADG24-1           INDEX
ADG23    RES      0                                                     ADG230
         B        ADG22             DESCENDING - LNKL(I) SET, SEARCH    ADG231
         LH,R4    *JDANC,R3         ASCENDING - LNKL(I) = ANCHOR(I)     ADG232
* ASCENDING CHAIN SEARCH                                                ADG24
ADG24    RES      0                                                     ADG240
         LH,R1    STBAS,R4          TLNKL = TYPLNK(LNKL)                ADG241
         CH,V0    STBAS+4,R1        COMPARE DECPC,DECP(TLNKL)           ADG242
         BL       ADG04             <, INSERT LINKC
         LW,R4    R1                LNKL(I) = TLNKL                     ADG244
         B        ADG24             CONTINUE SEARCH                     ADG245
* EXU FOR DECPC > DECP LAST                                             ADG25
ADG25    RES      0                                                     ADG250
         LH,R4    *JDANC,R3         DESCENDING - LNKL(I) = ANCHOR(I)    ADG251
         B        ADG24             ASCENDING - LNKL(I) SET, SEARCH     ADG252
* INDEX                                                                 ADG30
ADG30    RES      0                                                     ADG300
         LH,R6    *JDREF,R3         CHECK NREF(I)                       ADG311
         BCR,CZ   ADG12             NREF(I) = 0, FIRST ENTRY            ADG312
* NOT FIRST INDEX NAME                                                  ADG32
         CH,V0    JDMAX,R3          COMPARE SUBF,SUBF MAX               ADG341
         BCR,CL   ADG17             >/=, LINK TO LNKT(I)                ADG342
* SUBF < SUBF MAX                                                        3
         CH,V0    JDMIN,R3          COMPARE SUBF,SUBF MIN               ADG326
         BCR,CG   ADG15             </=, LNKC TO ANCHOR(I)              ADG327
* SUBF MIN < SUBF < SUBF MAX                                             6
         B        ADG20             LINK INTO CHAIN                      7
* WRITE STACKED REFERENCES         "WSREF"                              ADH
*                        R3 = NREF-1                                    ADH0 3
*                        R6 = TYPE(=I)                                  ADH0 6
*                        R7 = NO. OF TYPES                              ADH0 7
*                        R4,R5,V1 VOLATILE                              ADH0 8
*                        JDREF = NREF(I) BASE                           ADH0 91
*                        JDANC = ANCHOR BASE                            ADH0 92
ADH00    RES      0                                                     ADH00
         STW,D0   JDREF             STORE WA(NREF)+1
         STW,D1   JDANC             STORE WA(ANCHOR)+1
         STW,L1   ADHSAV            SAVE LINK REGISTER                  ADH001
ADH02    RES      0                                                     ADH020
         LH,R5    *JDREF,R6         LOAD,CHECK NREF(I)                  ADH021
         BEZ      ADH06             NREF(I) = 0, NO TYPE I ENTRIES      ADH022
         SW,R3    R5                NREF = NREF-NREF(I)
         LH,R5    *JDANC,R6         LOAD ANCHOR(I)                      ADH024
*                        R5 = HA(CLOC)-(STKBAS+1)                       ADH04 5
ADH04    RES      0                                                     ADH040
         LW,R4    R5                LOAD,SET  HA(CLOC)                  ADH041
         AI,R4    HA(STBAS)+1                                           ADH042
         AW,R4    R4                HA(CLOC) TO BA                      ADH043
         BAL,L1   ADV00             RESOLVE VAR PARAM
         BAL,L1   WRMCF             WRITE OPERAND CLUSTER               ADH044
         LH,R5    STBAS,R5          LOAD,CHECK LNKC                     ADH045
         BNEZ     ADH04             NOT= 0, NOT E-O-CHAIN               ADH046
         STH,R5   *JDREF,R6         CLEAR NREF(I)                       ADH047
         MTB,15   JNTYP             NTYP = NTYP-1                       ADH048
ADH06    RES      0                                                     ADH060
         AI,R6    1                 I = I+1                             ADH061
         BDR,R7   ADH02             REDUCE NO. OF TYPES                 ADH082
* REQUIRED DATA CHAINS OUTPUT                                           ADH08
         B        *ADHSAV           RETURN                              ADH081
KHASTK   EQU      JAKON+32          HA(STKTOP)
JSTYP    EQU      JADAT             SEC TYPE,PNO,PDNO
JDECP    EQU      JADAT+4           DECP
JDSIZ    EQU      JADAT+5           DSIZ
JSFLD    EQU      JADAT+6           SFLD TYPE,CNTL
JDLST    EQU      JADAT+8           DECP/SUBF LAST
JDMAX    EQU      JADAT+10          *         MAX
JDMIN    EQU      JADAT+12          *         MIN
JLNKT    EQU      JADAT+14          *         LNKT
JSIZM    EQU      JADAT+15          SIZE MAX
JLNKL    EQU      JADAT+17          LAST LINK I
JTYPB    EQU      JADAT+24          TYPE BITS
JDREF    EQU      JADAT+25          WA(NREF)
JDIGN    EQU      JADAT+26          IGNORE OPTIONS
JLANC    EQU      JADAT+27          LIT ANCHOR
* JNLIT  EQU      JLANC+1H          NO. OF LIT.
JLSTI    EQU      JADAT+27          LAST REF(I)
JNREF    EQU      JADAT+28          TOTAL NO. OF DATA REFS
JDEXU    EQU      JADAT+28          TYPE EXU LOC
JDANC    EQU      JADAT+29          WA(ANCHOR)
JMOP     EQU      JADAT+30          ARITH OPTION
JIGNL    EQU      JADAT+X'32'
JDFSAV   EQU      JASAV             L0,L1
JNTYP    EQU      JASAV+1           NO. OF TYPES
JDGSAV   EQU      JASAV+2           R2-R7
ADHSAV   EQU      JASAV+24          L1
KHASTKL  DATA     HA(STBAS+392)     STACK LIMIT                         COBOL41O
         END
