         SYSTEM   SIG7FDP
         SYSTEM   BPM
         TITLE    'PHASE 4.2 - I/O'
* WRITE PROC                                                            APW
* LF     W---     R-,BA(CLOC)+/-BA OFFSET,RETURN                        APW 1
WPOF     CNAME    0                                                     APW00
         PROC                                                           APW03
         DO       NUM(AF(2))                                            APW11
LF       LI,R4    AF(2)             LOAD BA(CLOC)                       APW12
         ELSE                                                           APW13
         DO       NUM(AF(1))                                            APW132
LF       LW,R4    AF(1)             LOAD,SET HA(CLOC) TO BA             APW14
         AW,R4    R4                                                    APW15
         FIN                                                            APW16
         FIN                                                            APW17
         DO       NUM(AF(4))
         B        WRPOF             WRITE POF CLUSTER
         ELSE
         DO       NUM(AF(3))
         LI,L1     AF(3)
         B        WRPOF             WRITE POF CLUSTER                   APW841
         ELSE                                                           APW842
         BAL,L1   WRPOF             WRITE POF CLUSTER                   APW843
         FIN                                                            APW844
         FIN                                                            APW848
         PEND                                                           APW90
* LINK(OR LOAD) AND BRANCH PROC                                         APL
* LF     LAB,L/R  BRANCH ADDRESS,LINK ADDRESS(OR LOAD VALUE)            APL  1
LAB      CNAME                                                          APL01
         PROC                                                           APL04
LF       LI,CF(2) AF(2)             SET LINK REGISTER                   APL12
         B        AF(1)             BRANCH                              APL14
         PEND                                                           APL90
* LOAD,BRANCH AND LINK                                                  PRL
LBAL     CNAME    0                                                     PRL01
         PROC                                                           PRL02
* LF     LBAL,L-  BRANCH,LOAD VALUE,V-                                  PRL09
         DO       NUM(AF(3))                                            PRL20
         LI,AF(3) AF(2)             LOAD VALUE                          PRL22
         ELSE                                                           PRL23
         LI,V0    AF(2)             LOAD VALUE                          PRL24
         FIN                                                            PRL28
         DO       NUM(CF(2))                                            PRL40
         BAL,CF(2) AF(1)            BRANCH                              PRL42
         ELSE                                                           PRL43
         BAL,L1   AF(1)             BRANCH                              PRL44
         FIN                                                            PRL48
         PEND                                                           PRL99
* EXTERNAL REFERENCES
         REF      BAA02             RETURN
         REF      PIA00,PIA02,PIA06,PIA08,PIA20,PIA22,PIA26,PIA28
         REF      PII00,PII02,PII20,PII22
         REF      PIL00,PIL02,PIL06,PIL20,PIL22,PIL26
         REF      PID10,PID11,PID12,PID14,PID16,PID18
         REF      PIP00,PIP02,PIP20,PIP22
         REF      PIW02
         REF      PIX06
         REF      PIX08
         REF      PRA00,PRA01,PRA02,PRA04,PRA20,PRA21,PRA22,PRA24
         REF      PRB00,PRB02,PRB06,PRB20,PRB22,PRB26
         REF      PRE00,PRE01,PRE02,PRE20,PRE21,PRE22
         REF      PRF00,PRF02,PRF06
         REF      PRG00,PRG02,PRG06,PRG20,PRG22,PRG26
         REF      PRT00,PRT02,PRT06,PRT20,PRT22,PRT26
         REF      PDB00,PDB02,PDB06
         REF      PDD00,PDD01,PDD02,PDD03,PDD04,PDD06,PDD08
         REF      PDL10,PDL12,PDL16
         REF      PDX06
         REF      PPI10,PPI12
         REF      PIY00,PIY01,PIY02,PIY03
         REF      PIY20,PIY21,PIY22,PIY23
         REF      PIY30,PIY31,PIY32,PIY33
         REF      PIZ30,PIZ32
         REF      WRPOF
         REF      RDMCF
         REF      MCBUF
         REF      PDBS              NO. OF BYTES FOR BASE 4(HALF-WORD)
         REF      PDBX              LINE NO.                            AAC063
         REF      PDBZ              DDB ADCONS
         REF      BAA52
         REF      VRSAV
         REF      VARF,VPP20
*                                             +3 = WA(DBB BASE)
*                                             +4 = NO. OF DDB'S,
*                                                  WA(DBINDX)
         REF      GTMP              TEMP STG
         REF      GADNO             ADCON NO.
* REGISTER EQUIVALENCES
R0       EQU      0
R1       EQU      1
R2       EQU      2
R3       EQU      3
R4       EQU      4
R5       EQU      5
R6       EQU      6                                                     117
R7       EQU      7                                                     116
V0       EQU      8
V1       EQU      9
V2       EQU      10
L0       EQU      V2                                                    1212
L1       EQU      11                LINK REGISTER
D0       EQU      12                DECA
D1       EQU      13
D2       EQU      14
D3       EQU      15
RB       EQU      R4                BIN
* ** * FOR BEFORE/AFTER BIN LOAD ONLY ******
RF       EQU      V2                FILE CNTL
RE       EQU      4                 EVEN
RO       EQU      5                 ODD
RCC      EQU      D0                COMPLETION CODE REGISTER
LL       EQU      D3                LOOP LINK REGISTER
SR1      EQU      8                 SR1
SR3      EQU      X'A'              SR3
* BA(D-)                                                                CBD
CBD0     EQU      X'30'                                                 CBD0
CBD1     EQU      X'34'                                                 CBD1
CBD2     EQU      X'38'                                                 CBD2
CBD3     EQU      X'3C'
* INDEX REGISTERS                                                       CIR
CIR1     EQU      2                                                     CIR1
CIR2     EQU      4                                                     CIR2
CIR3     EQU      6                                                     CIR3
CIR4     EQU      8                                                     CIR4
CIR5     EQU      X'A'                                                  CIR5
CIR6     EQU      X'C'                                                  CIR6
CIR7     EQU      X'E'
* R REGISTERS
CRR1     EQU      X'10'                                                 CR01
CRR2     EQU      X'20'                                                 CR02
CRR3     EQU      X'30'                                                 CR03
CRR4     EQU      X'40'                                                 CR04
CRR5     EQU      X'50'                                                 CR05
CRR6     EQU      X'60'                                                 CR06
CRR7     EQU      X'70'                                                 CR07
CRV0     EQU      X'80'                                                 CR08
CRV1     EQU      X'90'                                                 CR09
CRV2     EQU      X'A0'                                                 CR10
CRL1     EQU      X'B0'                                                 CR11
CRL0     EQU      CRV2              ALTERNATE LINK
CRD0     EQU      X'C0'                                                 CR12
CRD1     EQU      X'D0'                                                 CR13
CRD2     EQU      X'E0'                                                 CR14
CRD3     EQU      X'F0'
CRE      EQU      X'40'             EVEN
CRO      EQU      X'50'             ODD
CRB      EQU      CRR4              BIN
* ** * FOR BEFORE/AFTER BIN LOAD ONLY ******
CRF      EQU      CRV2              FILE CNTL
CRCC     EQU      CRD0              COMPLETION CODE REGISTER
CRLL     EQU      CRD3              LOOP LINK REGISTER
CSR1     EQU      X'80'             SR1                                 CR3
CSR3     EQU      X'A0'             SR3                                 CR3
* OP CODES                                                              C0
CCAL1    EQU      X'0400'           CAL1                                C04
CLI      EQU      X'2200'           LI                                  C22
CSTW     EQU      X'3500'           STW                                 C35
CLW      EQU      X'3200'                                               C32
CMTW     EQU      X'3300'
CSTS     EQU      X'4700'           STS                                 C47
CEOR     EQU      X'4800'           EOR                                 C48
COR      EQU      X'4900'           OR                                  C49
CMTH     EQU      X'5300'
CSTH     EQU      X'5500'
CMBS     EQU      X'6100'           MBS                                 C61
CBDR     EQU      X'6400'                                               C64
CEXU     EQU      X'6700'                                               C67
CBR      EQU      X'6800'           B                                   C68
CBLE     EQU      X'6820'           BLE,BLEZ                            C682
CBEZ     EQU      X'6830'           BEZ                                 C683
CBAZ     EQU      X'6840'           BAZ                                 C684
CBL      EQU      X'6910'           BL                                  C691
CSTB     EQU      X'7500'                                               C75
CIND     EQU      X'8000'           INDIRECT BIT                        C900
CBAL     EQU      X'6AB0'                                               C691
CCW      EQU      X'3100'           CW                                  COBOL42C
R12      EQU      12                                                    COBOL42C
R13      EQU      13                                                    COBOL42C
ENDEDFLG EQU      X'20000'
         REF      PIX02
PIX04   EQU   PIX02+1
         TEXT     ':ERD'
         RES      3
DECREF   RES      0
         TEXT     ':BBF'
         TEXT     ':ABF'
         TEXT     ':BEF'
         TEXT     ':AEF'
         TEXT     ':BBR'
         TEXT     ':ABR'
         TEXT     ':BER'
         TEXT     ':AER'
BBDRSAVE RES      16                                                    COBOL42C
         REF      DECL%TBL                                              COBOL42C
XNO      DATA,2   0                                                     COBOL42C
PNO      DATA,2   0                                                     COBOL42C
DECLMDSV RES      1                                                     COBOL42C
DECLSVR4 RES      1
MODETBL  DATA,1   1,1,1,1,1,1,1,1,1  MODE IS INPUT
         DATA,1   2,2,2,2,2,2,2,2,2   MODE IS OUTPUT
         DATA,1   4,4,4,4,4,4,4,4,4   MOSE IS I/O
         BOUND    4
DDB%ADD  RES      1
GTPNTSV  RES      1
BBO40    EQU      BBO46                                                 COBOL42C
BBDCL98  EQU      BBDCL99
* POF CLUSTER CLNG,CNTL
* INSTRUCTION TYPE
DAIA     EQU      X'0401'           CONSTANT
DAID     EQU      X'0609'           DATA
DAII     EQU      X'0402'           INTERNAL LABEL
DAIL     EQU      X'0406'           LOC. CNTR
DAIP     EQU      X'0404'           PAR/SEC NAME
DAIX     EQU      X'0108'           XREF
* DATA REFERENCE
DARA     EQU      X'0410'           ADCONS
DARB     EQU      X'0417'           BRANCH TABLE
DARE     EQU      X'0415'           EXIT TABLE
DARF     EQU      X'41A'            FILE LABEL
* DATA DEF
DADB     EQU      X'0621'           BINARY
DADD     EQU      X'0829'           DATA REF
DADL     EQU      X'0626'           LOC. CNTR
DADX     EQU      X'0328'           EXTERNAL NAME
* DEFINITIONS/DECLARATIONS
DAPI     EQU      X'0341'           INTERNAL LABEL
* FILE CONTROL FLAGS                                                    CF
DFOL     EQU      X'0F'             OPEN LOCKED FILE ABN CODE           CF
DFCL     EQU      X'10'             LOCK                                CF010
DFCR     EQU      X'20'             REVERSED(=FPT WORD 1 REV BIT)       CF020
DFCS     EQU      X'10000'             SEEKED
DFTM     EQU      X'10000'          E-O-TAPE FLAG
DFTC     EQU      X'1C'             E-O-TAPE CODE
* ENTRY POINTS
         DEF      BBI00
*                                                                       BBR18
*                                                                       BBR18
* I/O
BBI00    RES      0                                                     BBI000
         CI,R6    X'FFF00'          CHECK FOR SORT I/O                  COBOL42C
         BE       BBI05             YES                                 COBOL42C
*                        D1 = WA(DDB-DDB BASE)
         LW,R7    PDBZ+3            LOAD,SET DDB INDEX                  BBI002
         AW,R7    D1
         STW,R7   DDB%ADD           SAVE  DDB  ADDRESS
         LW,D3    9,R7              LOAD DCB BASENO.
         AND,D3   K0FF                                                  BBI005
         LW,R3    1,R7              LOAD FILE STATS                     BBI022
         STW,D3   BBOSAV            SAVE DCB BASE
         SW,D3    K032              I: BASE = DCB BASE-50
         CI,R6    0                 CHECK OPTION
         BNE      BBI10             NOT= 0, I/O OPERATION
* RERUN
         AI,D3    X'C'              I: = I:+3
         STW,D3   JAIDW+2
         LBAL     PIW02,CMTW+X'10'  WRITE MTW,1  I:+3
         LBAL     PIW02,CLW+CRL1    WRITE LW,L1  I:+3
         AI,D3    4                 I:+3 = I:+4
         BAL,L1   PID16             WRITE
         SW,L1    2                 ****  SW,L1  I:+4
         LH,D1    2,R5              LOAD,CHECK NEXT STMT INTL NO.
         BEZ      BBI02             = 0, FALL THRU
* NOT FALL THRU
         LI,V0    CBL               LOAD BL
         LAB,L1   PII02,BBI04       WRITE BL N.S.
* FALL THRU
BBI02    RES      0
         BAL,L1   PIL06             WRITE
         BL       3                 ****  BL  %+3
BBI04    RES      0
         LBAL     PIW02,CSTW+CRL1   WRITE STW,L1  I:+3
         BAL,L1   PIX06             WRITE
         TEXT     ':CKP'            ****  BAL,L1  C:CKP
         B        BAA02
BBI05    RES      0                                                     COBOL42C
         MTW,1    CRSF              SET SORT FLAG                       COBOL42C
         B        BAA02             GET NEXT CLUSTER                    COBOL42C
CRSF     DATA     0                                                     COBOL42C
* I/O OPERATION
BBI10    RES      0
         STW,D3   JAIDW+2           STORE I:
         STW,R7   BBOSAV+1          SAVE WA(DDB)
         AW,D3    K032              RESTORE DCB BASE
         CI,R6    X'400'            CHECK OPTION                        BBI102
         BGE      BBI80             READ/WRITE                          BBI103
         CI,R6    X'100'                                                BBI106
         BL       BBO00             OPEN                                BBI107
         BG       BBQ00             CLOSE                               BBI108
*                        R3 = FILE STATS                                BBI15 1
*                        R6 = OPTIONS                                   BBI15 4
*                        R7 = WA(DDB)                                   BBI15 5
*                        D3 = DCB BASE NO.                              BBI15 9
* SEEK                                                                  BBI18
         MTW,4    JAIDW+2           SET I: TO I: +1
         LBAL,L0  BBI30+1,CSTS+CRR1 RAISE SEEKED FLAG
         LI,R1    DFCS              WRITE LI,R1   SEEKED FLAG
*                                   ****  STS,R1 FILE CNTL
         LI,L0    BAA02             SET LINK REGISTER                   BBI188
*                                                                       BBI2
* MOVE KEY TO KEY AREA                                                  BBI20
*                        R7 = WA(DDB)                                   BBI20 7
*                        L0 = LINK REGISTER                             BBI20 8
*                        V0,D0,D1,D2,D3 VOLATILE                        BBI20 9
BBI20    RES      0                                                     BBI200
         LW,D3    4,R7              LOAD KEY BASE NO.,DISPL             BBI202
         LW,V0    1,R7              CHECK                               COBOL42C
         LB,V0    V0                    FIELD V                         COBOL42C
         AND,V0   =X'3C'                                                COBOL42C
         CI,V0    X'28'                 FOR DISC-R                      COBOL42C
         BNE      BBI201            NO. GO ON                           COBOL42C
         BAL,L1   PID16             YES. WRITE                          COBOL42C
         LW,15    2                     *** LW,15 WA(KEY)               COBOL42C
         B        *L0               ***EXIT***                          COBOL42C
BBI201   RES      0                                                     COBOL42C
         BAL,L1   PID16             WRITE                               BBI204
         LI,RE    0                 **** LI,RE BA(KEY)                  BBI205
         LW,D1    3,R7              LOAD KEY AREA, MBS RO ADCON(WA)     BBI222
         LBAL     PRA02,CLW+CRO     WRITE LW,RO ADCON                   BBI224
         BAL,L1   PIA06             WRITE                               BBI242
         MBS,RE   0                 **** MBS,RE 0                       BBI243
         B        *L0               RETURN                              BBI264
*                        V0 = OP CODE - OR/STW,R2                       BBI3 4
*                        D3 = FILE CNTL CONSTANT                        BBI3 7
*                        L0 = LINK REGISTER                             BBI3 8
*                        V0,D0,D2,D3 VOLATILE                           BBI3 9
* SET FILE CNTL FLAGS                                                   BBI30
BBI30    RES      0                                                     BBI300
         LI,V0    CSTW+CRF          LOAD OP CODE - STW,RF               BBI302
         LW,D3    *L0               LOAD ABS. INSTRUCTION               BBI304
         AI,L0    1                 SET LINK REGISTER                   BBI306
BBI32    RES      0                                                     BBI320
         LBAL     PRA24+1,DAIA,D2   WRITE LI,RF OPTION
         BAL,L1   PIW02             WRITE STW/OR,RF FILE CNTL
         B        *L0               RETURN                              BBI368
IS       CNAME                                                          COBOL42C
STARTS   CNAME                                                          COBOL42C
DEFINED  CNAME                                                          COBOL42C
         PROC                                                           COBOL42C
LF       EQU      %                                                     COBOL42C
         PEND                                                           COBOL42C
         PAGE                                                           COBOL42C
* THIS ROUTINE CHECKS A DDB FOR THE PRESENCE OF A DECLARATIVE LINK BYTE.COBOL42C
* IF THE BYTE IS PRESENT (NON-ZERO), THE APPROPRIATE DECLARATIVE        COBOL42C
* LINKAGE IS GENERATED.                                                 COBOL42C
*        R3= FILE HISTORY           R4 =  INDEX TO DECLARATIVE BYTE     COBOL42C
*        R6= CURRENT OPTIONS        R7 =  WORD ADDRESS OF DDB           COBOL42C
*        R1                         R11=  RETURN ADDRESS                COBOL42C
*                                                                       COBOL42C
BBDCL00  IS       HERE                                                  COBOL42C
         LCI      0                 SAVE REGISTERS                      COBOL42C
         STM,0    BBDRSAVE                                              COBOL42C
         AI,R7    6                SIXTH WORD OF DDB
         LB,R1    *R7,R4             IS THER A DECLARATIVE
         BEZ      BBDCL99              NO
         CI,R1    27                DO WE HAVE FILE OPTION
         BL       MODEDCL            NO
         BAL,L1   GENBLOCK              GENERATE   DECL BLOCK
         B        BBDCL99            EXIT
MODEDCL  RES      0
         AND,R1   L(X'1')            CHECK FOR INPUT MODE
         BEZ      %+2             NO INPUT
         BAL,L1   GENPOINT
         LB,R1    *R7,R4
         AND,R1   L(X'2')             CHECK FOR OUTPUT MODE
         BEZ      %+2             NO OUTPUT MODE
         BAL,L1   GENPOINT
         LB,R1    *R7,R4
         CI,R1    4               CHECK FOR I/O MODE
         BAZ      BBDCL99           NO I/O
         LI,R1     3
         BAL,L1   GENPOINT
BBDCL99  IS       HERE                                                  COBOL42C
         LCI      0                 RESTORE REGISTERS                   COBOL42C
         LM,0     BBDRSAVE                                              COBOL42C
         B        *BBDRSAVE+11      *** EXIT ***                        COBOL42C
GENPOINT RES      0
         STW,L1   GTPNTSV              SAVE RETURN REGISTER
         CI,R6    X'220'             IS THIS CLOSE REEL/UNIT
         BNE      GENPNT1            NO
         CI,R1    2               IS THIS MODE OUTPUT
         BE       GENPNT1             YES
         CI,R4    6                    IS DECL BER/AER
         BL       GENPNT1                 NO
         B        *GTPNTSV         YES EXIT
GENPNT1  RES      0
         CI,R4    -4              ERROR DECLARATIVE
         BNE      %+2                NO
         LI,R4    8                 CHANGE  POINTER
         AI,R1    -1          CHANGE TO 0/1/2
         MI,R1    9         MULT BY NO OF ENTRIES
         AW,R1    R4
         BAL,L1   GENBLOCK           GEN DECL BLOCK
         B        *GTPNTSV
GENBLOCK RES      0
         STW,L1   DECLMDSV
         LW,R4    BBDRSAVE+4          RESTORE R4
         CI,R6    X'220'       IS IT CLOSE UNIT /REEL
         BNE      DECLMOD1         NO
         CI,R3    1                    IS IT OPEN INPUT
         BAZ      DECLMOD1               NO
         CI,R4    6                IS IT BER OR AER
         BL       DECLMOD1               NO
         LI,R12   2
         B        DECLMOD2
DECLMOD1 RES      0
         CI,R1    26                IF FILE-NAME, NO CHECK REQUIRED     COBOL42C
         BG       DECLMODX           SO GET OUT                         COBOL42C
         LB,R12   MODETBL,R1        CONVERT DECL. DISP TO MODE          COBOL42C
         CI,R6    X'100'
         BGE      NOT%OPEN
         CW,R12   R6           DO WE WANT DECLARATIVES
         BAZ      DECLEXT            NO
         B        DECLMODX             YES
NOT%OPEN RES      0
         AND,R12  R3
         BEZ      DECLEXT
         LI,R13   7                 IF ONLY OPENED                      COBOL42C
         CS,R12   R3                 IN THE DESIRED MODE                COBOL42C
         BE       DECLMODX           GET OUT                            COBOL42C
DECLMOD2 RES      0
         AW,R12   =X'22600000'                                          COBOL42C
         STW,R12  DECLMLI                                               COBOL42C
         BAL,L1   PIA06             WRITE                               COBOL42C
DECLMLI  LI,R6    0                  *** LI,R6    OPTION                COBOL42C
         MTW,4    JAIDW+2           WRITE                               COBOL42C
         LBAL     PIW02,CCW+CRR6     *** CW,R6    I: +1                 COBOL42C
         MTW,-4   JAIDW+2           RESTORE I: ADDRESS                  COBOL42C
         BAL,L1   PIL06
         BAZ      4
DECLMODX IS       HERE                                                  COBOL42C
         LW,R4    BBDRSAVE+4          RESTORE R4
         LW,V0    *DECL%TBL,R1        GET PNO XNO
         STW,V0   PNO                SAVE IT
         LW,V0    DECREF,R4         GET EXTERNAL REF NAME
         BAL,L1   PIX04             WRITE *** BAL,11 C: DECL SETUP      COBOL42C
         LH,D1    XNO               WRITE                               COBOL42C
         BAL,L1   PRE00              *** LW,11 XNO                      COBOL42C
         LW,D3    PNO               WRITE                               COBOL42C
         BAL,L1   PIP20              *** BAL,11 PNO                     COBOL42C
DECLEXT  RES      0
         LW,R4    BBDRSAVE+4               RESTORE R4
         B        *DECLMDSV
* READ/WRITE                                                            BBI8
BBI80    RES      0                                                     BBI800
*                        R3 = FILE STATS                                BBI8003
*                        R7 = WA(DDB)                                   BBI8005
*                        D3 = DCB BASE NO.,DISPL(=0)                    BBI8009
         CI,R6    X'1000'           CHECK STMT OPTION                   BBI842
         BAZ      BBI90
* WRITE
BBI84    RES      0
*                        R6 = STATEMENT OPTIONS                         COBOL42C
         BAL,L1   BAA52             SAVE VAR FLAG
BBI90    RES      0                                                     BBI900
         CI,R3    X'400'            CHECK ACTUAL KEY FLAG
         BAZ      BBI94             DOWN, NOT KEYED
* KEYED FILE                                                            BBI92
         CI,R3    X'100'            CHECK SEEK FLAG                     BBI924
         BAZ      BBI92             DOWN. NOT SEEKED.
* SEEKED FILE                                                           BBI94
         MTW,4    JAIDW+2           2: = I:+1
         LBAL     PIW02,CLW+CRF     WRITE ****    LW,RF FILE CONTROL
         BAL,L1   PIA06             WRITE                               BBI942
         CI,RF    DFCS              ****  CI,RF SEEKED FLAG             BBI943
         BAL,L1   PIL06             WRITE                               BBI944
         BAZ      4                 **** BAZ %+4                        BBI945
* SEEKED                                                                BBI95
         LW,D1    V1                LOAD FILE CNTL ADCON NO.            BBI952
         BAL,L0   BBI30             WRITE                               BBI953
         AI,RF    -DFCS             ****  AI,RF -SEEKED FLAG            BBI954
*                                         STW,RF FILE CNTL              BBI955
         BAL,L1   PIL06             WRITE                               BBI956
         B        4                 **** B %+4                          BBI957
         MTW,-4   JAIDW+2           I:+1 = I:
BBI92    RES      0
         BAL,L0   BBI20             WRITE KEY TO KEY AREA               BBI962
         LW,D3    BBOSAV            RESTORE DCB BASE NO.
*                                                                       BBI98
BBI94    RES      0
         LI,L1    BBI940            SET RETURN ADDRESS                  COBOL42C
         LI,R4    8                 GENERATE                            COBOL42C
BBI940   IS       HERE               BEFORE/AFTER                       COBOL42C
         CI,R4    4                  BEGINNING/ENDING                   COBOL42C
         BE       BBI9401            REEL DECLARATIVES LINKAGES         COBOL42C
         BDR,R4   BBDCL00            IF NEEDED                          COBOL42C
BBI9401  IS       HERE                                                  COBOL42C
         LI,R4    -4                GENERATE ERROR DECLARATIVE LINKAGE  COBOL42C
         BAL,L1   BBDCL00            IF NEEDED                          COBOL42C
         SW,D3    K064              RECORD BASE = DCB BASE-100
         CI,R6    X'1000'           CHECK STMT OPTION
         BANZ     BBW00             WRITE STMT                          BBI993
* READ
         LI,SR1   CLI+CRR6          WRITE
         BAL,L1   PIW02             *****    LI,6 I:
         LW,L1    CRSF              IS SORT FLAG SEY                    COBOL42C
         BNEZ     BBI1949           YES                                 COBOL42C
         AI,R7    5                 *
         LB,R1    *R7               *
         BNEZ     BBI1950           *
         AI,R7    1                 *  IF WE HAVE DECLARATIVES
         LW,R1    *R7               *      BRANCH
         BNEZ     BBI1950           *
         AI,R7    1                 *
         LW,R1    *R7               *
         BNEZ     BBI1950           *
         BAL,L1   PIX06             WRITE                               COBOL42C
         TEXT     ':RLR'            ****  BAL,L1 L:RLR
         B        BBI1951
BBI1949  RES      0                                                     COBOL42C
         BAL,L1   PIX06                                                 COBOL42C
         TEXT     ':RSR'            BAL,L1   C:RSR                      COBOL42C
         LI,L1    0                                                     COBOL42C
         STW,L1   CRSF                                                  COBOL42C
         B        BBI1951                                               COBOL42C
BBI1950  BAL,L1   PIX06
         TEXT     ':RLD'
BBI1951  RES      0
         LI,R1    1                 LOAD INPUT FLAG                     82
         LH,R7    2,R5              LOAD NEXT STMT INTL NO.
         LH,D1    2,R2              LOAD INTL NO.                       BBR202
         CI,R6    1                 CHECK INTO FLAG                     BBR204
         BAZ      BBR22             DOWN. NOT READ INTO                 BBR205
* READ INTO/WRITE...INVALID KEY                                         BBR21
BBR21    RES      0                                                     BBR210
*                        D1 = INTL NO.                                  BBR2109
         BAL,L1   PII00             WRITE B INTO LABEL
         AI,D1    1                 INTL NO. = INTL NO.+1               BBR214
         B        BBR24                                                 BBR218
*                                                                       BBR22
BBR22    RES      0                                                     BBR220
         CI,R3    X'40'             CHECK RERUN FLAG
         BANZ     BBR21             UP. RERUN
* NO RERUN
         LH,D3    2,R5              LOAD NEXT STMT INTL NO.             BBR222
         BAL,L1   PII20             WRITE B NEXT STMT
*                                                                       BBR24
BBR24    RES      0                                                     BBR240
*                        D1 = AT END/INV. KEY INTL NO.                  BBR2409
         LAB,L1   PII00,BAA02       WRITE B AT END/INVALID KEY THEN EXITCOBOL42C
* WRITE                                                                 BBW00
BBW00    RES      0                                                     BBW000
         LW,V1    D3                SAVE RECORD BASE
         LI,SR1   CLI+CRR6+2        WRITE
         BAL,L1   PIW02             *****     LI,6 I:
         LH,R7    2,R5              LOAD NEXT STMT INTL NO.             BBW006
         CI,R6    X'F00'            CHECK BEFORE/AFTER OPTION           BBW022
         BAZ      BBW66             DOWN. NO BEFORE/AFTER               BBW023
* BEFORE/AFTER OPTION                                                   BBW03
         CI,R6    X'300'            CHECK BEFORE/AFTER FIELD TYPE       BBW032
         BAZ      BBW54             MNAM/INTEGER </= 16 LINES           BBW033
* BEFORE/AFTER DNAM/INTEGER (>16) LINES                                 BBW04
         CI,R7    0                 CHECK NEXT STMT INTL NO.            BBW042
         BNE      BBW05             NOT= 0, INVALID KEY OPTION          BBW043
*                                                                       BBW0439
         LH,R7    2,R2              NEXT STMT INTL NO. = INTL NO.+2     BBW044
         AI,R7    2                                                     BBW045
BBW05    RES      0                                                     BBW050
         CI,R6    X'200'            CHECK DNAM FLAG                     BBW052
         BAZ      BBW48             DOWN. B/A INTEGER(>16) LINES        BBW053
* BEFORE/AFTER DNAM LINES                                               BBW06
* **                     BINARY VALUE OF DNAM IN RB                     BBW06 9
         CI,R6    X'400'            CHECK BEFORE FLAG                   BBW062
         BAZ      BBW18             DOWN. AFTER DNAM LINES              BBW063
* BEFORE DNAM LINES                                                     BBW08
BBW08    RES      0                                                     BBW080
         LI,L0    BBW20             SET LINK REGISTER
         LI,R6    0                 RAISE B/A DNAM/INTEGER FLAG         BBW081
         BAL,L1   PIA26             WRITE                               BBW082
         LI,R3    X'60'             ****     VFC CHAR. - NO ADVANCING   BBW083
         BAL,L1   BBW32             WRITE LI,R2 BSIZ                    BBW084
         BAL,L1   BBW90
         BAL,L0   *L0               WRITE VALUE TEST,SET VFC INDICES
*                                   *  OR FALL THRU
* BEFORE DNAM/INTEGER LINES                                             BBW10
BBW10    RES      0                                                     BBW100
         BAL,L1   PIL06             WRITE                               BBW104
         BAL,LL   5                 ****  BAL,LL  %+5
         BAL,L1   PIA28             WRITE                               BBW112
         LI,R2    1                 ****     LOAD SIZE(=1,VFC ONLY)     BBW113
         LW,D3    V1                LOAD RECORD BASE NO.,DISPL(=0)      BBW114
         BAL,L1   PID16             WRITE                               BBW116
         STB,R1   2                 ****  STB,R1 RECORD                 BBW117
*                        D0 = LCREF CLNG,CNTL                           BBW1208
         BAL,L1   PIA08             WRITE                               BBW122
         BAL,LL   3                 ****  BAL,LL  %+3
         BAL,L1   PIA06             WRITE                               BBW124
         LI,R3    X'CF'             ****     VFC TO MAX ADVANCE VALUE   BBW125
         LH,D1    2,R2              LOAD INTL NO                        BBW126
         BAL,L1   PPI12             WRITE INTL DEF
         MTH,1    2,R2              INTL NO. = INTL NO.+1               BBW128
*                                                                       BBW14
*                        D3 = RECORD BASE NO.,DISPL(=0)                 BBW1409
         LAB,V0   BBW36,CSTB+CRR3   WRITE STB,R3 RECORD
*                                   ****     I/O CALL,TEST
* AFTER DNAM LINES                                                      BBW18
BBW18    RES      0                                                     BBW180
         LI,L0    BBW26             SET LINK REGISTER                   BBW182
*                                                                       BBW2
* TEST DNAM VALUE, SET WRITE LOOP REGISTERS                             BBW20
BBW20    RES      0                                                     BBW200
*                        L0 = LINK REGISTER                             BBW2008
*                        R6 VOLATILE                                    BBW2009
         STW,L0   BBWSAV            SAVE LINK REGISTER                  BBW202
         LH,D1    2,R2              LOAD INTL NO.                       BBW205
         BAL,L1   PIA26             WRITE
         CI,RB    0                 ****     CHECK DATA VALUE
         LBAL     PII02,CBLE        WRITE  BLE  INTL
         BAL,L1   PIA26             WRITE                               BBW222
         AI,RB    X'F'              ****     I = I-1+X'10'              BBW223
         LBAL,L0  PIZ30,-4,R1       WRITE                               BBW242
         LI,R1    X'F'              ****     MASK,FORM VFC CHAR.        BBW243
         AND,R1   RB                ****                                BBW244
         AI,R1    X'C0'             ****                                BBW245
         SLS,RB   -4                ****     I = I/16                   BBW246
         B        *BBWSAV           RETURN/FALL THRU                    BBW248
* AFTER DNAM/INTEGER LINES                                              BBW26
BBW26    RES      0                                                     BBW260
*                        R4 = BA(D2)+2                                  BBW2604
*                        D2 = ABS VAL CLNG,CNTL                         BBW2608
         LI,R6    0                 RAISE B/A DNAM/INTEGER FLAG         BBW261
         BAL,L1   PIA26             WRITE
         LI,R2    1                 ****     BSIZ = 1(FORMAT ONLY)      BBW263
         BAL,L1   PIL06             WRITE                               BBW264
         BAL,LL   5                 ****  BAL,LL  %+5
         BAL,L1   PIA28             WRITE                               BBW282
         LI,R1    X'CF'             ****     VFC TO MAX ADVANCE VALUE   BBW283
         BAL,L1   PIA08             WRITE                               BBW284
         B        3                 ****  B  %+3
         LH,D1    2,R2              LOAD INTL NO.                       BBW286
         BAL,L1   PPI12             WRITE INTL DEF
         MTH,1    2,R2              INTL NO. = INTL NO.+1               BBW288
*                                                                       BBW30
BBW30    RES      0                                                     BBW300
*                        L0 = LINK REGISTER                             BBW3009
         LI,L0    BBW33             SET LINK REGISTER                   BBW301
         BAL,L1   PIA26             WRITE                               BBW302
         LI,R1    X'60'             ****     VFC CHAR. - NO ADVANCING   BBW303
         AI,L1    5                 SET LINK REGISTER
BBW32    RES      0                                                     BBW320
*                        R4 = BA(D2)+2                                  BBW3204
*                        D2 = ABS VAL CLNG,CNTL                         BBW3208
*                        L1 = LINK REGISTER                             BBW3209
         LH,D3    4,R5              LOAD BSIZ                           BBW322
         LAB,V0   PIY03,CLI+CRR2    WRITE LI,R2 BSIZ                    BBW324
         BAL,L1   BBW90
         B        *L0               RETURN/FALL THRU                    BBW326
BBW33    RES      0                                                     BBW330
*                                                                       BBW34
*                        V1 = RECORD BASE NO.,DISPL(=0)                 BBW3407
*                        L0 = LINK REGISTER                             BBW3409
         LI,V0    CSTB+CRR1         LOAD OP CODE - STB,R1               BBW342
         LW,D3    V1                LOAD RECORD BASE NO.,DISPL(=0)      BBW344
BBW36    RES      0                                                     BBW360
*                        V0 = OP CODE - STB,R1/R3                       BBW3606
*                        D3 = RECORD BASE NO.,DISPL(=0)                 BBW3607
*                        R6 = 0 - B/A DNAM/INTEGER(>16) LINES           BBW3806
*                           > 0 - B/A MNAM/INTEGER(</=16) LINES         BBW3807
* ***                    R2 = RSIZ
         LAB,L1   PID11,BBW70       WRITE STB,R1/R3 RECORD
*                                   ****  I/O CALL
* BEFORE/AFTER INTEGER (>16) LINES                                      BBW48
*                        R7 = NEXT STMT INTL NO.                        BBW48 7
BBW48    RES      0                                                     BBW480
         CI,R6    X'400'            CHECK BEFORE FLAG                   BBW502
         BAZ      BBW26             DOWN. AFTER INTEGER LINES           BBW503
*                                   *     (SAME AS AFTER DNAM LINES)    BBW504
* BEFORE INTEGER LINES                                                  BBW52
         LAB,L0   BBW08+1,BBW10                                         BBW522
*                                   *     (SAME AS BEFORE DNAM LINES)   BBW523
* BEFORE/AFTER MNAM/INTEGER(</=16) LINES                                BBW54
BBW54    RES      0                                                     BBW540
         LI,D1    X'FF'             MASK VFC CHAR.                      BBW542
         AND,D1   R6                                                    BBW543
         CI,R6    X'1F'             CHECK VALUE                         BBW544
         BANZ     BBW56             NOT= HEX 60/E0/40/C0                BBW545
* VALUE = HEX 60/E0/40/C0                                               BBW55
         CI,R6    X'420'            CHECK FOR SEPARATE ADVANCE          BBW546
         BANZ     BBW64             NO. SEPARATE ADVANCE NOT REQUIRED.  BBW547
* SEPARATE ADVANCE REQUIRED                                             BBW56
BBW56    RES      0                                                     BBW560
         CI,R6    X'400'            CHECK BEFORE FLAG                   BBW562
         BAZ      BBW60             DOWN.AFTER OPTION                   BBW563
* BEFORE MNAM/INTEGER(</=16) LINES                                      BBW58
         BAL,L0   BBW30+1           WRITE LI,R1 X'60'                   BBW582
*                                   *     LI,R2 BLNG                    BBW583
         BAL,L0   BBW62+1           WRITE BAL,LL %+4
*                                   ****  LI,LL  N.S
         LAB,L0   BBW60+1,BBW33     WRITE LI,R1 VFC CHAR.               BBW586
*                                   *     LI,R2 1                       BBW587
*                                                                       BBW6
* AFTER MNAM/INTEGER(</=16) LINES                                       BBW60
BBW60    RES      0                                                     BBW600
         LI,L0    BBW62             SET LINK REGISTER                   BBW601
         LBAL     PIA02,CLI+CRR1    WRITE LI,R1 VFC CHAR                BBW602
         BAL,L1   PIY31             WRITE                               BBW604
         LI,R2    1                 ****     DSIZ = 1(FORMAT ONLY)      BBW605
         B        *L0               RETURN/FALL THRU                    BBW614
BBW62    RES      0                                                     BBW620
         LI,L0    BBW30             SET LINK REGISTER                   BBW621
         BAL,L1   PIL26             WRITE                               BBW622
         BAL,LL   4                 ****  BAL,LL  %+4
         LH,D3    2,R2              LOAD INTL NO.
         CI,R7    0                 CHECK N.S. INTL NO.
         BEZ      BBW63             =0, NO INVALID KEY
* INVALID KEY
         CI,R3    X'40'             CHECK RERUN FLAG
         BANZ     BBW63             UP. RERUN
* NO RERUN
         LW,D3    R7                LOAD N.S. INTL NO.
BBW63    RES      0
         LBAL     PII22,CLI+CRLL    WRITE LI,LL  N.S
         B        *L0               RETURN                              BBW634
* BEFORE/AFTER MNAM/INTEGER(</=16) LINES - NO SEPARATE ADVANCE          BBW64
BBW64    RES      0                                                     BBW640
         LBAL     PIA02,CLI+CRR1    WRITE LI,R1 VFC CHAR                BBW642
         LW,D3    V1                LOAD RECORD BASE NO.,DISPL          BBW643
         BAL,L1   PID16             WRITE                               BBW644
         STB,R1   2                 ****  STB,R1 RECORD
*                                                                       BBW65
* NORMAL WRITE                                                          BBW66
BBW66    RES      0                                                     BBW660
         LI,R6    0                 SET NORMAL WRITE CODE               BBW662
         LH,D1    4,R5              LOAD RSIZ
         LBAL     PIA02,CLI+CRR2    WRITE LI,R2 RSIZ
         LI,V0    R2
         BAL,L0   VPP20             RESOLVE VAR REC
         CI,R7    0                 CHECK NEXT STMT INTL NO.            BBW664
         BEZ      BBW71             =/, NOT INVALID KEY                 COBOL42C
         LI,R6    -1                SET INVALID KEY FLAG                BBW666
BBW70    RES      0                                                     BBW700
*                        R3 = FILE STATS
*                        R6 = 0 - NORMAL EXIT TO INTL                   BBW7001
*                           > 0 - NORMAL EXIT TO *L1                    BBW7002
*                           < 0 - NORMAL EXIT TO NEXT STMT              BBW7003
*                        R7 = DECLA. BRANCH FLAG(=0/N.S. INTL NO.)      BBW7005
*                        L0 = LINK REGISTER                             BBW7008
* ***                    R2 = RSIZ
BBW72    RES      0
         LW,L1    CRSF              IS SORT FLAG SET                    COBOL42C
         BNEZ     BBW731            YES                                 COBOL42C
         MTW,5    DDB%ADD           *
         LB,R1    *DDB%ADD          *
         BNEZ     BBW73             *
         MTW,1    DDB%ADD           *  IF WE HAVE DECLARATIVES
         LW,R1    *DDB%ADD          *       BRANCH
         BNEZ     BBW73             *
         MTW,1    DDB%ADD           *
         LW,R1    *DDB%ADD          *
         BNEZ     BBW73             *
         BAL,L1   PIX06             WRITE
         TEXT     ':WLR'            ****  BAL,L1 L:WLR
         B        BBW74
BBW71    RES      0                                                     COBOL42C
         CI,R3    X'400'            ACTUAL KEY DEFINED                  COBOL42C
         BAZ      BBW70             NO. AOK                             COBOL42C
         REF      DIAG               YESS ... OH OH                     COBOL42C
         LI,1     152               YOU CAN'T DO THAT                   COBOL42C
         BAL,11   DIAG                 TELL IT LIKE  IT IS              COBOL42C
         B        BBW70                                                 COBOL42C
BBW731   RES      0                                                     COBOL42C
         BAL,L1   PIX06                                                 COBOL42C
         TEXT     ':WSR'            BAL,L1   C:WSR                      COBOL42C
         LI,L1    0                                                     COBOL42C
         STW,L1   CRSF                                                  COBOL42C
         B        BBW74                                                 COBOL42C
BBW73    BAL,L1   PIX06
         TEXT     ':WLD'
BBW74    RES      0
         LH,D1    2,R2              LOAD INTL NO.                       BBW742
         LI,R1    2                 LOAD OUTPUT FLAG                    93
         CI,R6    0                 CHECK WRITE STMT TYPE               BBW744
         BE       BBW78             =0,WRITE(B/A DNAM/INTEGER(>16)LINES)BBW745
         BL       BBR22             < 0, NORMAL WRITE W/ INVALID KEY
* WRITE B/A MNAM/INTEGER(</=16) LINES                                   BBW76
         BAL,L1   PIA26             WRITE                               BBW762
         B        *LL               ****     TO N.S./FINAL WRITE
         CI,R3    X'40'             CHECK RERUN FLAG
         BAZ      BBW82             DOWN. NO RERUN
         B        BBW80                                                 BBW766
* WRITE(B/A DNAM/INTEGER(>16) LINES)                                    BBW78
BBW78    RES      0                                                     BBW780
         BAL,L1   PII00             WRITE B INTL                        BBW784
*                                                                       BBW80
BBW80    RES      0                                                     BBW800
         AI,D1    1                 INTL NO. = INTL NO.+1
         CI,R3    X'40'             CHECK RERUN FLAG
         BAZ      BBW82             DOWN. NO RERUN.
* RERUN
         CI,R7    0                 CHECK NEXT STMT INTL NO.
         BNEZ     BBW82             NOT= 0. NO FALL THRU.
* FALL THRU
         LW,R7    D1                SET NEXT STMT INTL NO.
*                        R7 = 0/NEXT STMT INTL NO.
*                        D1 = INVALID KEY INTL NO.
BBW82    RES      0
         LH,D3    2,R5              LOAD,CHECK NEXT STMT INTL NO.       BBW802
         BNEZ     BBR24             NOT= 0, INVALID KEY                 BBW803
* NO INVALID KEY OPTION                                                 BBW82
         BAL,L1   PIA26             WRITE                               BBW822
         B        *L1               ****     RETURN TO C:ABA/ERA        BBW823
         B        BAA02             *** EXIT ***                        COBOL42C
BBW90    STD,L0   VRSAV
         LI,V0    R2
         BAL,L0   VPP20             RESOLVE VAR REC
         LD,L0    VRSAV
         B        *L1
*                        L0 = LINK REGISTER                             BBW8268
* OPEN                                                                  BBO0
*                        D3 = DCB BASE NO.                              BBO00 9
BBO00    RES      0                                                     BBO000
         STW,R7   BBOSAV+1          SAVE WA(DDB)
         LI,R4    1                 GENERATE AFTER BEGINNING FILE DECL. COBOL42C
         BAL,L1   BBDCL00            LINKAGE IF NEEDED                  COBOL42C
         LI,R4    0                 GENERATE BEFORE BEGINNING FILE DECL.COBOL42C
         BAL,L1   BBDCL00            LINKAGE IF NEEDED                  COBOL42C
         LI,R4    -4                GENERATE ERROR DECLARATIVE          COBOL42C
         BAL,L1   BBDCL00            LINKAGE IF NEEDED                  COBOL42C
BBO10    RES      0                                                     BBO100
         CI,R6    8                 IF NO REWIND REWUESTED
         BAZ      %+3
         LI,1     X'100'
         STS,1    R6                SET FLAG WHWRE IT BELONGS
         LI,1     1                 STORE
         STH,6    BBOLI,1            OPTIONS
         BAL,L1   PIA06             WRITE
BBOLI    LI,D2    0                 *****    LI,14 OPTIONS
         LI,SR1   CLI+CRR6          WRITE
         BAL,L1   PIW02             *****    LI,6  I:
         MTW,5    DDB%ADD           *
         LB,L1    *DDB%ADD          *
         BNEZ     BBO28             *
         MTW,1    DDB%ADD           * IF WE HAVE DECLARATIVES
         LW,L1    *DDB%ADD          *    BRANCH
         BNEZ     BBO28             *
         MTW,1    DDB%ADD           *
         LW,L1    *DDB%ADD          *
         BNEZ     BBO28             *
         BAL,L1   PIX06             WRITE
         TEXT     ':OPN'            *****    BAL,15 C:OPN
         B        BBO29
BBO28    BAL,L1   PIX06
         TEXT     ':OPD'
BBO29    RES      0
BBO37    RES      0
         LW,D3    BBOSAV            LOAD DCB BASE
* LABELLED FILE                                                         BBO38
BBO46    RES      0
         CI,R3    X'40'             CHECK RERUN FLAG
         BAZ      BBO47             DOWN.  NO RERUN
* RERUN,  INITIALIZE COUNT
         BAL,L1   PIA06             WRITE
         LI,V2    0                 ****     CLEAR REGISTER
         LW,D3    JAIDW+2           LOAD I:+3
         AI,D3    X'C'
         BAL,L1   PID16             WRITE
         STW,V2   2                 ****  STW,V2  I:+3
BBO47    RES      0
*** E X I T   F R O M   O P E N   P R O C E S S I N G
         B        BAA02             RETURN                              BBO448
* CLOSE                                                                 BBQ0
BBQ00    RES      0                                                     BBQ000
         CI,R6    X'220'            CLOSE REEL/UNIT
         BNE      BBQ082           NO REG CLOSE
         LI,L1    BBQ08             SET RETURN ADDRESS                  COBOL42C
         LI,R4    8                 GENERATE                            COBOL42C
         CI,R3    2             HAS IT EVER BEEN OUTPUT
         BANZ     %+2              YES
         LI,R4    6
BBQ08    IS       HERE               BEFORE/AFTER                       COBOL42C
         CI,R4    4                  BEGINNING/ENDING                   COBOL42C
         BE       BBQ081              REEL DECLARATIVES LINKAGES        COBOL42C
         BDR,R4   BBDCL00             IF NEEDED                         COBOL42C
BBQ081   IS       HERE                                                  COBOL42C
         LI,R4    -4                GENERATE ERROR DECLARATIVE LINKAGE  COBOL42C
         BAL,L1   BBDCL00            IF NEEDED                          COBOL42C
         LI,1     1                 STORE
         STH,6    BBQLI,1            OPTIONS
         BAL,L1   PIA06             WRITE
BBQLI    LI,D2    0                 *****    LI,14 OPTIONS
         LI,SR1   CLI+CRR6          WRITE
         BAL,L1   PIW02             *****    LI,6  I:
         MTW,5    DDB%ADD           *
         LB,L1    *DDB%ADD          *
         BNEZ     BBQ0820           *
         MTW,1    DDB%ADD           *  IF THE HAS BEEN DECLARATIVES
         LW,L1    *DDB%ADD          *      BRANCH
         BNEZ     BBQ0820           *
         MTW,1    DDB%ADD           *
         LW,L1    *DDB%ADD          *
         BNEZ     BBQ0820           *
         BAL,L1   PIX06             WRITE
         TEXT     ':CLS'            *****    BAL,15 C:CLS
         B        BAA02             * * *    E X I T   * * *
BBQ0820  BAL,L1   PIX06
         TEXT     ':CLD'
         B        BAA02
*** E X I T   F R O M   C L O S E   P R O C E S S I N G                 COBOL42C
BBQ082   LI,R4    2                 BEF
         BAL,L1   BBDCL00              GENERATE DECL LINK
         LI,R4    3                AEF
         BAL,L1   BBDCL00              GENERATE DECL LINK
         B        BBQ081
*
KLIRF8   LI,RF    8                                                     BBQ044
         REF      KBKON,K4BAS,KABA
K0FF     EQU      KBKON+6
K2FF     EQU      KBKON+7
K032     EQU      K4BAS+3           I:,DCB BASE NO.ADJ.
K0A      EQU      K4BAS+4           LABEL BASE
K064     EQU      K4BAS+5           RECORD,DCB BASE NO. ADJ.
         REF      JINTE
JAIXL    EQU      JINTE+8           L:--- REF CLUSTER
         REF      JADXC
         REF      JAIDW             DATA REF
         REF      BBOSAV            DCB BASE NO.
BBWSAV   EQU      BBOSAV+2
         END
