/
/
/	SYSDEV TRANS IN SGNBLK AND RETURNS A VALUE INDICATING THE SYSTEM
/	DEVICE AS FOLLOWS:
/
/			RK = 1
/			DP = 2
/			DK = 3
/			ERROR = 0	!! MNEMONIC NOT RECOGNIZED !!
/
/
/	WRITTEN BY: GARTH A. REID	OCTOBER 6, 1975
/
/
/	.DAT SLOT USAGE:
/
/			-1 - MUST BE ASSIGNED TO THE SYSTEM DEVICE.
/
/
	.GLOBL	SYSDEV,.DA
	.IODEV	-1
SYSDEV	XX
	JMS*	.DA
	JMP	.+2
ANS	0
	.INIT	-1,0,0
	.TRAN	-1,0,36,BUF,256	/READ IN SGNBLK.
	.WAIT	-1		/
	LAC	BUF+4		/PICK UP THE SYSTEM DEVICE MNEMONIC IN SIXBT.
	SAD	RK		/RK?
	SKP			/YES.
	JMP	.+3		/NO.
	LAC	(1)
	JMP	AN.PT
	SAD	DP		/DP?
	SKP			/YES.
	JMP	.+3		/NO.
	LAC	(2)
	JMP	AN.PT
	SAD	DK		/DK?
	SKP			/YES.
	JMP	.+3		/NO.
	LAC	(3)
	JMP	AN.PT
	CLA			/ERROR -- MNEMONIC NOT RECOGNIZED!!
AN.PT	DAC*	ANS
	JMP*	SYSDEV
RK	.SIXBT	'RK'
DP	.SIXBT	'DP'
DK	.SIXBT	'DK'
BUF	.BLOCK	400
	.END	SYSDEV
