
MTD   NOP 
      STA BUFL      SAVE BUFFER LENGTH
      STB BUFA        AND ADDRESS 
MTD1  JSB TSTAT     GET STATUS
      SLA           CONTROLLER BUSY?
      JMP RSTAT     YES, WAIT UNTIL FREE
MT.1  CLC DATA      NO, CLEAR 
MT.5  CLC CMND        CONTROL BITS
      CLE,SLB,RSS   UNIT ON-LINE? 
      JMP MTD2      YES 
      LDA D.25      NO
      LDB MTLMA     REQUEST 
      JSB TT35I,I     "AUTO"
      HLT 44B 
      JMP MTD1      TRY AGAIN 
* 
MTD2  LDA MTD,I     ISOLATE 
      AND DB7         REQUEST CODE
      ADA TBASE     JUMP TO 
      JMP 0,I         REQUEST PROCESSOR, (E)=0
* 
TBASE DEF *+1,I 
      DEF READT 
      DEF WRITE 
      DEF WEOF
      DEF REW 
      DEF POS 
      DEF RES 
      DEF GAP 
      DEF STAT      STATUS IN (B) 
      SPC 3 
* 
**  GAP (ERASE TAPE) REQUEST  **
* 
GAP   JSB WNEC      ENSURE WRITE ENABLED
      JSB DOGAP     ERASE TAPE
      JMP MEOT      PAST EOT MARK, EXIT TO (P+2)
      JMP TEXIT     EXIT TO (P+4) 
      SPC 3 
* 
**  REWIND/STANDBY REQUEST  **
* 
RES   LDB DB105     PERFORM 
      JSB XCMND       REWIND/STANDBY
      JMP MEOT      EXIT TO (P+2) 
      SKP 
* 
**  POSITION TAPE REQUEST  ** 
* 
POS   LDB BUFL      LOAD FILE POSITIONING COUNT 
      SZB,RSS       ZERO? 
      JMP POSC      YES, DO RECORDS 
      LDA DB200     NO, FSF/BSF COMMAND SKELETON
      JSB SPCNT     SETUP FOR FILE POSITIONING
POSF  JSB SPACE     SPACE ONE FILE
      ISZ SCNTR     DONE? 
      JMP POSF      NO
      LDA BUFL      YES 
      SSA           BACKWARDS MOTION? 
      ISZ BUFA      YES, BIAS 
      NOP             RECORD REQUEST
* 
POSC  LDB BUFA      LOAD RECORD POSITIONING COUNT 
      SZB,RSS       ZERO? 
      JMP TEXIT     YES, EXIT TO (P+4)
CLA   CLA           NO, FSR/BSR COMMAND SKELETON
      JSB SPCNT     SETUP FOR RECORD POSITIONING
POSR  JSB SPACE     SPACE ONE RECORD OR EOF MARK
      ISZ SCNTR     DONE? 
      JMP POSR      NO
      JMP TEXIT     YES, EXIT TO (P+4)
      SPC 3 
* 
**  REWIND REQUEST  **
* 
REW   LDB DB101     PERFORM 
      JSB XCMND       REWIND
      JMP MEOT      EXIT TO (P+2) 
      SPC 3 
* 
**  WRITE EOF MARK REQUEST  **
* 
WEOF  JSB WNEC      ENSURE WRITE ENABLED
MT.2  CLF DATA
WEOFR LDB DB211     WRITE 
      JSB XCMND       EOF MARK
      JSB TSTAT     PARITY OR 
      RBR             TIMING
      SLB,RSS           ERRORS? 
      JMP TEXIT     NO, EXIT TO (P+4) 
      LDB DB41      YES 
      JSB XCMND     BACKSPACE AND 
      JMP WEOFR       TRY AGAIN 
      SKP 
* 
**  WRITE REQUEST  ** 
* 
WRITE LDA DM3       SET 'PAST EOT MARK' 
      STA SPCNT       RETRY COUNTER 
      JSB WNEC      ENSURE WRITE ENABLED
      LDB DB31      SET COMMAND TO
      STB SPACE       'WRITE RECORD'
REWRT LDA LBUFL     'LDA BUFL'
      LDB OTADC     'OTA DATA,C'
      JSB IODMA     PERFORM TRANSFER, (E)=0 
      JMP TEXIT     OK
* 
      LDB DB41      PARITY OR TIMING ERROR
      JSB XCMND     BACKSPACE 
      JSB DOGAP     ERASE TAPE
      ISZ SPCNT 
      JMP REWRT     TRY AGAIN 
      JMP MEOT      3RD RETRY PAST EOT MARK 
      SPC 3 
* 
**  READ REQUEST  **
* 
READT LDA DM3       ALLOW THREE 
      STA SPCNT       READ ATTEMPTS 
      LDB DB23      SET COMMAND TO
      STB SPACE       'READ RECORD' 
RERED LDA CLA       'CLA' 
      LDB LIADC     'LIA DATA,C'
      CCE           (E)=1 
      JSB IODMA     PERFORM TRANSFER
      JMP ENDR      OK
* 
RFAIL ISZ SPCNT     ERROR, TRIED THREE TIMES? 
      JMP ROVER     NO
      JSB TSTAT     YES 
      SSA           EOF MARK SEEN?
      JMP MEOT      YES, EXIT TO (P+2)
      JMP MERR      NO, EXIT TO (P+3) 
ROVER LDB DB41      PERFORM 
      JSB XCMND       BACKSPACE 
      JMP RERED     TRY AGAIN 
* 
ENDR  SSA           EOF MARK READ?
      JMP MEOT      YES, EXIT TO (P+2)
      LDB RLEN      NO
      SSB           CONVERT 
      CMB,CCE,RSS     RECORD'S
      CLE,ERB           LENGTH
      SEZ,CLE             TO
      INB                   WORDS 
      LIA DMAL      REQUEST LENGTH
      SZA             SATISFIED?
      JMP ENDR1     NO
      LDA RQLN      YES 
      ADA 1         RECORD'S LENGTH 
      CLE,SZA         LESS THAN 
      SSA,RSS           REQUESTED LENGTH? 
      JMP ENDR2     NO
      JMP RFAIL     YES, (E)=0
ENDR1 IOR DMASK     COMPUTE 
      CMA,INA         DMA'S READ
      ADA RQLN          IN -(WORDS) 
      ADA 1         EQUAL TO
      CLE,SZA         RECORD'S LENGTH?
      JMP RFAIL     NO, (E)=0 
ENDR2 LDA RLEN      YES, SET (E)=0 IF RECORD'S AND
      XOR BUFL        REQUEST'S LENGTH ARE BOTH 
      ELA               IN WORDS OR CHARACTERS
      LDA RLEN      RETRIEVE RECORD'S LENGTH
      SEZ,RSS       NEED TO CONVERT?
      JMP ENDC      NO
      CMA,SSA,INA,RSS  YES, CONVERT RECORD'S
      ALS,SLA            LENGTH TO CHARACTERS 
      ARS                  OR WORDS AS APPROPIATE 
ENDC  ADB RQLN      READ LENGTH SHORTER 
      SSB             THAN REQUESTED LENGTH?
      STA BUFL      YES, RETURN LENGTH READ 
      SPC 3 
* 
*  RETURN TO CALLER 
* 
TEXIT ISZ MTD       NORMAL EXIT (P+4) 
MERR  ISZ MTD       ERROR EXIT (P+3)
MEOT  JSB TSTAT     EOF/EOT EXIT (P+2)
STAT  LDA 1         NOTE IF 
      AND DB40        EOT MARK
      STA EOTF          PASSED
      LDA BUFL      RETURN COUNT IF READ REQUEST
MT.6  CLC CMND      CLEAR COMMAND CONTROL BIT 
      ISZ MTD 
      JMP MTD,I 
      SPC 3 
* 
*  CHECK FOR WRITE ENABLED
* 
WNEC  NOP           STATUS IN (B) 
      RBR,RBR 
      SLB,RSS       WRITE ENABLED?
      JMP WNEC,I    YES 
      LDA D.19      NO
      LDB WNEA      REQUEST 
      JSB TT35I,I     WRITE 
      HLT 33B       ENABLE
      JMP MTD1      TRY AGAIN 
      SKP 
* 
*  PERFORM TAPE ERASURE 
* 
DOGAP NOP 
      LDB DB15      ERASE 
      JSB XCMND       TAPE
      JSB TSTAT 
      RBR,SLB,RBR   PROPERLY ERASED?
      JMP MERR      NO, EXIT TO (P+3) 
      RAL,RAL       YES 
      SSA,RSS       EOT MARK PASSED?
      ISZ DOGAP     NO
      JMP DOGAP,I 
      SPC 3 
* 
*  PREPARE FOR SPACING OPERATIONS 
* 
SPCNT NOP           SPACE COUNT IN (B)
      SSB           BACKWARDS MOTION REQUESTED? 
      JMP SPC1      YES 
      ADA D.3       NO, BUILD FORWARD SPACE COMMAND 
      CMB,INB,RSS   MAKE SPACE COUNT NEGATIVE 
SPC1  ADA DB41      BUILD BACKWARD SPACE COMMAND
      STA PCMND     SAVE COMMAND
SPC2  STB SCNTR     SAVE SPACE COUNT
      JSB ERRCK     PRE-SPACING BOT/EOT CHECK 
      JMP SPCNT,I   OK, (E)=0 
      CLE,SZB,RSS   EOT SEEN, FILE SPACING? 
      JMP MEOT      NO, TAKE EOT/EOF EXIT 
      LDB DB41      YES, BACKSPACE
      JSB XCMND       AND LOOP
      CCB               UNTIL EOT STATUS
      JMP SPC2            IS CLEAR
      SPC 3 
* 
*  PERFORM SPACING OPERATION
* 
SPACE NOP           (E)=0 
      LDB PCMND     PERFORM 
      JSB XCMND       SPACING 
      JSB ERRCK     POST-SPACING BOT/EOT CHECK
      JMP SPACE,I   OK, (E)=0 
      SZB,RSS       EOT SEEN BUT OPERATION ALLOWED
      JMP TEXIT     RECORD SPACING COMPLETED
SPAC1 JSB TSTAT     DID FILE SPACE FORWARD
      CLE,SSA         REACH EOF MARK? 
      JMP POSC      YES, DO RECORD POSITIONING
      LDB D.3       NO, CONTINUE
      JSB XCMND       FORWARD RECORD SPACING
      JMP SPAC1         UNTIL EOF MARK SENSED 
      SKP 
* 
*  VALIDATE SPACING OPERATION 
* 
ERRCK NOP 
      JSB TSTAT     GET STATUS
      LDB PCMND     B(1)=1 IF FSR/FSF, 0 IF BSR/BSF 
      BRS,CLE,ERB 
      RAL,ELA       (E)=1 IMPLIES AT BOT MARK 
*                                   A(15)=1 IMPLIES PAST EOT MARK 
*                                   A(0)=1 IMPLIES FORWARD REQUEST
      CME,SSA,SLA,RSS    SKIP IF FORWARD AND EOT SET
      SEZ,CLE,SLA,RSS    NO SKIP IF BACKWARD AND BOT
      BRS,SLB,BRS   (SKIPS) 
      JMP ERRCK,I   OK, EXIT TO (P+1) WITH (E)=0
* 
      ISZ SCNTR     POSSIBLE BOUNDARY CONDITION?
      JMP MEOT      NO, TAKE EOT/EOF EXIT 
      CPB D.2       YES, BACKSPACING OVER BOT?
      JMP MEOT      YES 
      SLA,RSS       NO, BACKFILE AT BOT?
      JMP POSC      YES, PRETEND BOT IS EOF MARK
      ISZ ERRCK     NO, FORWARD MOTION PAST EOT 
      JMP ERRCK,I   EXIT TO (P+2) 
      SPC 3 
* 
*  PERFORM DMA TRANSFER 
* 
IODMA NOP           (E)=0 FOR WRITE, (E)=1 FOR READ 
      STA IODM1     CONFIGURE FOR 
      STB IODM3       READ OR WRITE 
LBUFL LDA BUFL      LOAD TRANSFER REQUEST 
      SZA,RSS       ZERO? 
      JMP TEXIT     YES, EXIT TO (P+4)
      CMA,SSA,INA,RSS    NO, REQUEST IN WORDS?
      CMA,INA,RSS   YES 
      ARS           NO, ROUND UP TO -(WORDS)
      STA RQLN      SAVE REQUEST LENGTH 
      LDB BUFA      PREFIX CORE ADDRESS 
      RBL,ERB         WITH READ/WRITE BIT 
      CLC DMAL      OUTPUT THE
      OTB DMAL        BUFFER ADDRESS
      STC DMAL      SET DMA 
      OTA DMAL        WORD COUNT
      LDB MTCHN     LINK DMA TO 
      OTB DMAH      DATA CHANNEL
IODM1 LDA BUFL      CHANGED TO 'CLA' FOR READ 
      LDB SPACE     LOAD COMMAND
      CCE,RSS 
      JMP IODM1     (REJECT RETURN POINT) 
      JSB XCMND     INITIATE TRANSFER 
MT.3  STC DATA,C    ENABLE DATA TRANSFER
IODM2 SFC CMND      QUICK FLAG? 
      JMP IODM4     YES 
MT.4  SFS DATA      NO, DATA CHANNEL READY? 
      JMP IODM2     NO
IODM3 OTA DATA,C    OUTPUT LENGTH ('LIA' FOR READ)
      STC DMAH,C    NOW START DMA 
MT.7  SFS CMND      WAIT FOR
      JMP *-1         TRANSFER COMPLETION 
IODM4 CLC DATA      CLEAR 
      CLC DMAH        CONTROL BITS
      STF DMAH      "SATISFY" DMA 
      STA RLEN      SAVE LENGTH WORD FOR READ 
      JSB TSTAT     PARITY OR 
      RBR,SLB         TIMING ERROR? 
      ISZ IODMA     YES 
      JMP IODMA,I   (E)=0 
      SPC 3 
* 
*  EXECUTE CONTROLLER COMMAND 
* 
XCMND NOP           COMMAND IN (B)
XCLR  OTB CMND      OUTPUT COMMAND
MT.8  LIB CMND      COMMAND 
      RBR,RBR 
      RBR,SLB         ACCEPTED? 
      JMP CLEAR     NO
MT.9  STC CMND,C    YES, REQUEST ACTION 
      SEZ,CLE       READ OR WRITE?
      JMP XCMND,I   YES 
MT.10 SFS CMND      NO, WAIT FOR
      JMP *-1         REQUEST COMPLETION
      JMP XCMND,I 
* 
CLEAR LDB XCMND     PREPARE 
      ADB DM2         REJECT
      STB XCMND         RETURN
      CLE           (E)=0 
      LDB DB110     PERFORM 
      JMP XCLR        CLEAR 
      SPC 3 
* 
*  GET STATUS 
* 
TSTAT NOP 
RSTAT LIB CMND      LOAD STATUS 
      LDA 1 
      ALF,ALF 
      JMP TSTAT,I 
      HED MAGNETIC TAPE DRIVER CONFIGURATOR 
* 
**  CONFIGURATOR FOR MAG TAPE DRIVER  **
* 
* 
*  ENTER WITH THE MAG TAPE UNIT'S HIGH PRIORITY SELECT CODE IN (A). 
*  CONFIGURE ALL I/O INSTRUCTIONS IN THE DRIVER, SELECT UNIT 0, AND 
*  COMPUTE THE "DMA" MASK FOR THE HIGH ORDER BITS OF THE DMA WORD 
*  COUNT REGISTER.
* 
MTDIN NOP 
      AND DB77      MASK TO SELECT CODE 
      STA MTSCD       AND SAVE IT 
      CLA,INA       CONFIGURE MTWR
      STA MTVFA,I     FOR WRITE 
      LDB CON1A     POINTER TO I/O INSTRUCTION ADDRS
MTDI1 CPB CON3A     ALL INSTRUCTIONS CONFIGURED?
      JMP MTDI2     YES 
      LDA 1,I       NO, LOAD NEXT ONE 
      AND DM64      REPLACE THE OLD 
      IOR MTSCD       SELECT CODE 
      STA 1,I           WITH THE NEW ONE
      INB           MOVE TO NEXT INSTRUCTION ADDR 
      CPB CON2A     FINISHED DATA CHANNEL?
      ISZ MTSCD     YES, INCREMENT SELECT CODE
      JMP MTDI1 
* 
MTDI2 LIA CMND      LOOP
      ALF,ALF         WHILE 
      SLA               CONTROLLER
      JMP MTDI2           BUSY
      LDA SLUN0     SELECT
MTD.1 OTA CMND        UNIT 0
      CCA           COMPUTE 
      STC DMAL        MASK
      OTA DMAL          FOR DMA 
      LIA DMAL            WORD COUNT
      CMA                   REGISTER
      STA DMASK     SAVE IT 
      JMP MTDIN,I 
* 
* 
CON1  DEF MT.1      DATA CHANNEL INSTRUCTIONS 
      DEF MT.2
      DEF MT.3
      DEF MT.4
      DEF IODM4 
      DEF OTADC 
      DEF LIADC 
      DEF MTCHN 
CON2  DEF MT.5      COMMAND CHANNEL INSTRUCTIONS
      DEF MT.6
      DEF IODM2 
      DEF MT.7
      DEF XCLR
      DEF MT.8
      DEF MT.9
      DEF MT.10 
      DEF RSTAT 
      DEF MTDI2 
      DEF MTD.1 
CON3      EQU * 
      HED CONSTANTS, TEMPORARIES, ETC.
BUFL  BSS 1         MTD BUFFER ADDRESS / FILE COUNT 
BUFA  BSS 1         MTD BUFFER LENGTH / RECORD COUNT
EOTF  BSS 1         <>0 IMPLIES EOT MARK PASSED 
DMASK BSS 1         DMA WORD COUNT REGISTER MASK
PCMND EQU WNEC
SCNTR EQU IODMA 
RQLN  EQU WNEC
RLEN  EQU ERRCK 
MTSCD EQU MTD 
* 
DM64  DEC -64 
DM3   DEC -3
DM2   DEC -2
D.2   DEC 2 
D.3   DEC 3 
DB7   OCT 7 
DB15  OCT 15        ERASE TAPE COMMAND
DB23  OCT 23        READ RECORD COMMAND 
D.19  EQU DB23
DB31  OCT 31        WRITE RECORD COMMAND
D.25  EQU DB31
DB40  OCT 40
DB41  OCT 41        BACKSPACE RECORD COMMAND
DB77  OCT 77
DB101 OCT 101       REWIND COMMAND
DB105 OCT 105       REWIND/STANDBY COMMAND
DB110 OCT 110       CLEAR COMMAND 
DB200 OCT 200       FILE SPACE COMMAND SKELETON 
DB211 OCT 211       WRITE EOF MARK COMMAND
SLUN0 OCT 1400      SELECT UNIT 0 COMMAND 
* 
MTCHN OCT 20000     'CLC DATA' ON DMA COMPLETION
OTADC OTA DATA,C
LIADC LIA DATA,C
* 
MTLMA DEF MTLM
WNEA  DEF WNE 
TT35I DEF TTY35 
CON1A DEF CON1,I
CON2A DEF CON2,I
CON3A DEF CON3,I
MTVFA DEF MTVFL 
*                                                                [B]
      SUP 
MTLM  OCT 5103
      ASC 11,HANGE MAG TAPE TO AUTO 
      OCT 6400
WNE   OCT 5127
      ASC 8,RITE NOT ENABLED
      OCT 6400
      UNS 
      HED MAG TAPE DRIVER DRIVER WITH EOT PROCESSOR 
* 
*      THIS ROUTINE IS CALLED FOR MAG TAPE READS
* WHEN AN END OF TAPE IS ALLOWED. 
*      A READ OF 1036 WORDS IS ATTEMPTED INTO 
* THE BUFFER AT ADTBL 
* 
*      THE CALLING SEQUENCE IS: 
*     JSB MTRD
*     <EOF RETURN>
*     <TAPE ERROR RETURN>           B = STATUS
*     <NORMAL RETURN>   A = RECORD SIZE  B = STATUS 
* 
*      THE MTRD ROUTINE MAKES THE END OF TAPE CONDITION 
* TRANSPARENT TO THE CALLER.  END OF SET IS NOT CHECKED 
* BY MTRD.  CAUTION MUST BE TAKEN WHEN PROCESSING 
* END OF FILE CONDITIONS, AS THE NEXT RECORD IS ALREADY 
* IN THE BUFFER.
* 
MTRD  NOP 
      ISZ MTRRF     CHECK FOR RECORD ALREADY IN 
      RSS 
      JMP MTRCF     YES, CHECK IT 
MTRDE EQU * 
      LDA GM1L
      LDB MTRB
      JSB MTD                                    [B]
      OCT 0 
      JMP MTREF     END OF FILE READ
      RSS           TAPE ERROR
      ISZ MTRD
      ISZ MTRD
      STB MTRRF     SET MTRRF # -1
      JMP MTRD,I    RETURN
* 
* 
MTREF EQU * 
      LDA GM1L      TRY READ ON 
      LDB MTRB        NEXT RECORD 
      JSB MTD                                    [B]
      OCT 0 
      JMP MTREG     ANOTHER EOF, RETURN FIRST ONE 
      NOP           TAPE ERROR, IGNORE NOW
* 
*      RECORDS WITH THE CORRECT WORD COUNT FOR AN 
* END OF TAPE TRAILER LABEL WILL BE TREATED AS
* SUCH REGARDLESS OF ERRORS IN ORDER THAT PROCESSING CAN
* CONTINUE
* 
      CPA MTLEN     CHECK FOR LABEL SIZE
      JMP MTRLR     YES, GO GET NEXT REEL 
MTREG EQU * 
      STA MTRSA     SAVE LENGTH READ
      STB MTRSB       AND STATUS
      CCA 
      STA MTRRF     SET FLAG TO SAY RECORD IN 
      JMP MTRD,I    GIVE EOF RETURN 
* 
*      PRETEND THAT WE JUST NOW READ THE RECORD 
* 
MTRCF EQU * 
      LDA MTRSB     GET THE STATUS TO A 
      AND MTRMS     LEAVE EOF AND ERROR BITS
      ALF,CLE,ALF   EOF BIT TO SIGN 
      SSA           END OF FILE?
      JMP MTREF     YES, PROCESS IT 
      SZA,RSS       SKIP IF ERRORS
      ISZ MTRD
      ISZ MTRD
      LDA MTRSA     GET THE RECORD LENGTH 
      LDB MTRSB       AND STATUS BACK 
      JMP MTRD,I
* 
*      REQUEST THE NEXT REEL
* 
MTRLR EQU * 
      ISZ MTRRN,I   INCREMENT THE CURRENT REEL NUMBER 
MTRDU EQU * 
      JSB MTD       REWIND AND STANDBY           [B]
      OCT 5 
      LDA MTRRN,I   GET THE REEL NUMBER 
      CLB 
      DIV GD10      MAKE INTO TWO DIGITS
      ALF,ALF 
      IOR B 
      IOR GSCZZ     MAKE INTO ASCII CODES 
      STA ERLN      STORE INTO THE ERROR MESSAGE [B]
      LDA GD35
      LDB GNXRN     "MOUNT REEL # XX. PRESS RUN"
      JSB GTT35,I 
      HLT 77B       WAIT FOR THE OPERATOR 
* 
*      READ THE NEXT LABEL
* 
      JSB MTD       REWIND                       [B]
      OCT 3 
      LDA MTLEM     ALLOW ONE EXTRA WORD
      LDB MTRVG     ADDRESS OF SECOND BUFFER
      JSB MTD                                    [B]
      OCT 0 
      JMP MTRDU     EOF. . . NOT OUR TAPE 
      JMP MTRDU     TAPE ERROR. . . DO I KNOW YOU?
      CPA MTLEN 
      RSS 
      JMP MTRDU     WRONG LENGTH
* 
      LDA GM7       IGNORE                       [B]
      STA MTRRF       LEVEL CODES                [B]
      LDA MTRTG     => FIRST TAPE LABEL BUFFER
      STA MTRSA 
      LDB MTRVG     => SECOND LABEL BUFFER
      SKP 
MTRDZ EQU * 
      LDA B,I       CHECK LABEL FOR 
      CPA MTRSA,I     FOR CORRECTNESS 
      RSS           THIS WORD OKAY
      JMP MTRDU     OOPS. . . WRONG SYSTEM OR SOMETHING 
      INB           ADVANCE THE 
      ISZ MTRSA       POINTERS
      ISZ MTRRF 
      JMP MTRDZ 
* 
      JMP MTRDE     GO READ NEXT RECORD FOR THE 
*                                   NICE MAN
GM1L  DEC -1036 
GM7   DEC -7                                     [B]
GD10  DEC 10
GD35  DEC 35
MTRMS OCT 733       TAPE ERROR AND EOF BITS 
GSCZZ ASC 1,00
GNXRN DEF NXRN      => "MOUNT REEL # XX. PRESS RUN" 
GTT35 DEF TTY35 
MTLEM ABS -TLEN-1 
MTLEN ABS -TLEN 
MTRRN DEF TLRT+TLRN  => REEL NUMBER 
MTRTG DEF TLRT      => FIRST TAPE LABEL BUFFER
MTRVG DEF TLRV      => SECOND TAPE LABEL BUFFER 
MTRB  DEF ADTBL     => READ BUFFER
MTRRF BSS 1 
MTRSA BSS 1 
MTRSB BSS 1 
*                                                                [B]
      SUP 
NXRN  OCT 6412
      ASC 9,MOUNT REEL NUMBER 
ERLN  NOP 
      ASC 6,.  PRESS RUN
      OCT 6400
      UNS 
      SPC 3 
* 
*  CHECK FOR PAGE OVERFLOW
* 
      LDA 24000B                                 [B]
