
      HED LIBRARY SIZES 
* THIS TABLE IS USED BY THE TSB PAPER TAPE LOADER, THE SLEEP
* ROUTINE, AND THE MAG TAPE LOADER. IT CONTAINS THE LENGTHS OF
* ALL THE REMAINING LIBRARY ROUTINES, AND ENABLES THE LOADER TO 
* ALLOCATE THE MINIMUM NUMBER OF DISC SECTORS FOR EACH OF THEM. 
* THE TABLE IS WRITTEN ON THE DISC AS THE FIRST LIBRARY ROUTINE.
      SPC 1 
      ORG LIBRA 
      ABS LIBRA-$SLPL 
      DEC -512      TWO HALVES OF 
      DEC -512        FUSS TABLE
      ABS LIBRA-$FLB
      ABS LIBRA-$ASN
      ABS LIBRA-$CHN
      ABS LIBRA-$SAV
      ABS LIBRA-$SAV
      ABS LIBRA-$$SAV    SAVE OVERLAY.
      ABS LIBRA-$GET
      ABS LIBRA-$APP
      ABS LIBRA-$HEL
      ABS LIBRA-$BYE
      ABS LIBRA-$KIL
      ABS LIBRA-$REN
      ABS LIBRA-$NAM
      ABS LIBRA-$CAT
      ABS LIBRA-$CAT
      ABS LIBRA-$CAT     GROUP
      ABS LIBRA-$DIR$ 
      ABS LIBRA-$REP$ 
      ABS LIBRA-$STA$ 
      ABS LIBRA-$STA$ 
      ABS LIBRA-$DEL
      ABS LIBRA-$TIM
      ABS LIBRA-$PRO
      ABS LIBRA-$PRO
      ABS LIBRA-$OPE
      ABS LIBRA-$LEN
      ABS LIBRA-$ECH
      ABS LIBRA-$MES     MESSAGE
      ABS LIBRA-$LPR
      ABS LIBRA-$POR$ 
      ABS LIBRA-$REP
      ABS LIBRA-$DIR
      ABS LIBRA-$STA
      ABS LIBRA-$STA
      ABS LIBRA-$POR
      ABS LIBRA-$ROS
      ABS LIBRA-$ANN
      ABS LIBRA-$RES
      ABS LIBRA-$CHA
      ABS LIBRA-$SLE
      ABS LIBRA-$SLE     HIBERNATE
      ABS LIBRA-$NEW
      ABS LIBRA-$KID
      ABS LIBRA-$MUN
      ABS LIBRA-$MLO
      ABS LIBRA-$$MLO 
      ABS LIBRA-$COP
      ABS LIBRA-$BES
      ABS LIBRA-$PUR
      ABS LIBRA-$MAG
      ABS LIBRA-$PHO
      ABS LIBRA-$PRI
      ABS LIBRA-$SPE
      ABS LIBRA-$BRE
      REP 4 
      DEC -512
$SLPL EQU * 
      HED FUSS
* THE FUSS TABLE CONTAINS A 32 WORD ENTRY FOR EACH PORT.  THESE 
* WORDS ARE THE DISC ADDRESSES OF THE FILES HE IS CURRENTY USING. 
* A ZERO INDICATES NO FILE. THE TABLE IS READ OUT TO THE DISC 
* IN TWO HALVES, AND THEY ARE  ASSUMED TO BE ON CONTIGUOUS
* SECTORS. (THIS IS GUARANTEED IF FUSS IS ONE OF THE FIRST
* LIBRARY ROUTINES. 
* 
      ORG LIBRA 
      SUP 
      REP 32
      OCT 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0 
* 
      ORG LIBRA 
      REP 32
      OCT 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0 
      UNS 
      HED FILES 
* THE FILES ROUTINE IS USED BY THE BASIC COMPILER TO PROCESS FILES
* STATEMENTS DURING PHASE II.  THE PURPOSE OF THE ROUTINE IS TO PRO-
* VIDE THE COMPILER WITH INFORMATION ABOUT THE REQUESTED FILES. THIS
* INFORMATION CONSISTS OF THE FILE'S DISC ADDRESS, ITS LENGTH,
* AND ITS RECORD SIZE.
* THE COMPILER PASSES PARAMETERS TO THE FILES ROUTINE AS FOLLOWS: 
* 
*     FILCT=-5+# OF FILES STATEMENTS
*     FILTB=>BEGINNING OF TABLE AREA FOR FILE INFO. 
*     SCHLB,I=>FIRST POSSIBLE RETURN ADDRESS. 
* 
* THE CALLING SEQUENCE TO THE FILES ROUTINE IS AS FOLLOWS:
* 
*     JSB SCHLB,I 
*     DEF FILIB 
*     <ERROR EXIT FOR BAD FORMAT IN FILES STATEMENT>
*     <ERROR EXIT IF A FILE IS UNACCESSIBLE>
*     <ERROR EXIT IF PROGRAM OVERFLOW>
*     <NORMAL EXIT> 
      SPC 2 
      ORG LIBRA 
* 
      LDA FILBP     GET POINTER TO FILE BUFFER
      STA FLBUF     SAVE BUFFER POINTER.
      STA FLBFP 
      LDA .-17      SET COUNTER FOR MAXIMUM NUMBER
      STA FLBC1      OF FILES ALLOWED.
      LDA FILCT     GET COUNT - 5 OF FILES STATEMENTS 
      ADA .+5       GET COUNT 
      CMA,INA       GET NEGATIVE
      STA FLBFC     SAVE COUNT
      LDA DFILT     GET POINTER TO FILES
      STA FLBFF     STATEMENT TABLE 
* 
* INITIALIZATION IS COMPLETE.  NOW BEGIN PROCESSING THE FILES STMTS.
* 
FLBA  EQU * 
      LDB FLBFF,I   GET POINTER TO FILES STATEMENTS 
      CCA           SET POINTER TO
      ADA 1,I        LAST CHAR + 1 OF 
      ADA 1           FILES STATEMENT.
      RAL 
      STA FLBP      INITIALIZE EOF STATEMENT POINTER
      INB          INITIALIZE POINTER TO
      BLS 
      STB FLBCP    FILES STATEMENT. 
* 
* GET THE FILE NAME 
* 
FLB1  ISZ FLBC1     TEST FOR
      RSS             TOO MANY
      JMP FLB8+1        FILES 
      LDA .-3       SET FLAG TO SAY 
      STA FLBC2       3 WORDS ALLOWED 
      CLA 
      STA FLBCM     CLEAR COMMA FLAG. 
      STA FLB$
      JSB FLBCH     GET FIRST CHAR. 
      CPA .+44B     TEST FOR DOLLAR SIGN. 
      JMP FLB2
      CPA .+52B     TEST FOR SNOWFLAKE
      JMP FLB22 
FLB5  CPA .+40B     BETTER NOT BE A BLANK.
      JMP FLB8+1    FAIL IF IT IS.
FLB25 EQU * 
      ADA FLB$      * OR $ FLAG FIRST CHARACTER 
FLB3  ALF,ALF       POSITION ON LEFT
      STA FLBUF,I    AND STORE IN BUFFER. 
      JSB FLBCH     GET RIGHT CHARACTER 
      IOR FLBUF,I    AND PACK IN. 
      STA FLBUF,I 
      ISZ FLBUF     BUMP BUFFER POINTER.
      JSB FLBCH     GET NEXT CHARACTER. 
      ISZ FLBC2     TEST FOR END OF FILE NAME.
      JMP FLB3
* 
* TEST 7TH CHARACTER FOR BLANK
* 
      CPA .+40B     IF END OF FILE NAME, CHAR MUST
      JMP FLB4       BE A BLANK.
      JMP FLB8+1    FAIL IF NOT.
* 
* COME HERE IF 1ST CHARACTER IS $ 
* 
FLB2  LDA B200      IF 1ST CHAR IS $, SET FIL$ TO 
      STA FLB$       INDICATE LIBRARY FILE. 
      JSB FLBCH     GET NEXT CHAR.
      JMP FLB5
* 
* COME HERE IF 1ST CHARACTER IS * 
* 
FLB22 LDA BIT15     IF FIRST CHAR IS *, SET FIL$ TO 
      STA FLB$        INDICATE GROUP LIBRARY FILE 
      JSB FLBCH     GET NEXT CHARACTER
      CPA .+40B     IS IT BLANK?
      CLA,RSS       YES, * IS PLACE HOLDER
      JMP FLB25     NO, CONTINUE PROCESSING NAME
      LDB .-7       CLEAR BUFFER
      STA FLBUF,I     SINCE NO
      ISZ FLBUF         FILE NOW
      INB,SZB 
      JMP *-3 
      LDB B400      RESERVE 256 WORDS 
      STB FLBUF,I     IN CORE FOR FUTURE FILE 
      INA 
      JMP FLB26 
* 
* THE FILE NAME HAS BEEN TESTED AS CORRECT AND STORED IN THE
*   TEMPORARY BUFFER
* 
FLB4  LDA .+5       LEAVE ROOM FOR STORAGE
FLB26 EQU * 
      ADA FLBUF       OF FILE INFORMATION 
      STA FLBUF         FROM THE DIRECTORY
      LDA FLBCM     TEST FOR ANY MORE 
      SZA             FILES REQUESTED 
      JMP FLB1      YES IF COMMA WAS SEEN.
      ISZ FLBFF     COUNT UP POINTER INTO TABLE 
      ISZ FLBFC     CHECK COUNTER 
      JMP FLBA      PROCESS ANOTHER FILES STATEMENT.
* 
* ALL FILE STATEMENTS HAVE NOW BEEN PROCESSED 
* 
      LDA FLBC1     SET FILC1 TO EQUAL
      ADA .+17        -# OF FILES REQUESTED 
      CMA,INA 
      STA FLBC1 
      STA FLBC2 
* 
      ISZ SCHLQ     BUMP RETURN ADDRESS SINCE WE'VE 
      LDA FLBFP      NOW CHECKED FOR TYPE I ERRORS. 
      STA FLBUF     SET POINTER TO BUFFER AGAIN.
* 
* BEGIN BUILDING THE 'FILES' TABLE FOR THIS USER
* 
      LDA MLINK+1   GET USER ID AND SAVE IT.
      ADA .+?ID-?LINK 
      LDA 0,I 
      STA FLBID 
* 
FLB6  LDB FLBUF,I   GET FIRST WORD OF FILE NAME.
      SZB,RSS       IS THIS A PLACE HOLDER
      JMP FLB27     YES, SKIP DIRECTORY LOOKUP
      LDA FLBID 
      SSB           IF BIT 15 OF FIRST WORD IS SET, 
      LDA A000       PERFORM SEARCH USING A000. 
      BLF,BLF       IF BIT 7 OF 
      SSB             FIRST WORD IS SET 
      JMP FLB24         SET UP FOR GROUP LIB SEARCH 
      BLF,BLF       ELSE RESTORE FIRST WORD 
      JMP FLB23 
* 
FLB27 EQU * 
      LDB FLBUF     BUMP POINTER
      ADB .+8       TO NEXT TEMP
      STB FLBUF         BUFFER ENTRY
      JMP FLB28 
* 
FLB24 ELB,CLE,ERB   CLEAR BIT 7 
      BLF,BLF         AND 
      STB FLBUF,I       RESTORE TO TABLE
      AND B1777     ISOLATE NUMERICAL PART OF ID
      CLB 
      DIV .100      GET 
      MPY .100
      LDB A           LIBRARIAN 
      LDA M2000 
      AND FLBID         USER
      IOR B               NUMBER
      LDB FLBUF,I   RESTORE FIRST WORD OF FILE NAME 
FLB23 DST LTEMP 
      ISZ FLBUF     GET NEXT 2 WORDS ALSO.
      DLD FLBUF,I 
      DST LTEMP+2 
* 
      JSB DLOKP,I   SEARCH FOR FILE 
      JMP FLB7      FOUND IT. 
* 
FLB8  JSB RDPRG     FAILURE 
      CLA 
      STA DIRWD     NO DIRECTORY BLOCK IN CORE NOW
      JSB DCMPL 
      JMP SCHBL 
* 
FLB7  EQU * 
      LDA LTEMP+4  LOAD POINTER TO DIREC ENTRY. 
      ADA .+5         AND BUMP TO DISC ADDRESS
      STA DIRWD     SET DIRWD FOR DLOOK 
      LDB LTEMP+5   TEST TO SEE 
      ADB .+2        IF THIS IS 
      LDA 1,I         REALLY A
      SSA,RSS          FILE.
      JMP FLB8      FAIL IF NOT.
      LDA LTEMP     IS THIS THE 
      CPA FLBID       FILE OWNER? 
      JMP FLB9      YES 
      ADB .-1       NO
      LDA B,I       IS THE FILE 
      SSA             PROTECTED?
      JMP FLB8      YES - FAIL
      ADB .+2       NO
      LDA B,I       IS THE FILE 
      SSA            MASKED?
      JMP FLB8      YES - FAIL
* 
*  THE FOLLOWING SECTION OF CODE FILLS EACH INTERIM 8 WORD
*  FILE TABLE WITH INFORMATION FROM THE DIRECTORY ENTRIES.
*  THE TABLE APPEARS AS FOLLOWS:
*     1  FILE 
*     2   ..
*     3    NAME 
*     4  NOT USED 
*     5  DISC 
*     6    ADDRESS
*     7  FILE LENGTH
*     8  RECORD SIZE
*  (NOTE: THE FILE NAME HAD BEEN INSERTED IN FLB3)
* 
FLB9  ISZ FLBUF     CLEAR 
      ISZ FLBUF       THE 
      CLA               UNUSED
      STA FLBUF,I         WORD
      ISZ FLBUF     BUMP BUFF POINTER TO WORD 5 
      LDB LTEMP+5 
      ADB .+8 
      DLD B,I       GET DISC ADDRESS AND
      DST FLBUF,I     PUT IT IN THE BUFFER
      LDB LTEMP+5   GET DIRECTORY ENTRY POINTER 
      ADB .+11      ADJUST TO FILE LENGTH WORD
      ISZ FLBUF     BUMP BUFFER POINTER 
      ISZ FLBUF       TO LENGTH SLOT
      LDA FLBID     TEST FOR USER REFERENCE 
      CPA LTEMP       TO PUBLIC OR GROUP FILE 
      CLA,RSS       NO,CLEAR BIT 15 
      LDA BIT15     YES, SET BIT 15 
      IOR B,I       OR IN FILE LENGTH 
      STA FLBUF,I   STORE IT IN BUFFER
      ISZ FLBUF     BUMP POINTER TO RECORD SIZE SLOT
      ADB .-7       SAME FOR DIRECTORY POINTER
      LDA B,I       TRANSFER RECORD SIZE
      STA FLBUF,I     TO BUFFER 
      ISZ FLBUF     BUMP POINTER TO NEXT ENTRY
      JSB DATE      GET DATE AND SET
      LDB LTEMP+5     INTO PURGE (LAST
      ADB .+5           REFERENCED) 
      STA B,I             DATE. 
* 
FLB28 EQU * 
      ISZ FLBC1     TEST FOR ANY MORE FILES.
      JMP FLB6
* 
* WE HAVE FOUND ALL THE FILES. WE NOW HAVE TO UPDATE THE FUSS TABLE.
* FIRST CHECK TO SEE IF THE PROGRAM HAS ROOM ENOUGH FOR THE TABLE.
* 
      LDA DIRWD     WRITE DIRECTORY TO DISC 
      SZA,RSS         IF ANY IS IN CORE 
      JMP FLB29 
      LDB LIBD     OUTGOING CORE ADDRESS. 
      JSB DISCZ,I 
      JSB SLVAG,I   CAN'T DO IT, TRY TO SALVAGE 
      CLA           SAY DIRECTORY 
      STA DIRWD       NOT IN CORE 
FLB29 EQU * 
      ISZ SCHLQ     BUMP TO NEXT ERROR EXIT.
      LDA FLBC2     GET # OF FILES. 
      STA FLBC1 
      CMA,INA 
      MPY .+FTEL    COMPUTE NEW VALUE OF PBPTR
      ADA PBPTR 
      CMA 
      ADA LWAUS     TEST FOR OVERFLOW.
      SSA 
      JMP FLB8      FAIL--PROGRAM TOO LARGE.
* 
      ISZ SCHLQ     BUMP TO NORMAL RETURN ADDRESS.
      LDA M2000     INPUT FUSS TABLE
      STA MWORD 
      LDA FUSS
      LDB LIBDI 
      JSB DISCZ,I 
      JSB SICKP,I   IT'S STUCK ON THE DISC
* 
      LDA MLINK+1   DETERMINE USER #. 
      ADA .+?TNUM-?LINK 
      LDA 0,I       USER # IN BITS 12-8 
      ALF,ALF       RIGHT JUSTIFY USER #
      ALF,RAL       MULTIPLY USER # BY 32 AND 
      ADA LIBD       ADD LIBD TO POINT AT USER'S
      STA FLBFS       SECTION OF FUSS.
      STA LTEMP 
      LDB M32       ZERO OUT USER'S SECTION 
      CLA 
      STA LTEMP,I 
      ISZ LTEMP 
      INB,SZB 
      JMP *-3 
* 
* NOW CHECK TO SEE IF ANY OF THE REQUESTED FILES ARE BEING USED BY
* ANOTHER USER. IF THEY ARE, WE ALLOW ONLY FILE READS BUT NO WRITES.
*  IF THE USER IS AN 'A', WE SKIP THE TEST. 
* 
      LDA FLBID 
      AND M2000 
      CPA A000
      JMP FLB10 
* 
      LDA FLBFP     SET BUFFER POINTER. 
FLB11 EQU * 
      STA FLBUF         ADDRESS.
* 
      LDB FLBUF,I   GET FIRST WORD OF NAME
      SZB,RSS       PLACE HOLDER? 
      JMP FLB30     YES 
      ADA .+4       NO, BUMP POINTER TO 
      STA FLBUF       DISC ADDRESS
* 
      LDB LIBD      PUT ADDRESS OF FUSS 
      STB FUSCH       INTO FUSS SEARCH POINTER
      DLD FLBUF,I   GET DISC ADDRESS
FLB14 CPA FUSCH,I   UPPER WORDS EQUAL?
      JMP FLB18     YES, GO COMPARE LOWER 
      ISZ FUSCH     NO, BUMP
FLB19 ISZ FUSCH       FUSS POINTER
      LDA L1024     GET FUSS END ADDRESS
      CPA FUSCH     HAVE WE EXHAUSTED FUSS? 
      JMP FLB13     YES, GO CHECK NEXT FILE 
      LDA FLBUF,I   NO, RESTORE UPPER ADDRESS WORD
      JMP FLB14       AND GO COMPARE AGAIN
FLB18 ISZ FUSCH     BUMP TO LOW ADDRESS WORD
      CPB FUSCH,I   IS LOW ADDRESS ALSO EQUAL?
      JMP FLB12     YES, GO FLAG READ ONLY
      JMP FLB19     NO, GO CHECK NEXT FILE
* 
FLB30 EQU * 
      LDA .+6 
      JMP FLB13+1 
* 
FLB12 ISZ FLBUF     BUMP BUFFER POINTER 
      ISZ FLBUF       TO LENGTH WORD
      LDA FLBUF,I   SET DISC LENGTH TO SAY
      IOR BIT15      READ ONLY. 
      STA FLBUF,I 
* 
      CLA,RSS 
FLB13 LDA .+2 
      ADA .+2       ADJUST BUFFER POINTER 
      ADA FLBUF       TO NEXT FILE NAME 
      ISZ FLBC1     TEST FOR ANY MORE 
      JMP FLB11 
* 
* NOW UPDATE FUSS BY PLACING THE DISC ADDRESSES JUST REQUESTED
* INTO THE USER'S FUSS AREA.
* 
FLB10 LDA FLBC2     SET COUNTER.
      STA FLBC1 
      LDA FLBFP     GET POINTER TO FIRST ONE. 
FLB15 EQU * 
      ADA .+6       GET FILE LENGTH 
      LDB 0,I 
      ADA .-2       A POINTS TO HIGH DISC ADDRESS 
      SSB,RSS       IF NOT READ ONLY, 
      CLB,RSS       LEAVE BIT 15 0. 
      LDB BIT15       ELSE SET IT.
      ADB 0,I 
      STB FLBFS,I    AND PUT INTO TABLE.
      ISZ FLBFS     BUMP
      INA           POINTERS AND
      LDB A,I         STORE LOW 
      STB FLBFS,I       DISC ADDRESS
      ISZ FLBFS     REBUMP
      ADA .+3         POINTERS
      ISZ FLBC1     TEST FOR DONE.
      JMP FLB15 
* 
      LDA FUSS
      LDB LIBD
      JSB DISCZ,I 
      JSB SICKP,I   THE FUSS TABLE IS STUCK IN CORE 
* 
      JSB RDPRG     READ IN USER'S PROGRAM AGAIN. 
      LDA FILTB 
      STA VALTB 
      LDB FLBFP     GET BUFFER POINTER
FLB16 EQU * 
      ADB .+6       BUMP TO LENGTH WORD 
      DLD B,I       GET LENGTH WORD AND RECORD SIZE 
      DST VALTB,I   STORE THEM IN FILE TABLE
      ISZ VALTB     BUMP FILE 
      ISZ VALTB       TABLE POINTER 
      ELA,CLE,ERA   REMOVE BIT 15 FROM LENGTH 
      ADA .-2       COMPUTE RELATIVE
      SLA,INA,SZA     ADDRESS OF LAST 
      ADA .-1           LOGICAL RECORD
      LDB FLBFP     GET THE ADDRESS 
      ADB .+4         OF HIGH DISC ADDRESS
      STB FUSCH         AND SAVE IT 
      INB           GET POINTER TO LOW DISC ADD WD. 
      CLE 
      ADA B,I       ADD RELATIVE LAST RECORD ADDRESS
      LDB FUSCH     B GETS HIGH DISC
      LDB B,I         ADDRESS WORD
      SEZ           IF LOW ADD OVERFLOW,
      INB             ADD 1 TO HIGH PART
      SWP           STORE BOTH WORDS
      DST VALTB,I     OF DISC ADDRESS 
      LDA .+4 
      ADA VALTB 
      STA VALTB 
      DLD FUSCH,I     BASE DISC ADDRESS 
      DST VALTB,I       INTO FILE TABLE 
      ISZ VALTB     ADJUST POINTER
      LDA VALTB     BUMP POINTERS 
      ADA .+4 
      STA VALTB 
      LDB FLBFP,I   MOVE
      STB VALTB,I 
      ISZ FLBFP      FILE 
      ISZ VALTB 
      DLD FLBFP,I     NAME
      DST VALTB,I 
      LDA VALTB        INTO 
      ADA .+FTEL-12 
      STA VALTB         TABLE 
      LDB FLBFP 
      ADB .+7 
      STB FLBFP 
      ISZ FLBC2     TEST FOR ANY MORE.
      JMP FLB16 
      STA PBPTR     ADVANCE PBPTR TO
      JMP SCHBL       FIRST UNUSED WORD 
* 
* 
* FLBCH GETS THE NEXT CHARACTER OUT OF THE FILES
* STATEMENT. IF FLBCM=1, IT ASSUMES A COMMA HAS BEEN
* SEEN AND RETURNS A BLANK. OTHERWISE IF THE CHARAC-
* TER IS A COMMA, IT SETS FLBCM AND RETURNS A BLANK.
* IT ALSO RETURNS BLANKS AT THE END OF THE CODE.
* 
FLBCH NOP 
      LDA .+40B     RETURN BLANK IF 
      LDB FLBCM     FLBCM IS SET. 
      SZB 
      JMP FLBCH,I 
      LDB FLBCP     GET CHAR. POINTER.
      INB           OTHERWISE BUMP
      CPB FLBP       IF END OF STATEMENT, 
      JMP FLBCH,I   RETURN A BLANK. 
      STB FLBCP      POINTER. 
      CLE,ERB       GET NEXT CHAR.
      LDA 1,I 
      SEZ,RSS 
      ALF,ALF       ROTATE IF NECESSARY.
      AND B177      MASK. 
      SZA,RSS       SKIP 0'S. 
      JMP FLBCH+1 
      ADA M96 
      SSA,RSS       LOWER CASE? 
      ADA M32       YES, MAKE INTO UPPER CASE 
      ADA .140      NO
      CPA .+54B     TEST FOR COMMA. 
      RSS 
      JMP FLBCH,I   NOT A COMMA.
      ISZ FLBCM     IF COMMA, SET FLAG AND GO 
      JMP FLBCH+1    RETURN A BLANK.
* 
FLB$  EQU LTEMP     * OR $ FLAG 
FLBCM EQU LTEMP+1   COMMA FLAG
FLBUF EQU LTEMP+6   INTERIM FILE TABLE INDEX
FLBFP EQU LTEMP+7   INTERIM FILE TABLE POINTER
FLBC1 EQU LTEMP+8   FILE COUNTER (NEG)
FLBC2 EQU LTEMP+9 
FLBP  EQU LTEMP+10  END OF FILE STATEMENT POINTER 
FLBCP EQU LTEMP+11  FILE STATEMENT CHARACTER POINTER
FLBID EQU LTEMP+12  USER ID STORAGE 
FLBFS EQU LTEMP+13  POINTER TO USERS FUSS TABLE 
FLBFC EQU LTEMP+14  FILE STATEMENT COUNTER (NEG)
FLBFF EQU LTEMP+15  POINTER TO 4 WORD AREA CONTAIN- 
*                                   ING POINTERS TO THE FILES 
*                                   STATEMENTS
FILBP DEF FILBF     POINTER TO 131 WORD TEMPORARY 
*                                   FILE TABLE BUFFER 
$FLB  EQU * 
FUSCH BSS 1         FUSS TABLE SEARCH POINTER 
