	.TITLE ALOG10	COMPUTE COMMON LOGARITHM FOR REAL ARGUMENT
/
/COPYRIGHT (C) 1975
/DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASS.
/
/THIS SOFTWARE IS FURNISHED UNDER A LICENSE FOR USE ONLY
/ON A SINGLE COMPUTER SYSTEM AND MAY BE COPIED ONLY WITH
/THE INCLUSION OF THE ABOVE COPYRIGHT NOTICE.  THIS
/SOFTWARE, OR ANY OTHER COPIES THEREOF, MAY NOT BE PRO-
/VIDED OR OTHERWISE MADE AVAILABLE TO ANY OTHER PERSON
/EXCEPT FOR USE ON SUCH SYSTEM AND TO ONE WHO AGREES TO
/THESE LICENSE TERMS.  TITLE TO AND OWNERSHIP OF THE
/SOFTWARE SHALL AT ALL TIMES REMAIN IN DEC.
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE
/WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED AS A COM-
/MITMENT BY DIGITAL EQUIPMENT CORPORATION.
/
/DEC ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY
/OF ITS SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DEC.
	.EJECT
/FOR HARDWARE FLOATING POINT PROCESSOR (FPP), DEFINE 90 FPP,
/EDIT 2   1-27-71
/EDIT 3	    27-JAN_75
/ EDIT 4	20-AUG-75	M. HEBENSTREIT	DISCLAIMER
       .GLOBL ALOG10,.DA,.EE,.CAT1R
	.IFUND %FPP
	.GLOBL .AG,.AK
	.ENDC
	.IFUND %FPP
	.DEFIN FLD%,A		/FLOATING LOAD (.AG)
	JMS* A
	.ENDM
	.ENDC
	.IFDEF %FPP
FLD=713050
	.DEFIN FLD%
	FLD
	.ENDM
	.ENDC
	.IFUND %FPP
	.DEFIN FMP%,A
	JMS* A			/FLOATING MULTIPLY (.AK)
	.ENDM
	.ENDC
	.IFDEF %FPP
FMP=711440
	.DEFIN FMP%
	FMP
	.ENDM
	.ENDC
/             CALLING SEQUENCE
/      JMS*   (ALOG10)        SUBR CALL
/      JMP    .+2             SUBR RETURN
/      CAL/XCTADDR            ADDR OF ARGUMENT (XCT IF INDIRECT)
/
ALOG10 CAL    0              /ENTRY-EXIT
       JMS*   .DA            /GET ARGUMENT (.DA)
       JMP    AL1002
AL1001 CAL    0              /ARGUMENT
AL1002	LAC	AL1001		/SEE IF ARG = 0 **003**
	JMS*	.CAT1R		/**003**
	SKP			/ARG DOSN'T =0 SO COMPUTE LOG
	JMP*	ALOG10		/RETRUN IF IT DOES (FAC SET TO 0) **003**
	FLD%   .AG            /LOAD REAL (.AG)
       .DSA   AL1001+400000  / (ARG)
       JMS*   .EE            /COMPUTE LOG2(ARG) (.EE)
       FMP%   .AK            /MULTIPLY REAL (.AK)
       .DSA   AL1007         / (LOG10(2))
       JMP*   ALOG10         /EXIT
AL1007 .DSA   152777         /LOG10(2) (1) (0.3010299957)
              232101         /         (2)
       .END
