         SYSTEM   SIG7FDP
         TITLE    'PHASE 4.1 - CONDITION STMTS'
* READ PROC                                                             APR
* LF     R---     R-,+/-HW OFFSET,INDIRECT ADDR.                        APR  1
RCEF     CNAME    0                                                     APR00
RECF     CNAME    1                                                     APR01
RCRF     CNAME    2                                                     APR02
         PROC                                                           APR04
         DO       NAME>1                                                APR10
LF       BAL,L1   AAC00             READ CRF CLUSTER                    APR11
         ELSE                                                           APR12
         DO       NAME                                                  APR13
LF       BAL,L1   AAE00             READ ECF CLUSTER                    APR14
         ELSE                                                           APR15
LF       BAL,L1   *AF(3)            READ CRF/ECF CLUSTER                APR16
         FIN                                                            APR17
         FIN                                                            APR18
         DO       NUM(AF(1))                                            APR30
         LW,AF(1) R2                LOAD HA(CLOC)+/- HW OFFSET          APR31
         DO       NUM(AF(2))                                            APR40
         AI,AF(1) AF(2)                                                 APR41
         ELSE                                                           APR42
         AI,AF(1) 1                                                     APR43
         FIN                                                            APR44
         FIN                                                            APR44
         PEND                                                           APR50
* WRITE PROC                                                            APW
* LF     W---     R-,BA(CLOC)+/-BA OFFSET,RETURN                        APW 1
WPOF     CNAME    0                                                     APW00
WMCF     CNAME    1                                                     APW01
         PROC                                                           APW03
         DO       NUM(AF(2))                                            APW11
LF       LI,R4    AF(2)             LOAD BA(CLOC)                       APW12
         ELSE                                                           APW13
         DO       NUM(AF(1))                                            APW132
LF       LW,R4    AF(1)             LOAD,SET HA(CLOC) TO BA             APW14
         AW,R4    R4                                                    APW15
         FIN                                                            APW16
         FIN                                                            APW17
         DO       NAME                                                  APW80
         DO       NUM(AF(4))
         B        WRMCF             WRITE MCF CLUSTER
         ELSE
         DO       NUM(AF(3))
         LI,L1    AF(3)             LOAD LINK REGISTER
         B        WRMCF             TO WRITE MCF CLUSTER
         ELSE                                                           APW812
         BAL,L1   WRMCF             WRITE MCF CLUSTER                   APW813
         FIN                                                            APW814
         FIN                                                            APW818
         ELSE                                                           APW82
         DO       NUM(AF(4))
         B        WRPOF             WRITE POF CLUSTER
         ELSE
         DO       NUM(AF(3))
         LI,L1    AF(3)             LOAD LINK REGISTER
         B        WRPOF             TO WRITE POF CLUSTER
         ELSE                                                           APW842
         BAL,L1   WRPOF             WRITE POF CLUSTER                   APW843
         FIN                                                            APW844
         FIN                                                            APW848
         FIN                                                            APW85
         PEND                                                           APW90
* DIAG PROC                                                             APD
DX       CNAME                                                          APD00
         PROC                                                           APD01
* AF     DX       DIAG CODE,LINK                                        APD02
LF       LI,R1    AF(1)             LOAD DIAG CODE                      APD10
         DO       NUM(AF(3))
         B        DIAG              WRITE DMF CLUSTER
         ELSE
         DO       NUM(AF(2))
         LI,L1    AF(2)             LOAD LINK REGISTER
         B        DIAG              WRITE DMF CLUSTER                   APD242
         ELSE                                                           APD243
         BAL,L1   DIAG              WRITE DMF CLUSTER                   APD244
         FIN                                                            APD248
         FIN                                                            APD29
         PEND                                                           APD40
* LINK(OR LOAD) AND BRANCH PROC                                         APL
* LF     LAB,L/R  BRANCH ADDRESS,LINK ADDRESS(OR LOAD VALUE)            APL  1
LAB      CNAME                                                          APL01
         PROC                                                           APL04
LF       LI,CF(2) AF(2)             SET LINK REGISTER                   APL12
         B        AF(1)             BRANCH                              APL14
         PEND                                                           APL90
* LOAD,BRANCH AND LINK                                                  PRL
LBAL     CNAME    0                                                     PRL01
         PROC                                                           PRL02
* LF     LBAL,L-  BRANCH,LOAD VALUE,V-                                  PRL09
         DO       NUM(AF(3))                                            PRL20
         LI,AF(3) AF(2)             LOAD VALUE                          PRL22
         ELSE                                                           PRL23
         LI,V0    AF(2)             LOAD VALUE                          PRL24
         FIN                                                            PRL28
         DO       NUM(CF(2))                                            PRL40
         BAL,CF(2) AF(1)            BRANCH                              PRL42
         ELSE                                                           PRL43
         BAL,L1   AF(1)             BRANCH                              PRL44
         FIN                                                            PRL48
         PEND                                                           PRL99
*                                                                       AA0
         REF      WRMCF
         REF      WRPOF
         REF      DIAG
         REF      AAC00             READ
         REF      AA01,AA02,AA03    M.C. RETURNS
         REF      ADC00             CONDITIONAL EXPRESION
         REF      ADE00             ARITHMETIC EXPRESSIONS
         REF      ADI00,ADI02       REF
         REF      ADO30             DCB BASE
         REF      PIA00,PIA02,PIA06,PIA08,PIA20,PIA22,PIA26,PIA28
         REF      PID10,PID11,PID12,PID14,PID16,PID18
         REF      PII00,PII02,PII20,PII22
         REF      PIL00,PIL02,PIL06,PIL20,PIL22,PIL26
         REF      PRA00,PRA01,PRA02,PRA04,PRA20,PRA21,PRA22,PRA24
         REF      PPI10,PPI12
         REF      PPI30,PPI32
         REF      GADNO             ADCON NO.
         REF      GTMP              TEMP STG
         REF      JAKON,JADAT,JASAV
         REF      JAMOD             MODEL CLUSTERS,BUFFER
         REF      STBAS             DATA STACK
         REF      SSTBS             SEARCH BUFFER
         REF      ADL00,ADVMF
         REF      PIX06
         REF      WHENFLG
         REF      METHKY
         REF      DIRECT
         REF      TDBKYODR
         REF      KEYORDER
         REF      KEYPRIOT
         DEF      GNBISRH
         DEF      ATENDFLG
         DEF      SRHTDB
         DEF      ALL
         DEF      BINSRD
* REGISTER EQUIVALENCES
R0       EQU      0
R1       EQU      1
R2       EQU      2
R3       EQU      3
R4       EQU      4
R5       EQU      5
R6       EQU      6                                                     117
R7       EQU      7                                                     116
V0       EQU      8
V1       EQU      9
V2       EQU      10
L0       EQU      V2                                                    1212
L1       EQU      11                LINK REGISTER
D0       EQU      12                DECA
D1       EQU      13
D2       EQU      14
D3       EQU      15
RI       EQU      R7                INDEX
CRI      EQU      RI*16             INDEX
* ENTRY POINTS
         DEF      ABF00             SEARCH
         DEF      ABY00             IF(/WHEN)
* DIAG CODE BASE EQUIVALENCES
XTS      EQU      157
*                                                                       70
IBCS     EQU      X'9000'           MOVE SFLD                           ABC001
IBER     EQU      X'2C'
CISAV    EQU      X'80000'          SAVE REF FLAG                       ADI455
CJIX     EQU      X'5098C'          INDEX
* OP CODES
CCI      EQU      X'2100'
CLI      EQU      X'2200'
CCW      EQU      X'3100'
CSTW     EQU      X'3500'
CBGE     EQU      X'6810'
CBLE     EQU      X'6820'
CBL      EQU      X'6910'
CBG      EQU      X'6920'
CB       EQU      X'6800'
*                                                                        0
         TITLE    'PHASE 4.1 - SEARCH'
* SEARCH                            TYPE = X'65'                        ABF
ABF00    RES      0                                                     ABF00
         LI,R3    HA(SSTBS)         SET  HA(SEARCH BUFFER)              41
         LH,V0    1,R5
         AND,V0   K2FFF
         STH,V0   1,R5
         LI,V2    IBCS+CISAV        LOAD SEARCH REF CNTL                43
         BAL,L1   ADI00             CHECK SEARCH FLD                    44
         B        AA01              INVALID SEARCH FLD                  45
* VALID SEARCH FLD                                                      46
         LH,R7    JTDB              LOAD,CHECK TDB NO.                  10
         CI,R7    X'3200'                                               11
         BGE      ABF02             WITHIN TDB NO. RANGE                12
* S*****NON-TABLE ITEM SEARCH*******                                    13
         DX       XTS,AA02          WRITE DMF CLUSTER                   14
* TDB NO.                                                               15
ABF02    RES      0                                                     16
         STH,7    SRHTDB            SAVE SEARCH TDB#
         BAL,L1   ADO30             OBTAIN WA(TDB)                      18
*                        R7 = WA(TDB)                                   19
         LI,R6    0
         STW,R6   BINSRD            CLEAR
         LB,R6    *7                LOAD FIRST BYTE OF TDB
         CI,R6    16                HAVE KEY ?
         BL       ABF03
         CI,R6    48                TWO DIRECT ?
         BGE      ABF03
         AI,R6    -32
         STW,R6   BINSRD            SET BINARY SEARCH DIRECT
ABF03    RES      0
         LH,V0    1,R5              LOAD,CHECK OPTION                   25
         CI,V0    1                                                     26
         BAZ      ABF04             ALL FLAG DOWN                       27
* SEARCH ALL                                                            28
         STW,V0   ALL               SET ALL FLAG
         CB,V0    *R7               CHECK TDB TYPE                      30
         BANZ     ABF04             ORDERED TABLE                       32
* S*****SEARCH ALL UNORDERED TABLE***                                   33
         DX       XTS+1             WRITE DMF CLUSTER                   34
ABF04    RES      0                                                     38
         LI,R6    CJIX              LOAD,STORE INDEX CNTL                5
         STW,R6   SSTBS                                                  6
         LB,D2    SSTBS+2           LOAD,FORM INDEX BASE
         CI,D2    9                 CHECK BASE NO.
         BLE      ABF05             NOT FD
         CI,D2    X'FF'             SEE IF LINKAGE ITEM                 COBOL41I
         BNE      ABF04A            NO                                  COBOL41I
         LI,D2    1                 LINKAGE INDEXES IN WORK-STO         COBOL41I
         B        ABF05                                                 COBOL41I
ABF04A   RES      0                                                     COBOL41I
* FD
         AI,D2    50
* *** INDEX BASE NO. = TABLE BASE+50 ***
ABF05    RES      0
         LW,D3    0,R7              LOAD,STORE 1ST INDEX DISPL           1
         STW,D3    SSTBS+2
         STB,D2   SSTBS+2           STORE INDEX BASE NO.
         LH,D0    3,R4              SUBF = BSIZ                          3
         STH,D0   4,R5                                                   4
         LB,D2    JTDB              LOAD,SAVE TDB NO.                   10
         STB,D2   SSTBS                                                 11
         AI,R2    1                 HA(CLOC) = HA(CLOC)+1               12
         LH,V0    0,R2              LOAD,CHECK OPTION                   13
         AI,R2    -1                HA(CLOC) = HA(CLOC)-1               14
         CI,V0    2                                                     15
         BAZ      ABF10             VARYING FLAG DOWN                   16
* VARYING
         STW,R7   JSTDB             SAVE WA(TDB)                        20
         LI,R3    HA(SSTBS+5)       LOAD HA(STKTOP)                     21
         LI,V2    IBER+CISAV        LOAD REF CNTL                       22
         BAL,L1   ADI00             CHECK VARYING FLD                   23
         B        ABF09             INVALID VARYING
* VALID VARYING FLD                                                     25
*                        D2 = TDB NO.                                   26
         CB,D2    JTDB              COMPARE TDB,TDBV                    27
         BNE      ABF08             TDB NOT= TDBV.                      30
* TDB = TDBV                                                            31
*                        D0 = SUBF.
         CI,R6    CJIX              CHECK DREF CNTL                     32
         BNE      ABF08             NOT= INDEX                          33
         CW,V0    D0                CHECK SUBFV,SUBF                    34
         BNE      ABF08             SUBV NOT= SUBF                      35
* SUBF = SUBF, USE AS ONLY INDEX                                        36
         LW,D3    SSTBS+7           LOAD,STORE NEW INDEX BASE,DISPL     37
         STW,D3   SSTBS+2                                               38
         B        ABF09
* TDB NOT= TDBV, EFFECTIVE VARYING OPTION                               40
ABF08    RES      0                                                     41
         STW,R6   SSTBS+5           SAVE VARYING TYPE(,CLNG,CNTL)
         MTB,-1   SSTBS+1           RAISE VARYING FLAG                  42
ABF09    RES      0
         LW,R7    JSTDB             LOAD WA(TDB)
*                        R2 = HA(CLOC) (=AT END CLUSTER)                42
*                        R7 = WA(DDB)                                   BBI15 5
*                        D0 = SUBF                                      42
*                        D2 = TDB NO.                                   43
ABF10    RES      0                                                     43
         LI,R1    3                 LOAD TDB INDEX                      48
         MH,D0    *R7,R1            OBTAIN UPPER LIMIT(=(OCC-1)*SUBF)   48
         SW,D1    D0
*                        D1 = UPPER LIMIT
         LW,V1    D1                SAVE UPPER LIMIT                    49
         LB,R6    *R7               LOAD,CHECK TABLE TYPE CODE          50
         CI,R6    8                                                     51
         BAZ      ABF14             FIXED LNG TABLE                     52
* VARIABLE LNG TABLE                                                    54
         LI,R1    6                 LOAD SUBF INDEX                     55
         LH,D3    *R7,R1            SAVE ADCON NO./0                    56
         BNEZ     ABF12             NOT= 0. ADCON RESERVED.             66
* ADCON NO. = 0, NOT RESERVED                                           70
         MTW,4    GADNO             ADCON NO.= ADCON NO.+1              71
         LW,D3    GADNO             ADCON NO. TO WA                     72
         SLS,D3   -2                                                    73
*                        D3 = ADCON NO.(WA)                             74
ABF12    RES      0                                                     75
         STH,D0   *R7,R1            SUBF TO LOAD CLUSTER                57
         LW,R4    R7                WA(TDB) TO BA(TDB)+8                60
         SLS,R4   2                                                     61
         AI,R4    8                                                     62
         MTW,1    ADVMF
         BAL,L1   ADL00
         BAL,L1   WRMCF             WRITE LOAD (INDEX) CLUSTER          63
         STH,D3   *R7,R1            SAVE ADCON NO.                      77
         LH,V0    SSTBS+1
         CI,V0    1                 COMPARE ALL FLAG
         BAZ      ABF13             NOT ALL
         LH,V0    D1                CLEAR V0
         STW,D1   UPLIMIT           SAVE UPPER LIMIT
         AI,V0    CCI+CRI           WRITE
         BAL,L1   PIA02               CI,7   UPPER LIMIT
         BAL,L1   PIL06             WRITE
         BLE      2                    BLE   %+2
         LW,D1    UPLIMIT           RELOAD UPPER LIMIT
         AI,V0    CLI-CCI           FORM
         BAL,L1   PIA02             WRITE LI,RI UPPER LIMIT
         LH,D1    4,R5              LOAD SUBF - RECORD SIZE
         LI,V0    X'2070'           WRITE
         BAL,L1   PIA02                AI,7    RECSIZE
         BAL,L1   STRADCON          TO WRITE  STW,7  UPLMT
         STW,D3   UPLMT             SAVE UPLMT ADDR
         B        ABF14
ABF13    LH,V0    D1                CLEAR V0
         AI,V0    CCI+CRI
         BAL,L1   PIA02             WRITE CI,RI UPPER LIMIT
         BAL,L1   PIL06             WRITE                               79
         BLE      2                 ****  BLE %+2                       80
         LW,D1    V1                RELOAD UPPER LIMIT                  81
         AI,V0    CLI-CCI           FORM LI,RI                          82
         BAL,L1   PIA02             WRITE LI,RI UPPER LIMIT             83
         LBAL     PRA22,CSTW+CRI    WRITE STW,RI ADCON                  76
ABF14    RES      0                                                    80
         LW,D3    SSTBS+2           LOAD INDEX BASE,DISPL               80
         LH,V0    SSTBS+1           LOAD,CHECK OPTION                    1
         CI,V0    1
         BAZ      ABF16             ALL FLAG DOWN                       83
* ALL                                                                   84
         BAL,L1   PIA06             WRITE                               85
         LI,RI    0                 ****     CLEAR REGISTER             86
         BAL,L1   PID16             WRITE                               87
         STW,RI   2                 ****     INITIALIZE INDEX           88
         CI,R6    8
         BAZ      ABF18             FIXED LNG TABLE
         B        ABF17
STRADCON STW,11   RETURN            SAVE RETURN ADDR
         MTW,4    GADNO             ADCON NO. = ADCON NO. + 1
         LW,D3    GADNO             ADCON NO. TO WA
         SLS,D3   -2                D3 = ADCON NO. (WA)
         LBAL     PRA22,CSTW+CRI    WRITE STW,7  ADCON
         B        *RETURN           RETURN
*                        R6 = TDB TYPE CODE                             92
*                        D3 = INDEX BASE,DISPL                          93
ABF16    RES      0                                                     94
         BAL,L1   PPI10             WRITE INTL DEF                      95
         STW,D1   JSTDL             SAVE INTL NO.                       96
         BAL,L1   PID16             WRITE                               97
         LW,RI    2                 ****  LW,RI INDEX                   98
         CI,R6    8                 CHECK SEARCH TABLE TYPE             99
         BAZ      ABF19
* VARIABLE LNG TABLE                                                     2
         LH,D3    *R7,R1            LOAD ADCON NO.                       3
         LI,V0    CCW+CRI           LOAD CW,RI                           4
         LAB,L1   PRA22,ABF20       WRITE CW,RI ADCON NO.                5
ABF17    BAL,L1   STRADCON          TO WRITE  STW,7  METHKY
         STW,D3   METHKY            SAVE METHKY ADDR
         BAL,L1   STRADCON          TO WRITE STW,7  DIRECT
         STW,D3   DIRECT            SAVE DIRECT ADDR
         LH,D1    4,R5              LOAD RECORD LENGTH
         LI,V0    CLI+CRI           SET RECORD LENGTH
         BAL,L1   PIA02             WRITE  LI,R7   RECORD LENGTH
         BAL,L1   STRADCON          TO WRITE  STW,7  RCDSZ
         STW,D3   RCDSZ             SAVE RCDSZ ADDR
         BAL,L1   PIA06             WRITE
         LCW,RI   RI                   LCW,7   7
          BAL,L1  STRADCON          TO WRITE  STW,7  LWLMT
         STW,D3   LWLMT             SAVE LWLMT ADDR
         B        ABF20
* FIXED LNG TABLE                                                       10
*                        V1 = UPPER LIMIT                               14
ABF19    RES      0
         LW,D1    V1                LOAD UPPER LIMIT
         LH,V0    D1                FORM  CI,RI
         AI,V0    CCI+CRI
         BAL,L1   PIA02             WRITE  CI,RI  UPPER LIMIT
         B        ABF20
ABF18    RES      0                                                     12
         BAL,L1   STRADCON          TO WRITE  STW,7  METHKY
         STW,D3   METHKY            SAVE METHKY ADDR
         BAL,L1   STRADCON          WRITE  STW,7  DIRECT
         STW,D3   DIRECT            SAVE DIRECT ADDR
         LH,D1    4,R5              LOAD RECORD LENGTH
         LI,V0    CLI+CRI           SET  LI,7   RCDSZ
         BAL,L1   PIA02             WRITE  LI,7  RCDSZ
         BAL,L1   STRADCON          TO WRITE  STW,7  RCDSZ
         STW,D3   RCDSZ             SAVE RCDSZ ADDR
         BAL,L1   PIA06             WRITE, COMPLEMENT R7
         LCW,RI   RI
         BAL,L1   STRADCON          TO WRITE  STW,7  LWLMT
         STW,D3   LWLMT             SAVE LWLMT ADDR
         LW,D1    V1                RELOAD UPPER LIMIT
         AH,D1    4,R5              FORM UPPER LIMIT
         LI,V0    CLI+CRI           FORM  LI,7
         BAL,L1   PIA02             WRITE  LI,7  UPLMT
         BAL,L1   STRADCON          TO WRITE  STW,7  UPLMT
         STW,D3   UPLMT             SAVE UPLMT ADDR
*
ABF20    RES      0
         LH,D1    1,R2              LOAD L1
         STH,D1   ENDADR             SAVE INTL DEF FOR AT END ADDR
         AI,R2    1                 HA(CLOC) = HA(CLOC)+1
         LH,V0    0,R2              LOAD,CHECK OPTION
         CI,V0    X'FE000'
         BE       ABF22             JUMP TO N.S.
* AT END IMPERATIVE
         LH,V0    SSTBS+1
         CI,V0    1                 COMPARE ALL FLAG
         BAZ      ABF21             NOT ALL
* ALL
         LI,V0    CB                LOAD B
         BAL,L1   PII02             WRITE B  L1
         BAL,L1   PPI10             SET INTNL DEF FOR AT END ADDR
         STH,D1   ENDADR            STORE INTL DEF#
         STW,D1   ATENDFLG          SET ATEND FLAG
         B        AA02
* VARYING
ABF21    LI,V0    CBLE              LOAD BLE
         LAB,L1   PII02,AA02        WRITE BLE L1
         LAB,L1   PII02,AA02        WRITE BLE  L1
* JUMP TO N.S., NO AT END IMPERATIVE
ABF22    RES      0
         LH,V0    SSTBS+1
         CI,V0    1                 COMPARE ALL FLAG
         BAZ      ABF23             NOT ALL
* ALL
         BAL,L1   GNBISRH           TO GENERATE BIN SEARCH ROUTINE
         B        AA02
GNBISRH  STW,L1   RETURN            SAVE RETURN ADDR
         BAL,L1   PPI10             WRITE INTL DEF
         STW,D1   JSTDL             SAVE INTL NO.
         BAL,L1   PIX06
         TEXT     ':BIS'
         LI,V0    X'3210'           LOAD  LW,1
         LW,D3    LWLMT             LOAD ADCON OF LWLMT
         BAL,L1   PRA22             WRITE  LW,1  LWLMT
         LI,V0    X'3220'           LOAD  LW,2
         LW,D3    UPLMT             LOAD ADCON OF UPLMT
         BAL,L1   PRA22             WRITE  LW,2  UPLMT
         LI,V0    X'3230'           LOAD  LW,3
         LW,D3    RCDSZ             LOAD  ADCON OF RCDSZ
         BAL,L1   PRA22             WRITE LW,3  RCDSZ
         LI,V0    X'3240'           LOAD  LW,4
         LW,D3    METHKY            LOAD ADCON OF METHKY
         BAL,L1   PRA22             WRITE LW,4  METHKY
         LI,V0    X'3250'           LOAD  LW,5
         LW,D3    DIRECT            LOAD  ADCON OF DIRECT
         BAL,L1   PRA22             WRITE  LW,5  DIRECT
         LI,V0    CB
         LH,D1    ENDADR            LOAD INTL DEF FOR AT END ADDR
         BAL,L1   PII02             BRANCH AT END ADDR
         LW,D3    SSTBS+2           LOAD INDEX BASE, DISPL
         BAL,L1   PID16             WRITE
         STW,RI   2                 STW,7   INDEX
         B        *RETURN           RETURN
RETURN   RES      1
* VARYING
ABF23    LI,V0    CBG               LOAD BG
         LAB,L1   PII02,AA02        WRITE BG N.S.
         TITLE    'PHASE 4.1 - IF(/WHEN)'
* IF(/WHEN)
ABY00    RES      0                                                     ABY00
         LI,8     0
         CI,R1    X'2D'             IS IT A WHEN CLAUSE                 COBOL41I
         BNE      %+5               NO, TO PROCESS CONDITION            COBOL41I
         STW,R1   WHENFLG           SET WHEN STMT FLAG IN 41L
         STW,8    TDBKYODR          CLEAR WORKING AREA
         STW,8    KEYORDER          CLEAR WORKING AREA
         STW,8    KEYPRIOT          CLEAR WORKING AREA
         LAB,L1   ADC00,ABY01       PROCESS CONDITIONAL                 COBOL41I
ABY01    RES      0                                                     COBOL41I
         LI,8     0                 CLEAR WHEN FLAG                     COBOL41I
         STW,8    WHENFLG                                               COBOL41I
         B        AA01                                                  COBOL41I
K2FFF    DATA     X'FFF0'
SRHTDB   RES      1
ENDADR   RES      1                 INTL DEF FOR AT END ADDR
UPLIMIT  RES      1                 UPPER LIMIT
ATENDFLG DATA     0                 AT END FLAG
ALL      DATA     0
BINSRD   DATA     0
LWLMT    RES      1
UPLMT    RES      1
RCDSZ    RES      1
JTDB     EQU      JADAT+3
JDECP    EQU      JADAT+4
JDSIZ    EQU      JADAT+5
JSTDB    EQU      JADAT+X'31'       SEARCH WA(TDB)
JSTDL    EQU      JADAT+X'31'       INTL NO.
         END
