       .TITLE DIM    POSITIVE DIFFERENCE FOR REAL ARGUMENTS
/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/COPYRIGHT 1970,1971, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/EDIT 2  8-9-71
/FOR HARDWARE FLOATING POINT PROCESSOR (FPP), DEFINE %FPP,
       .GLOBL DIM,.DA,
	.IFUND %FPP
	.GLOBL .AG,.AJ,.AB,.AW
	.ENDC
	.IFUND %FPP
	.DEFIN FLD%,A		/FLOATING LOAD (.AG)
	JMS* A
	.ENDM
	.ENDC
	.IFDEF %FPP
FLD=713050
	.DEFIN FLD%
	FLD
	.ENDM
	.ENDC
	.IFUND %FPP
	.DEFIN FSB%,A		/FLOATING SUBTRACT (.AJ)
	JMS* A
	.ENDM
	.ENDC
	.IFDEF %FPP
FSB=710440
	.DEFIN FSB%
	FSB
	.ENDM
	.ENDC
/             CALLING SEQUENCE
/      JMS*   (DIM)           SUBR CALL
/      JMP    .+3             SUBR RETURN
/      CAL/XCTADDR            ADDR OF ARG1
/      CAL/XCTADDR            ADDR OF ARG2 (XCT IF INDIRECT)
/FPP INSTR. ASS
	.IFDEF %FPP
BPA=716604			/BR ON POS FPP AC
FZR=711200
	.ENDC
/
DIM    CAL    0              /ENTRY-EXIT
       JMS*   .DA            /GET ARGUMENTS (.DA)
       JMP    DIM03
DIM01  CAL    0              /ARG1
DIM02  CAL    0              /ARG2
DIM03  FLD%   .AG            /LOAD REAL (.AG)
       .DSA   DIM01+400000   / (ARG1)
       FSB%   .AJ            /SUBTRACT REAL (.AJ)
       .DSA   DIM02+400000   / (ARG1-ARG2)
	.IFDEF %FPP
	BPA			/BR IF POS.
	DIM04
	FZR			/ZERO FPP AC
	0			/UNUSED
	.ENDC
	.IFUND %FPP
       LAC*   .AB            /GET SIGN WORD
       SPA!CLA               /SKIP IF POSITIVE
       JMS*   .AW	    /OTHERWISE FLOAT A ZERO
	.ENDC
DIM04  JMP*   DIM            /EXIT-KEEP-TAG
       .END
