	.TITLE	COLORS


;	* * * ID-1000/2000/5000 SOFTWARE MODULE * * *


;	SETS 256-NIBBLE COLOR ITT'S FOR BITS 0-2 RED, 3-5 GREEN & 6,7 BLUE

;	ALL NEW CODE: 27 FEBRUARY 79

;	PROGRAMMER: KEN DINWIDDIE

;	EQUIVALENCES FOR ID-1000/2000/5000:

	XREG	= 166000	; X-REGISTER
	CSR	= 166006	; CONTROL/STATUS REGISTER
	DATREG	= 166010	; DATA "REGISTER"
	TRANSF	= 10000		; START OF INTENSITY TRANSFORMATION TABLES

	.MCALL	.REGDEF,.EXIT

	.REGDEF
	.PAGE
COLORS:	MOV	#TRANSF+2000,@#XREG	; START OF RED ITT
	MOV	#400,R1		; NUMBER OF STEPS OF RED
	MOV	#37,R0		; INITIAL VALUE
RED:	MOVB	R0,@#DATREG	; LOAD RED ITT
	ADD	#40,R0
	DEC	R1
	BNE	RED		; 8 - LEVEL WEDGE * 32
	MOV	#TRANSF+4000,@#XREG	; START OF GREEN ITT
	MOV	#40,R2		; NUMBER OF GREEN STEPS
	MOV	#37,R0		; INITIAL VALUE
GREEN:	MOV	#10,R1		; WIDTH OF EACH STEP
GREEN1:	MOVB	R0,@#DATREG	; LOAD GREEN ITT
	DEC	R1
	BNE	GREEN1
	ADD	#40,R0
	DEC	R2
	BNE	GREEN		; 4 * 8 - LEVEL 8 - WIDE STEPS
	MOV	#TRANSF+6000,@#XREG	; START OF BLUE ITT
	MOV	#4,R2		; NUMBER OF BLUE STEPS
	CLR	R0		; INITIAL VALUE
BLUE:	MOV	#100,R1		; WIDTH OF EACH STEP
BLUE1:	MOVB	R0,@#DATREG	; LOAD BLUE ITT
	DEC	R1
	BNE	BLUE1
	TST	R0
	BNE	BLUE2
	ADD	#77,R0		; BIAS BLUE UPWARD ONLY AFTER ZERO VALUES
BLUE2:	ADD	#100,R0
	DEC	R2
	BNE	BLUE		; 64 - WIDE STEPS * 4
	MOV	#20000,@#CSR	; ENABLE VIEWING THROUGH COLOR ITT'S
	.EXIT			; RETURN TO RT-11 MONITOR
	.END	COLORS
                                                                                                                 