
      HED MAGTAPE 
* THE MAGTAPE COMMAND IS USED TO TELL THE SYSTEM OF THE EXISTENCE 
* OF A MAGTAPE UNIT. THE FORMAT IS: 
*         MAGTAPE-SELECT CODE 
* THE SELECT CODE SPECIFIED IS THE LOWER NUMBERED OF THE 2
* CODES FOR THE TAPE. A CODE OF 0 INDICATES THAT NO TAPE EXISTS.
      SPC 1 
      ORG LIBRA 
      JSB MAGDG     GET FIRST DIGIT.
      ALF,RAR       MULTIPLY BY 8 AND SAVE. 
      STA LTEMP 
      SZA,RSS 
      JMP MAG1
      JSB MAGDG     GET 2ND DIGIT.
      ADA LTEMP     COMPUTE #.
      STA LTEMP 
      CPA B77       ILLEGAL IF 77.
      JMP LFRER 
      ADA .-17B     LESS THAN 
      SSA             17 OCTAL? 
      JMP LFRER     YES 
MAG1  JSB T35CQ     NO, NEXT CHARACTER CR?       [B]
      RSS           YES                          [B]
      JMP LFRER     NO, ERROR                    [B]
      LDA LTEMP     STORE SELECT CODE            [B]
      STA MAGSC       IN SYSTEM LOCATION         [B]
      JMP LEND                                   [B]
* 
MAGDG NOP           GET AN OCTAL DIGIT. 
      JSB T35CQ 
      JMP LFRER     FAIL IF NONE. 
      STA 1 
      AND .-8       TEST FOR OCTAL DIGIT. 
      CPA .+60B 
      RSS 
      JMP LFRER     FAIL. 
      XOR 1         CONVERT TO BINARY.
      JMP MAGDG,I    RETURN.
$MAG  EQU * 
      HED PHONES
*  THE FORMAT FOR THE PHONES COMMAND IS:
* 
*     PHONES-TIME LIMIT 
* 
* TIME LIMIT REFERS TO THE NUMBER OF SECONDS ALLOWED A USER TO
* LOG ON. IT IS ORIGINALLY ASSUMED TO BE 120. 
* 
      ORG LIBRA 
      CLA           INITIALIZE COUNT TO 0.
PHO6  STA LTEMP 
      ADA M256      TEST FOR
      SSA,RSS         TOO 
      JMP LFRER         BIG 
      JSB T35CQ     GET A CHAR. 
      JMP PHO5      LAST CHAR.
      ADA M72B      TEST FOR DIGIT. 
      SSA,RSS 
      JMP LFRER 
      ADA .+10
      SSA 
      JMP LFRER 
      LDB LTEMP     MULTIPLY OLD VALUE BY 10 AND
      RBL,RBL        ADD IN NEW.
      ADB LTEMP 
      RBL 
      ADA 1 
      JMP PHO6
PHO5  LDA LTEMP     A=INPUT VALUE 
      SZA,RSS       TEST FOR ZERO 
      JMP LFRER     ERROR 
      IOR PHO       SEND TIME LIMIT 
      JSB S14SC,I     TO 2114 
      JMP LEND      TERMINATE 
$PHO  EQU * 
      HED PRINTER 
*  THE PRINTER COMMAND IS USED TO TELL THE SYSTEM OF THE EXISTANCE
*  OF A LINE PRINTER.  THE FORMAT IS: 
*         PRINTER-SELECT CODE[*][*] 
*  A CODE OF 0 INDICATES THAT NO PRINTER EXISTS.
      SPC 1 
      ORG LIBRA 
      JSB PRIDG     GET FIRST DIGIT 
      ALF,RAR       MULTIPLY BY 8 
      STA LTEMP       AND SAVE
      SZA,RSS       TEST FOR ZERO 
      JMP PRI1      YES 
      JSB PRIDG     GET SECOND DIGIT
      ADA LTEMP     COMPUTE NUMBER
      STA LTEMP 
      ADA .-16B     LESS THAN 
      LDB NPORT                                  [B]
      ADB .+16                                   [B]
      SSB                                        [B]
      ADA .-3B                                   [B]
      SSA             OCTAL 16? 
      JMP LFRER     YES - ILLEGAL 
      ADA .-7B      GREATER THAN
      SSB                                        [B]
      ADA .+3B                                   [B]
      SSA,RSS         OCTAL 24? 
      JMP LFRER     YES - ILLEGAL 
      JSB T35CQ     GET NEXT CHARACTER
      JMP PRI2      CR - MUST BE 2778A
      CPA .+52B     ASTERISK? 
      RSS           YES 
      JMP LFRER     NO - ERROR
      LDA LTEMP     FLAG
      IOR BIT15       AS
      STA LTEMP         2610A 
      JSB T35CQ     GET NEXT CHARACTER
      JMP PRI2      CR
      CPA .+52B     ASTERISK? 
      RSS           YES 
      JMP LFRER     NO - ERROR
      LDA LTEMP     FLAG
     IOR BIT14       AS 
      STA LTEMP         2767A 
PRI1  JSB T35CQ     NEXT CHARACTER
      RSS             CARRIAGE RETURN?
      JMP LFRER     NO - ERROR
PRI2  LDA LTEMP 
      ALF,ALF       MOVE TO BITS 12-8 
      IOR PSC       TELL I/O
      JSB S14SC,I     PROCESSOR 
      CLA           CLEAR THE LINE PRINTER
      STA PRIST       USER INDICATOR
      JMP LEND      TERMINATE 
* 
PRIDG NOP           GET OCTAL DIGIT 
      JSB T35CQ 
      JMP LFRER     ERROR - NO INPUT
      STA 1 
      AND .-8       TEST FOR OCTAL DIGIT
      CPA .+60B 
      RSS 
      JMP LFRER     ERROR - NOT OCTAL 
      XOR 1         CONVERT TO BINARY 
      JMP PRIDG,I 
$PRI  EQU * 
      HED SPEED 
*  THIS COMMAND IS USED TO CONFIGURE A PORT FOR A 
*  SPECIFIED SPEED & CHAR. SIZE.
* 
*  THE FORMAT FOR THIS OPERATORS COMMAND IS:
* 
*         SPEED-BAUD RATE,CHAR. SIZE OR *,PORT#,PORT#,......CR
*  OR 
*         SPEED-BAUD RATE,CHAR. SIZE OR *,ALL  CR 
* 
      ORG LIBRA 
      LDA NPORT     SET UP LIMIT. 
      STA SPDCN 
      LDA PTABL     SET TABLE ADDRESS.
      STA TABPN 
      CLA           ZERO OUT COUNTERS.
      STA SPDTM 
      STA SPDOC 
      STA SPDNR     ZERO OUT SPEED INDICATOR. 
      STA SPDSZ     ZERO OUT CHAR.SIZE INDICATOR. 
      JSB T35CH,I   GET 1ST DIGIT OF SPEED. 
      JMP LFRER     CR. ERROR!
SPD01 EQU * 
      JSB SPDDG     NO CR. DIGIT? 
      JSB SPDCK     YES. COMPUTE SPEED INDICATOR. 
* 
      JSB T35CH,I   GET NEXT CHAR.
      JMP LFRER     CR. ERROR!
      CPA .+54B     NO CR. COMMA? 
      RSS 
      JMP SPD01     NO. 
      LDA SPDNR     YES. CHECK BAUD RATE. 
      ADA BAUDL 
      SSA           LESS THAN 5B? 
      JMP LFRER     YES. ERROR! 
      LDA SPDNR 
      ADA BAUDH 
      SSA,RSS       GREATER THAN 277B?
      JMP LFRER     YES. ERROR! 
* 
      JSB T35CH,I   NO. GET NEXT CHAR.
      JMP LFRER     CR. ERROR!
      CPA .+52B     NO CR. ASTERIK? 
      RSS 
      JMP SPD14     NO. 
      JSB T35CH,I   YES. GET NEXT CHAR. 
      JMP LFRER     CR. ERROR!
      CPA .+54B     NO CR. COMMA? 
      JMP SPD03     YES.
      JMP LFRER     NO. ERROR!
SPD14 EQU * 
      JSB SPDDG     DIGIT?
      JSB SPDCL     YES. COMPUTE CHAR. SIZE.
      JSB T35CH,I   GET NEXT CHAR.
      JMP LFRER     CR. ERROR!
      CPA .+54B     NO CR. COMMA? 
      RSS 
      JMP SPD14     NO. 
      LDA SPDSZ     CHECK SPEED INDICATOR.
      CPA .+2       =2? 
      JMP SPD03     YES.
      CPA .+1       NO. =1? 
      RSS           YES.
      JMP LFRER     NO. ERROR!
SPD03 EQU * 
      JSB T35CH,I   GET NEXT CHAR.
      JMP LFRER     CR. ERROR!
      CPA SP.A      NO CR. =A?
      JMP SPD9      YES.
SPD16 EQU * 
      JSB SPDDG     NO. DIGIT?
      JSB SPDSP     YES. COMPUTE PORT NR. 
      JSB T35CH,I   GET NEXT CHAR.
      JMP SPD4      CR. 
      CPA .+54B     NO CR. COMMA? 
      RSS           YES.
      JMP SPD16     NO. 
SPD4  EQU * 
      LDA SPDTM     CHECK LIMIT.
      ADA SPDCN 
      SSA,RSS       GREATER THAN LIMIT? 
      JMP LFRER     YES. ERROR! 
* 
      LDA SPDTM     NO. PORT LOGGED ON? 
      JSB SPD11 
      LDA SPDTM     NO. SET PORT# INTO TABLE. 
      JSB SPSET 
      LDA T35LC     PICK UP LAST CHAR.
      CPA .+15B     WAS IT A CR?
      JMP SPD10     YES. CONFIGURE PORT(S). 
      CLA           NO. 
      STA SPDTM 
      JSB T35CH,I   GET NEXT CHAR.
      JMP SPD10     CR. 
      JMP SPD16     NO CR.
* 
SPD9  EQU * 
      JSB T35CH,I   GET NEXT CHAR.
      JMP LFRER     CR. ERROR!
      CPA SP.L      NO CR. =L?
      RSS 
      JMP LFRER     NO. ERROR!
      JSB T35CH,I   YES. GET NEXT CHAR. 
      JMP LFRER     CR. ERROR!
      CPA SP.L      NO CR. =L?
      RSS 
      JMP LFRER     NO. ERROR!
      JSB T35CH,I   YES. GET NEXT CHAR. 
      RSS           CR. START CONFIGURATION.
      JMP LFRER     NO CR. ERROR! 
      CLA 
      STA SPDOC 
SPD18 EQU * 
      JSB SPD11     PORT LOGGED ON? 
      ISZ SPDCN     NO. BUMP COUNTER. 
      RSS 
      JMP SPD19     PORTS CHECKED.
      ISZ SPDOC     BUMP PORT NUMBER. 
      LDA SPDOC 
      JMP SPD18 
SPD19 EQU * 
      LDA NPORT     SET UP COUNTER. 
      STA SPDCN 
      CLA           SET UP FOR PORT#00. 
      STA SPDOC 
SPD6  EQU * 
      JSB SPD7      CONFIGURE PORT. 
      ISZ SPDCN     BUMP COUNTER. 
      RSS 
      JMP LEND      DONE! 
      ISZ SPDOC     NOT DONE. 
      LDA SPDOC 
      JMP SPD6      TREAT NEXT PORT.
* 
SPD7  EQU * 
      NOP           PORT CONFIGURATION SUBROUTINE.
      STA SPDPO     SAVE PORT NR. 
      LDB CHS       B= CHAR. SIZE OPCODE. 
      ALF,ALF       ROTATE PORT NR. 
      IOR B         MERGE PORT NR.
      LDB SPDSZ     B= CHAR. SIZE INDICATOR.
      BLF,RBL       ROTATE INTO POSITION. 
      IOR B         MERGE CHAR. SIZE. 
      JSB S14SC,I   TELL 2114.
      LDA SPDPO     A=PORT NR.
      LDB SPE       B= SPEED OPCODE.
      ALF,ALF       ROTAEE PORT NR. 
      IOR B         MERGE PORT NR.
      LDB SPDNR     B= SPEED INDICATOR. 
      IOR B         MERGE SPEED.
      JSB S14SC,I   TELL 2114.
      JMP SPD7,I    RETURN. 
* 
SPDDG EQU * 
      NOP           DETERMINES IF CHAR. IS A DIGIT. 
      ADA M72B
      SSA,RSS       DIGIT?
      JMP LFRER     NO. ERROR?
      ADA .+10      MAY BE. 
      SSA 
      JMP LFRER     NOT A DIGIT. ERROR! 
      JMP SPDDG,I   DIGIT. OK! EXIT!
* 
SPSET EQU * 
      NOP           SET PORT NR. INTO TABLE.
      LDB TABPN     GET POINTER.
      CPB PEND      TABLE LIMIT EXCEEDED? 
      JMP LFRER     YES. ERROR! 
      STA B,I       NO. SET PORT NR. INTO TABLE.
      ISZ SPDOC     BUMP COUNTER. 
      ISZ TABPN     BUMP POINTER. 
      JMP SPSET,I   EXIT. 
* 
SPD10 EQU * 
      LDA SPDOC     SET UP COUNTER FOR NUMBER 
      CMA,INA       OF PORTS
      STA SPDOC     TO BE CONFIGURED. 
      LDA PTABL     SET UP TABLE POINTER. 
      STA TABPN 
SPD13 EQU * 
      LDA TABPN,I   GET PORT NR.
      JSB SPD7      CONFIGURE PORT. 
      ISZ SPDOC     BUMP COUNTER. 
      RSS 
      JMP LEND      DONE! 
      ISZ TABPN     NOT YET. BUMP POINTER.
      JMP SPD13     GO BACK.
* 
* 
SPDCK EQU * 
      NOP 
      STA SPDPO     SAVE (A). 
      LDA SPDNR     UPDATE
      MPY .+10
      ADA SPDPO          SPEED
      STA SPDNR     INDICATOR.
      JMP SPDCK,I 
* 
* 
SPDCL EQU * 
      NOP 
      STA SPDPO     SAVE (A). 
      LDA SPDSZ     UPDATE
      MPY .+10           CHAR.
      ADA SPDPO               SIZE
      STA SPDSZ     INDICATOR.
      JMP SPDCL,I 
* 
* 
SPDSP EQU * 
      NOP 
      STA SPDPO     SAVE (A). 
      LDA SPDTM     UPDATE
      MPY .+10
      ADA SPDPO          PORT 
      STA SPDTM     NUMBER. 
      JMP SPDSP,I 
* 
* 
*  ENTER WITH (A)=PORT NR.
* 
SPD11 NOP 
      MPY .+TTY01-TTY00 
      ADA DTTY0     A=> ?FLAG 
      ADA .+?ID     A=> ?ID 
      LDA A,I       A= ?ID
      SZA,RSS       USER LOGGED ON? 
      JMP SPD11,I    NO.
      LDA T35B1     PUT ERROR 
      STA MOVED 
      LDA SPD12       MESSAGE 
      STA MOVES 
      LDB .-7           INTO TTY35
      JSB MOVEW 
      LDA .+14            BUFFER AND
      LDB T35B1 
      JMP LEND2             PRINT IT
SPD12 DEF *+1 
      OCT 5116      LF-N
      ASC 6,O CONF. DONE
* 
* 
* 
* 
PTABL DEF *+1 
      BSS 32
PEND  DEF * 
SPDNR EQU LTEMP 
SPDTM EQU LTEMP+1 
SPDCN EQU LTEMP+2 
SPDPO EQU LTEMP+3 
TABPN EQU LTEMP+4 
SPDOC EQU LTEMP+5 
SPDSZ EQU LTEMP+6 
BAUDH OCT -300
BAUDL OCT -5
SP.A  OCT 101 
SP.L  OCT 114 
$SPE  EQU * 
      HED BREAK 
* 
*  THIS COMMAND IS USED TO ENABLE THE ABORT CAPA- 
*  BILITY WITH THE "BREAK" KEY DESPITE THE FACT 
*  THAT THE ABORT CAPABILITY WAS DISABLED BY EVA- 
*  LUATION OF THE BRK(0) FUNCTION.
* 
*  THE FORMAT OF THIS OPERATORS COMMAND IS: 
* 
*         BREAK-PORT NR 
* 
* 
      ORG LIBRA 
      CLA           CLEAR STORAGE OF
      STA BRKPN          PORT NR. 
      JSB T35CH,I   GET 1ST DIGIT OF PORT NR. 
      JMP LFRER     CR. ERROR?
      JSB BRKDG     NO CR. DIGIT? 
      JSB BRKSP     YES. COMPUTE PORT NR. 
      JSB T35CH,I   GET NEXT CHAR.
      JMP BREK1     CR. 
      JSB BRKDG     NO CR. DIGIT? 
      JSB BRKSP     YES. COMPUTE PORT NR. 
      JSB T35CH,I   GET NEXT CHAR.
      RSS           CR. 
      JMP LFRER     NO CR. ERROR! 
BREK1 EQU * 
      LDA BRKPN     CHECK LIMIT.
      LDB NPORT 
      ADA B 
      SSA,RSS       PORT NR. > AVAILABLE PORTS? 
      JMP LFRER     YES. ERROR! 
      LDA BRKPN     NO. CHECK IF USER IS LOGGED ON. 
      MPY .+TTY01-TTY00 
      ADA DTTY0     A=>?FLAG
      ADA .+?ID     A=> ?ID 
      LDA A,I       A= ?ID
      SZA,RSS       USER LOGGED ON? 
      JMP BREK2     NO. PRINT ERROR MESSAGE.
      LDA BRKPN     YES. SET CBFLG BIT. 
      MPY .+TTY01-TTY00 
      ADA DTTY0     A=> ?FLAG 
      LDB A         B=> ?FLAG 
      LDA  A,I      A= ?FLAG
      IOR CBFLG     SET CBFLG BIT.
      STA B,I 
      JMP LEND      DONE. 
* 
BREK2 EQU * 
      LDA T35B1     PUT ERROR 
      STA MOVED 
      LDA BREK3       MESSAGE 
      STA MOVES 
      LDB .-10          INTO TTY35
      JSB MOVEW 
      LDA .+20            BUFFER AND
      LDB T35B1 
      JMP LEND2             PRINT IT
BREK3 DEF *+1 
      OCT 5125      LF-U
      ASC 9,SER NOT LOGGED ON 
* 
* 
BRKDG EQU * 
      NOP           DETERMINES IF CHAR. IS A DIGIT. 
      ADA M72B
      SSA,RSS       DIGIT?
      JMP LFRER     NO. ERROR!
      ADA .+10      MAY BE. 
      SSA 
      JMP LFRER     NOT A DIGIT! ERROR! 
      JMP BRKDG,I   DIGIT. OK! EXIT!
* 
* 
BRKSP EQU * 
      NOP 
      STA BRKPO     SAVE DIGIT. 
      LDA BRKPN     UPDATE
      MPY .+10
      ADA BRKPO          PORT 
      STA BRKPN               NUMBER. 
      JMP BRKSP,I 
* 
* 
BRKPO EQU LTEMP 
BRKPN EQU LTEMP+1 
$BRE  EQU * 
      HED LANGUAGE PROCESSOR ERROR MESSAGES 
      SUP 
      ORG LIBRA 
      DEC -7
      ASC 15,OUT OF STORAGE 
      DEC -13 
      ASC 15,ILLEGAL OR MISSING INTEGER 
      DEC -13 
      ASC 15,EXTRANEOUS LIST DELIMITER
      DEC -14 
      ASC 15,MISSING ASSIGNMENT OPERATOR
      DEC -15 
      ASC 15,CHARACTERS AFTER STATEMENT END 
      DEC -14 
      ASC 15,MISSING OR ILLEGAL SUBSCRIPT 
      DEC -15 
      ASC 15,MISSING OR BAD LIST DELIMITER
      DEC -14 
      ASC 15,MISSING OR BAD FUNCTION NAME 
      DEC -15 
      ASC 15,MISSING OR BAD SIMPLE VARIABLE 
      DEC -12 
      ASC 15,MISSING OR ILLEGAL 'OF'
      DEC -13 
      ASC 15,MISSING OR ILLEGAL 'THEN'
      DEC -12 
      ASC 15,MISSING OR ILLEGAL 'TO'
      DEC -13 
      ASC 15,MISSING OR ILLEGAL 'STEP'
      DEC -14 
      ASC 15,MISSING OR ILLEGAL DATA ITEM 
      DEC -8
      ASC 15,ILLEGAL EXPONENT 
      DEC -10 
      ASC 15,SIGN WITHOUT NUMBER
      DEC -14 
      ASC 15,MISSING RELATIONAL OPERATOR
      DEC -11 
      ASC 15,ILLEGAL READ VARIABLE
      DEC -14 
      ASC 15,ILLEGAL SYMBOL FOLLOWS 'MAT' 
      DEC -15 
      ASC 15,MATRIX CANNOT BE ON BOTH SIDES 
      DEC -15 
      ASC 15,NO '*' AFTER RIGHT PARENTHESIS 
      DEC -15 
      ASC 15,NO LEGAL BINARY OPERATOR FOUND 
      DEC -12 
      ASC 15,MISSING LEFT PARENTHESIS 
      DEC -13 
      ASC 15,MISSING RIGHT PARENTHESIS
      DEC -15 
      ASC 15,PARAMETER NOT STRING VARIABLE
      DEC -11 
      ASC 15,UNDECIPHERABLE OPERAND 
      DEC -15 
      ASC 15,MISSING OR BAD ARRAY VARIABLE
      DEC -15 
      ASC 15,STRING VARIABLE NOT LEGAL HERE 
      DEC -15 
      ASC 15,MISSING OR BAD STRING OPERAND
      DEC -8
      ASC 15,NO CLOSING QUOTE 
      DEC -14 
      ASC 15,72 CHARACTERS MAX FOR STRING 
      DEC -15 
      ASC 15,STATEMENT HAS EXCESSIVE LENGTH 
      SPC 2 
      ORG LIBRA 
      DEC -15 
      ASC 15,MISSING OR BAD FILE REFERENCE
      DEC -14 
      ASC 15,'PRINT' MUST PRECEDE 'USING' 
      DEC -15 
      ASC 15,ILLEGAL OPERAND AFTER 'USING'
      DEC -15 
      ASC 15,VARIABLE MISSING OR WRONG TYPE 
      DEC 15
      ASC 15,UNDEFINED STATEMENT REFERENCE
      DEC 13
      ASC 15,NEXT WITHOUT MATCHING FOR
      DEC 12
      ASC 15,SAME FOR-VARIABLE NESTED 
      DEC 11
      ASC 15,FUNCTION DEFINED TWICE 
      DEC 13
      ASC 15,VARIABLE DIMENSIONED TWICE 
      DEC 12
      ASC 15,LAST STATEMENT NOT 'END' 
      DEC -7
      ASC 15,UNMATCHED FOR
      DEC -9
      ASC 15,UNDEFINED FUNCTION 
      DEC -8
      ASC 15,ARRAY TOO LARGE
      DEC -14 
      ASC 15,ARRAY OF UNKNOWN DIMENSIONS
      DEC 7 
      ASC 15,OUT OF STORAGE 
      DEC 13
      ASC 15,DIMENSIONS NOT COMPATIBLE
      DEC -14 
      ASC 15,CHARACTERS AFTER COMMAND END 
      DEC -13 
      ASC 15,BAD FORMAT OR ILLEGAL NAME 
      DEC -13 
      ASC 15,MISSING OR PROTECTED FILE
      DEC 11
      ASC 15,GOSUBS NESTED TEN DEEP 
      DEC 13
      ASC 15,RETURN WITH NO PRIOR GOSUB 
      DEC 12
      ASC 15,SUBSCRIPT OUT OF BOUNDS
      DEC 11
      ASC 15,NEGATIVE STRING LENGTH 
      DEC 15
      ASC 15,NON-CONTIGUOUS STRING CREATED
      DEC 8 
      ASC 15,STRING OVERFLOW
      DEC 6 
      ASC 15,OUT OF DATA
      DEC 9 
      ASC 15,DATA OF WRONG TYPE 
      DEC 12
      ASC 15,UNDEFINED VALUE ACCESSED 
      DEC 9 
      ASC 15,MATRIX NOT SQUARE
      DEC 15
      ASC 15,REDIMENSIONED ARRAY TOO LARGE
      DEC 11
      ASC 15,NEARLY SINGULAR MATRIX 
      DEC 12
      ASC 15,LOG OF NEGATIVE ARGUMENT 
      SPC 2 
      ORG LIBRA 
      DEC 12
      ASC 15,SQR OF NEGATIVE ARGUMENT 
      DEC 9 
      ASC 15,ZERO TO ZERO POWER 
      DEC 15
      ASC 15,NEGATIVE NUMBER TO REAL POWER
      DEC 15
      ASC 15,ARGUMENT OF SIN OR TAN TOO BIG 
      DEC -15 
      ASC 15,OVER/UNDERFLOWS - WARNING ONLY 
      DEC -15 
      ASC 15,LAST INPUT IGNORED, RETYPE IT
      DEC -13 
      ASC 15,TOO MANY FILES STATEMENTS
      DEC 14
      ASC 15,NON-EXISTENT FILE REQUESTED
      DEC 15
      ASC 15,WRITE TRIED ON READ-ONLY FILE
      DEC 13
      ASC 15,END-OF-FILE/END OF RECORD
      DEC 10
      ASC 15,STATEMENT NOT IMAGE
      DEC 15
      ASC 15,NON-EXISTENT PROGRAM REQUESTED 
      DEC 12
      ASC 15,CHAIN REQUEST IS A FILE
      DEC 14
      ASC 15,PROGRAM CHAINED IS TOO LARGE 
      DEC -13 
      ASC 15,COM STATEMENT OUT OF ORDER 
      DEC 14
      ASC 15,ARGUMENT OF TIM OUT OF RANGE 
      DEC 14
      ASC 15,BAD FORMAT STRING SUBSCRIPT
      DEC 7 
      ASC 15,BAD FILE READ
      DEC 12
      ASC 15,BAD FILE WRITE DETECTED
      DEC 15
      ASC 15,CAN'T READ PROGRAM CHAINED TO
      DEC 15
      ASC 15,ILL-STORED PROGRAM CHAINED TO
      DEC -6
      ASC 15,PROGRAM BAD
      DEC 15
      ASC 15,STATEMENT NUMBER OUT OF BOUNDS 
      DEC 14
      ASC 15,MISSING FORMAT SPECIFICATION 
      DEC 14
      ASC 15,ILLEGAL OR MISSING DELIMITER 
      DEC 8 
      ASC 15,NO CLOSING QUOTE 
      DEC 15
      ASC 15,BAD CHARACTER AFTER REPLICATOR 
      DEC 10
      ASC 15,REPLICATOR TOO LARGE 
      DEC 8 
      ASC 15,REPLICATOR ZERO
      DEC 12
      ASC 15,MULTIPLE DECIMAL POINTS
      DEC 13
      ASC 15,BAD FLOATING SPECIFICATION 
      DEC 14
      ASC 15,ILLEGAL CHARACTER IN FORMAT
      SPC 2 
      ORG LIBRA 
      DEC 13
      ASC 15,ILLEGAL FORMAT FOR STRING
      DEC 13
      ASC 15,MISSING RIGHT PARENTHESIS
      DEC 9 
      ASC 15,MISSING REPLICATOR 
      DEC 14
      ASC 15,TOO MANY PARENTHESIS LEVELS
      DEC 12
      ASC 15,MISSING LEFT PARENTHESIS 
      DEC 13
      ASC 15,ILLEGAL FORMAT FOR NUMBER
      DEC -14 
      ASC 15,BAD INPUT, RETYPE FROM ITEM
      DEC 13
      ASC 15,LOG OF ZERO - WARNING ONLY 
      DEC 15
      ASC 15,ZERO TO NEGATIVE POWER-WARNING 
      DEC 15
      ASC 15,DIVIDE BY ZERO - WARNING ONLY
      DEC 14
      ASC 15,EXP OVERFLOW - WARNING ONLY
      DEC 12
      ASC 15,OVERFLOW - WARNING ONLY
      DEC 12
      ASC 15,UNDERFLOW - WARNING ONLY 
      DEC -13 
      ASC 15,EXTRA INPUT - WARNING ONLY 
      DEC -8
      ASC 15,READ-ONLY FILES: 
      DEC -3
      OCT 11423 
      OCT 5012
      ASC 13,*
      SPC 2 
      ORG 0 
      NOP           SIGNAL LOADER THAT WE'RE DONE.
      END 
