
ASMB,A,B,L
      HED I/O PROCESSOR BOOTSTRAP 
      ORG 2 
C2    EQU 11B      2116 TO 2114 CHANNEL 
PR    EQU 13B      PHOTOREADER CHANNEL
* 
*      THIS PROGRAM IS THE FIRST OF THE TWO PROGRAMS
* ON THE I/O PROCESSOR PROGRAM TAPE.  IT READS
* SINGLE CHARACTERS AND PASSES THEM TO THE BASIC
* BINARY LOADER IN THE I/O PROCESSOR ON ONE OF THE
* COMMUNICATIONS CHANNELS.
* 
*      THIS PROGRAM MAY BE USED TO LOAD ANY 
* ABSOLUTE BINARY TAPE INTO THE I/O PROCESSOR 
* 
TWP   EQU * 
      STC PR,C     START PHOTOREADER
      SFS PR       WAIT FOR A CHARACTER 
      JMP *-1 
      LIA PR       GET CHARACTER FROM PHOTOREADER 
      CLB           RESET COUNTER                [C]
TWP10 SFC C2        WAIT FOR LOP TO ACKNOWLEDGE  [C]
      JMP TWP30                                  [C]
      INB,SZB       INCREMENT TIME-OUT COUNTER   [C]
      JMP TWP10                                  [C]
      CLC PR        TIMED OUT - TURN OFF         [C]
      HLT 77B         PHOTO READER AND HALT      [C]
      JMP TWP                                    [C]
* 
TWP30 OTA C2        OUTPUT CHARACTER             [C]
      STC C2,C     SET FLAG 
      JMP TWP      GET NEXT CHARACTER 
      END 
