       .TITLE STOP
/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/COPYRIGHT 1970,1973 DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/EDIT 7  11-14-73
/OBJECT TIME STOP STATEMENT PROCESSOR.
/FOR RSX VERSION,DEFINE RSX
/WITH RSX,TSKNAME IS PRINTED WITH STOP MSG. VIA LUN-4
/CALLING SEQUENCE--LAC   OCTAL NUMBER TO BE PRINTED.
/                  JMP*  .ST
/ 
/ IF THE NUMBER OF POSITIVE DAT SLOTS IS NOT 20 DEFINE STTBSZ
/
/
/}
/	EDIT 008	RKH	2-AUG-74 	CHANGES FOR PDP-9
/
/
	.IFUND RSX
       .GLOBL .ST,.SP,.SDSTB
	.GLOBL STOP
IDX=ISZ
	.IFUND STTBSZ
STTBSZ=20
	.ENDC
STOP=.
.ST    JMS*   .SP            /PRINT MESSAGE.
       .DSA   ST1            / CONTROL RETURN
       LAW    123            /S
       LAW    124            /T
       LAW    117            /O
       LAW    120            /P
       LAW    040            /BLANK
       LAW    040            /BLANK
ST1	LAW	-STTBSZ		/COUNT NO. OF DAT SLOTS
	DAC	TEMP
	LAC	C00001  / RKH- 2-AUG-74 	/SET UP TO CLOSE DAT SLOT 1
	DAC	SLOT
ST2	LAC	SLOT
	TAD	(.SDSTB-1
	DAC	SLOTPT
	LAC*	SLOTPT
	SNA
	JMP	ST4
	LAC	SLOT
	DAC	.+1
	CAL	0		/CLOSE CAL
	.DSA	6
ST4	IDX	SLOT		/INCREMENT THE SLOT NO.
	ISZ	TEMP		/ALL DONE?
	JMP	ST2		/NO -- CLOSE THE NEXT SLOT
ST3	CAL	0		/GO TO .EXIT IN MONITOR.--
       .DSA   15
TEMP	0
C00001	.DSA	1		/-RKH- 2-AUG-74 CHANGE FOR PDP-9
SLOT	0
SLOTPT	0
.SDSTB	.BLOCK STTBSZ
	.ENDC
	.IFDEF RSX
	.GLOBL	.ST
	.GLOBL	.SP
	.GLOBL	STOP
STOP=.
.ST	SNA	/IF ZERO ARG.,SUPPRESS MESSAGE.
	JMP	ST1	/EXIT IMMED.
	JMS*	.SP	/PRINT MESSAGE.
	123	/S
	124	/T
	117	/O
	120	/P
	177	/NULL
	055	/-
ST1	CAL	(10)	/EXIT
	.ENDC
	.END
